acinclude.m4 revision ecce36be 
1# ===========================================================================
2#       http://www.nongnu.org/autoconf-archive/ax_compare_version.html
3# ===========================================================================
4#
5# SYNOPSIS
6#
7#   AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
8#
9# DESCRIPTION
10#
11#   This macro compares two version strings. Due to the various number of
12#   minor-version numbers that can exist, and the fact that string
13#   comparisons are not compatible with numeric comparisons, this is not
14#   necessarily trivial to do in a autoconf script. This macro makes doing
15#   these comparisons easy.
16#
17#   The six basic comparisons are available, as well as checking equality
18#   limited to a certain number of minor-version levels.
19#
20#   The operator OP determines what type of comparison to do, and can be one
21#   of:
22#
23#    eq  - equal (test A == B)
24#    ne  - not equal (test A != B)
25#    le  - less than or equal (test A <= B)
26#    ge  - greater than or equal (test A >= B)
27#    lt  - less than (test A < B)
28#    gt  - greater than (test A > B)
29#
30#   Additionally, the eq and ne operator can have a number after it to limit
31#   the test to that number of minor versions.
32#
33#    eq0 - equal up to the length of the shorter version
34#    ne0 - not equal up to the length of the shorter version
35#    eqN - equal up to N sub-version levels
36#    neN - not equal up to N sub-version levels
37#
38#   When the condition is true, shell commands ACTION-IF-TRUE are run,
39#   otherwise shell commands ACTION-IF-FALSE are run. The environment
40#   variable 'ax_compare_version' is always set to either 'true' or 'false'
41#   as well.
42#
43#   Examples:
44#
45#     AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
46#     AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
47#
48#   would both be true.
49#
50#     AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
51#     AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
52#
53#   would both be false.
54#
55#     AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
56#
57#   would be true because it is only comparing two minor versions.
58#
59#     AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
60#
61#   would be true because it is only comparing the lesser number of minor
62#   versions of the two values.
63#
64#   Note: The characters that separate the version numbers do not matter. An
65#   empty string is the same as version 0. OP is evaluated by autoconf, not
66#   configure, so must be a string, not a variable.
67#
68#   The author would like to acknowledge Guido Draheim whose advice about
69#   the m4_case and m4_ifvaln functions make this macro only include the
70#   portions necessary to perform the specific comparison specified by the
71#   OP argument in the final configure script.
72#
73# LICENSE
74#
75#   Copyright (c) 2008 Tim Toolan <toolan@ele.uri.edu>
76#
77#   Copying and distribution of this file, with or without modification, are
78#   permitted in any medium without royalty provided the copyright notice
79#   and this notice are preserved.
80
81dnl #########################################################################
82AC_DEFUN([AX_COMPARE_VERSION], [
83
84  # Used to indicate true or false condition
85  ax_compare_version=false
86
87  # Convert the two version strings to be compared into a format that
88  # allows a simple string comparison.  The end result is that a version
89  # string of the form 1.12.5-r617 will be converted to the form
90  # 0001001200050617.  In other words, each number is zero padded to four
91  # digits, and non digits are removed.
92  AS_VAR_PUSHDEF([A],[ax_compare_version_A])
93  A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
94                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
95                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
96                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
97                     -e 's/[[^0-9]]//g'`
98
99  AS_VAR_PUSHDEF([B],[ax_compare_version_B])
100  B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
101                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
102                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
103                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
104                     -e 's/[[^0-9]]//g'`
105
106  dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
107  dnl # then the first line is used to determine if the condition is true.
108  dnl # The sed right after the echo is to remove any indented white space.
109  m4_case(m4_tolower($2),
110  [lt],[
111    ax_compare_version=`echo "x$A
112x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
113  ],
114  [gt],[
115    ax_compare_version=`echo "x$A
116x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
117  ],
118  [le],[
119    ax_compare_version=`echo "x$A
120x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
121  ],
122  [ge],[
123    ax_compare_version=`echo "x$A
124x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
125  ],[
126    dnl Split the operator from the subversion count if present.
127    m4_bmatch(m4_substr($2,2),
128    [0],[
129      # A count of zero means use the length of the shorter version.
130      # Determine the number of characters in A and B.
131      ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
132      ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
133
134      # Set A to no more than B's length and B to no more than A's length.
135      A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
136      B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
137    ],
138    [[0-9]+],[
139      # A count greater than zero means use only that many subversions
140      A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
141      B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
142    ],
143    [.+],[
144      AC_WARNING(
145        [illegal OP numeric parameter: $2])
146    ],[])
147
148    # Pad zeros at end of numbers to make same length.
149    ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
150    B="$B`echo $A | sed 's/./0/g'`"
151    A="$ax_compare_version_tmp_A"
152
153    # Check for equality or inequality as necessary.
154    m4_case(m4_tolower(m4_substr($2,0,2)),
155    [eq],[
156      test "x$A" = "x$B" && ax_compare_version=true
157    ],
158    [ne],[
159      test "x$A" != "x$B" && ax_compare_version=true
160    ],[
161      AC_WARNING([illegal OP parameter: $2])
162    ])
163  ])
164
165  AS_VAR_POPDEF([A])dnl
166  AS_VAR_POPDEF([B])dnl
167
168  dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
169  if test "$ax_compare_version" = "true" ; then
170    m4_ifvaln([$4],[$4],[:])dnl
171    m4_ifvaln([$5],[else $5])dnl
172  fi
173]) dnl AX_COMPARE_VERSION
174