/*	$NetBSD: __sigtramp2.S,v 1.6 2020/10/12 23:56:08 kamil Exp $	*/

/*-
 * Copyright (c) 2002 The NetBSD Foundation, Inc.
 * All rights reserved.
 *
 * This code is derived from software contributed to The NetBSD Foundation
 * by Christos Zoulas.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 * POSSIBILITY OF SUCH DAMAGE.
 */

#include "SYS.h"
#include "assym.h"

/*
 * The i386 signal trampoline is invoked only to return from
 * the signal; the kernel calls the signal handler directly.
 *
 * On entry, stack looks like:
 *
 *		ucontext structure			[12+sizeof(siginfo_t)]
 *		siginfo structure			[12]
 *		pointer to ucontext structure		[8]
 *		pointer to siginfo structure		[4]
 *	sp->	signal number				[0]
 *
 * The unwind entry includes the one byte prior to the trampoline
 * because the unwinder will look up (return PC - 1) while unwinding.
 * Normally (return PC - 1) computes an address inside the call
 * instruction that created the child frame, but here there is no call
 * instruction so we have to manually add padding.
 */
	.cfi_startproc simple
	.cfi_signal_frame
	.cfi_def_cfa esp, 140
	.cfi_offset eax, UC_GREGS_EAX
	.cfi_offset ecx, UC_GREGS_ECX
	.cfi_offset edx, UC_GREGS_EDX
	.cfi_offset ebx, UC_GREGS_EBX
	/* The unwinder will use the CFA to restore ESP. */
	.cfi_offset ebp, UC_GREGS_EBP
	.cfi_offset esi, UC_GREGS_ESI
	.cfi_offset edi, UC_GREGS_EDI
	.cfi_offset eip, UC_GREGS_EIP
	nop
NENTRY(__sigtramp_siginfo_2)
	leal	12+128(%esp),%eax	/* get address of ucontext */
	movl	%eax,4(%esp)	/* put it in the argument slot */
				/* fake return address already there */
	SYSTRAP(setcontext)	/* do setcontext */
	movl	$-1,4(%esp)	/* if we return here, something is wrong */
	SYSTRAP(exit)		/* exit */
	.cfi_endproc
END(__sigtramp_siginfo_2)
