setjmp.S revision 1.1 
1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 * the Systems Programming Group of the University of Utah Computer
7 * Science Department.
8 *
9 * Redistribution and use in source and binary forms, with or without
10 * modification, are permitted provided that the following conditions
11 * are met:
12 * 1. Redistributions of source code must retain the above copyright
13 *    notice, this list of conditions and the following disclaimer.
14 * 2. Redistributions in binary form must reproduce the above copyright
15 *    notice, this list of conditions and the following disclaimer in the
16 *    documentation and/or other materials provided with the distribution.
17 * 3. All advertising materials mentioning features or use of this software
18 *    must display the following acknowledgement:
19 *	This product includes software developed by the University of
20 *	California, Berkeley and its contributors.
21 * 4. Neither the name of the University nor the names of its contributors
22 *    may be used to endorse or promote products derived from this software
23 *    without specific prior written permission.
24 *
25 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
26 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
27 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
28 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
29 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
30 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
31 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
32 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
33 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
34 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
35 * SUCH DAMAGE.
36 */
37
38#if defined(LIBC_SCCS) && !defined(lint)
39	.text
40	/*.asciz "from: @(#)setjmp.s	5.1 (Berkeley) 5/12/90"*/
41	.asciz "$Id: setjmp.S,v 1.1 1993/11/25 23:37:19 paulus Exp $"
42#endif /* LIBC_SCCS and not lint */
43
44/*
45 * C library -- setjmp, longjmp
46 *
47 *	longjmp(a,v)
48 * will generate a "return(v)" from
49 * the last call to
50 *	setjmp(a)
51 * by restoring registers from the stack,
52 * and a struct sigcontext, see <signal.h>
53 */
54
55#include "DEFS.h"
56
57ENTRY(setjmp)
58	subql	#8,sp		/* space for sigstack args/rvals */
59	clrl	sp@		/* don't change it... */
60	movl	sp,sp@(4)	/* ...but return the current val */
61	jbsr	_sigstack	/* note: onstack returned in sp@(4) */
62	clrl	sp@		/* don't change mask, just return */
63	jbsr	_sigblock	/*   old value */
64	movl	sp@(4),d1	/* old onstack value */
65	addql	#8,sp
66	movl	sp@(4),a0	/* save area pointer */
67	movl	d1,a0@+		/* save old onstack value */
68	movl	d0,a0@+		/* save old signal mask */
69	lea	sp@(4),a1	/* adjust saved SP since we won't rts */
70	movl	a1,a0@+		/* save old SP */
71	movl	a6,a0@+		/* save old FP */
72	clrl	a0@+		/* no AP */
73	movl	sp@,a0@+	/* save old PC */
74	clrl	a0@+		/* clean PS */
75	moveml	#0x3CFC,a0@	/* save remaining non-scratch regs */
76	clrl	d0		/* return 0 */
77	rts
78
79ENTRY(longjmp)
80	movl	sp@(4),a0	/* save area pointer */
81	tstl	a0@(8)		/* ensure non-zero SP */
82	jeq	botch		/* oops! */
83	movl	sp@(8),d0	/* grab return value */
84	jne	ok		/* non-zero ok */
85	moveq	#1,d0		/* else make non-zero */
86ok:
87	moveml	a0@(28),#0x3CFC	/* restore non-scratch regs */
88	movl	a0,sp@-		/* let sigreturn */
89	jbsr	_sigreturn	/*   finish for us */
90
91botch:
92	jbsr	_longjmperror
93	stop	#0
94