1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-input-keyboard],
26        [2.0.0],
27        [https://gitlab.freedesktop.org/xorg/driver/xf86-input-keyboard/issues],
28        [xf86-input-keyboard])
29AC_CONFIG_SRCDIR([Makefile.am])
30AC_CONFIG_HEADERS([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33# Initialize Automake
34AM_INIT_AUTOMAKE([foreign dist-xz])
35
36# Initialize libtool
37AC_DISABLE_STATIC
38AC_PROG_LIBTOOL
39
40# Initialize X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
41m4_ifndef([XORG_MACROS_VERSION],
42          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
43XORG_MACROS_VERSION(1.8)
44XORG_DEFAULT_OPTIONS
45
46# Obtain compiler/linker options from server and required extensions
47PKG_CHECK_MODULES(XORG, [xorg-server >= 1.10] xproto inputproto)
48
49# Define a configure option for an alternate input module directory
50AC_ARG_WITH(xorg-module-dir,
51            AC_HELP_STRING([--with-xorg-module-dir=DIR],
52                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
53            [moduledir="$withval"],
54            [moduledir="$libdir/xorg/modules"])
55inputdir=${moduledir}/input
56AC_SUBST(inputdir)
57
58# The keyboard driver code is O/S specific
59case $host_os in
60  linux*)
61    AC_MSG_ERROR([This is not the keyboard driver you are looking for. Use evdev or libinput.])
62    ;;
63
64  freebsd* | kfreebsd-gnu* | netbsd* | openbsd* | dragonfly*)
65    IS_BSD="yes"
66    ;;
67
68  solaris*)
69    IS_SOLARIS="yes"
70    ;;
71
72  gnu*)
73    IS_HURD="yes"
74    ;;
75
76  *)
77    AC_MSG_ERROR([Your operating system is not supported by the kbd driver.
78                  Contact xorg@lists.freedesktop.org if you are interested in
79                  porting it.])
80    ;;
81esac
82case $host_os in
83  netbsd*)
84    case $host in
85      *powerpc-*|*sparc-*|*sparc64-*|*vax-*)
86        OS_FLAGS="$OS_FLAGS -DDEFAULT_TO_WSKBD"
87        ;;
88    esac
89    case "$(uname -m 2>&1)" in
90      evbarm|sgimips|shark)
91        OS_FLAGS="$OS_FLAGS -DDEFAULT_TO_WSKBD"
92        ;;
93    esac
94    ;;
95esac
96AC_SUBST([OS_FLAGS])
97
98AM_CONDITIONAL(BSD, [test "x$IS_BSD" = xyes])
99AM_CONDITIONAL(SOLARIS, [test "x$IS_SOLARIS" = xyes])
100AM_CONDITIONAL(HURD, [test "x$IS_HURD" = xyes])
101
102DRIVER_NAME=kbd
103AC_SUBST([DRIVER_NAME])
104
105AC_CONFIG_FILES([Makefile
106                 src/Makefile
107                 man/Makefile])
108AC_OUTPUT
109