configure.ac revision 504d986f 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-amdgpu],
26        [1.2.0],
27        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
28        [xf86-video-amdgpu])
29
30AC_CONFIG_SRCDIR([Makefile.am])
31AC_CONFIG_HEADERS([config.h])
32
33AC_CONFIG_AUX_DIR(.)
34
35# Initialize Automake
36AM_INIT_AUTOMAKE([foreign dist-bzip2])
37AC_SYS_LARGEFILE
38
39# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
40m4_ifndef([XORG_MACROS_VERSION],
41          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
42XORG_MACROS_VERSION(1.8)
43XORG_DEFAULT_OPTIONS
44
45# Initialize libtool
46AC_DISABLE_STATIC
47AC_PROG_LIBTOOL
48
49# Checks for programs.
50AM_PROG_CC_C_O
51
52if test "x$GCC" = "xyes"; then
53	CPPFLAGS="$CPPFLAGS -Wall"
54fi
55
56AH_TOP([#include "xorg-server.h"])
57
58# Define a configure option for an alternate module directory
59AC_ARG_WITH(xorg-module-dir,
60            AS_HELP_STRING([--with-xorg-module-dir=DIR],
61                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
62            [moduledir="$withval"],
63            [moduledir="$libdir/xorg/modules"])
64
65# Store the list of server defined optional extensions in REQUIRED_MODULES
66XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
67XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
68XORG_DRIVER_CHECK_EXT(XV, videoproto)
69XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
70
71# Checks for libraries.
72PKG_CHECK_MODULES(LIBDRM, [libdrm >= 2.4.58])
73PKG_CHECK_MODULES(LIBDRM_AMDGPU, [libdrm_amdgpu])
74PKG_CHECK_MODULES(GBM, [gbm])
75
76# Obtain compiler/linker options for the driver dependencies
77PKG_CHECK_MODULES(XORG, [xorg-server >= 1.10 xproto fontsproto xf86driproto $REQUIRED_MODULES])
78PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
79                  HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
80                  HAVE_XEXTPROTO_71="no")
81AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
82
83# Section "OutputClass" is only supported as of xserver 1.16
84PKG_CHECK_EXISTS([xorg-server >= 1.16],
85		 [sysconfigdir=`$PKG_CONFIG --variable=sysconfigdir xorg-server`],
86		 [sysconfigdir=""])
87AM_CONDITIONAL(HAS_XORG_CONF_DIR, [test "x$sysconfigdir" != "x"])
88
89# Define a configure option for an alternate X Server configuration directory
90AC_ARG_WITH(xorg-conf-dir,
91            AS_HELP_STRING([--with-xorg-conf-dir=DIR],
92                           [Default xorg.conf.d directory [[default=${prefix}/share/X11/xorg.conf.d]]]),
93            [configdir="$withval"],
94            [configdir='${prefix}/share/X11/xorg.conf.d'])
95AC_SUBST(configdir)
96
97AC_ARG_ENABLE([udev],
98		AS_HELP_STRING([--disable-udev], [Disable libudev support [default=auto]]),
99		[enable_udev="$enableval"],
100		[enable_udev=auto])
101if test "x$enable_udev" != "xno"; then
102	PKG_CHECK_MODULES(LIBUDEV, [libudev], [LIBUDEV=yes], [LIBUDEV=no])
103	if test "x$LIBUDEV" = xyes; then
104		AC_DEFINE(HAVE_LIBUDEV, 1,[libudev support])
105	elif test "x$enable_udev" != "xauto"; then
106		AC_MSG_ERROR([Building with udev requested but libudev not found])
107	fi
108fi
109AM_CONDITIONAL(LIBUDEV, test x$LIBUDEV = xyes)
110
111SAVE_CPPFLAGS="$CPPFLAGS"
112CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
113
114AC_MSG_CHECKING([whether to include GLAMOR support])
115AC_ARG_ENABLE(glamor,
116	      AS_HELP_STRING([--disable-glamor],
117			     [Disable glamor, a new GL-based acceleration [default=enabled]]),
118	      [GLAMOR="$enableval"],
119	      [GLAMOR=yes])
120
121if test "x$GLAMOR" != "xno"; then
122	AC_CHECK_HEADERS([glamor.h], [GLAMOR_H="yes"], [GLAMOR_H="no"], [#include "xorg-server.h"])
123
124	if test "x$GLAMOR_H" = xyes; then
125		AC_CHECK_DECL(GLAMOR_NO_DRI3,
126			      [GLAMOR_XSERVER="yes"], [GLAMOR_XSERVER="no"],
127			      [#include "xorg-server.h"
128			       #include "glamor.h"])
129
130		AC_CHECK_DECL(glamor_glyphs_init,
131			      [AC_DEFINE(HAVE_GLAMOR_GLYPHS_INIT, 1,
132					 [Have glamor_glyphs_init API])], [],
133			      [#include "xorg-server.h"
134			       #include "glamor.h"])
135
136		AC_CHECK_DECL(glamor_egl_destroy_textured_pixmap,
137			      [AC_DEFINE(HAVE_GLAMOR_EGL_DESTROY_TEXTURED_PIXMAP, 1,
138					 [Have glamor_egl_destroy_textured_pixmap API])], [],
139			      [#include "xorg-server.h"
140			       #include "glamor.h"])
141	fi
142
143	PKG_CHECK_MODULES(LIBGL, [gl])
144
145	if test "x$GLAMOR_XSERVER" != xyes; then
146		PKG_CHECK_MODULES(LIBGLAMOR, [glamor >= 0.6.0])
147		PKG_CHECK_MODULES(LIBGLAMOR_EGL, [glamor-egl])
148	fi
149	AC_DEFINE(USE_GLAMOR, 1, [Enable glamor acceleration])
150else
151	AC_MSG_RESULT([$GLAMOR])
152fi
153AM_CONDITIONAL(GLAMOR, test x$GLAMOR != xno)
154
155AC_CHECK_DECL(fbGlyphs,
156	      [AC_DEFINE(HAVE_FBGLYPHS, 1, [Have fbGlyphs API])], [],
157	      [#include <X11/Xmd.h>
158	       #include <X11/Xfuncproto.h>
159	       #include <X11/extensions/renderproto.h>
160	       #include <xorg-server.h>
161	       #include <picture.h>
162	       #include <glyphstr.h>
163	       #include <fbpict.h>])
164
165AC_CHECK_DECL(xf86CursorResetCursor,
166	      [AC_DEFINE(HAVE_XF86_CURSOR_RESET_CURSOR, 1,
167	      [Have xf86CursorResetCursor API])], [],
168	      [#include <xorg-server.h>
169	       #include <xf86Cursor.h>])
170
171AC_CHECK_DECL(xorg_list_init,
172	      [AC_DEFINE(HAVE_XORG_LIST, 1, [Have xorg_list API])], [],
173	      [#include <X11/Xdefs.h>
174	      #include "xorg-server.h"
175	      #include "list.h"])
176
177AC_CHECK_DECL(GBM_BO_USE_LINEAR,
178	      [AC_DEFINE(HAVE_GBM_BO_USE_LINEAR, 1, [Have GBM_BO_USE_LINEAR])], [],
179	      [#include <stdlib.h>
180	       #include <gbm.h>])
181
182AC_CHECK_HEADERS([misyncshm.h], [], [],
183                 [#include <X11/Xdefs.h>
184	          #include <X11/Xfuncproto.h>
185	          #include <xorg-server.h>
186		  #include <screenint.h>])
187
188AC_CHECK_HEADERS([present.h], [], [],
189		 [#include <X11/Xmd.h>
190		 #include <X11/Xproto.h>
191		 #include <X11/X.h>
192		 #include "xorg-server.h"])
193
194AC_CHECK_HEADERS([dri3.h], [], [],
195		 [#include <X11/Xmd.h>
196		 #include <xorg-server.h>])
197
198CPPFLAGS="$SAVE_CPPFLAGS"
199
200# Checks for headers/macros for byte swapping
201# Known variants:
202#	<byteswap.h> bswap_16, bswap_32, bswap_64  (glibc)
203#	<sys/endian.h> __swap16, __swap32, __swap64 (OpenBSD)
204#	<sys/endian.h> bswap16, bswap32, bswap64 (other BSD's)
205#	and a fallback to local macros if none of the above are found
206
207# if <byteswap.h> is found, assume it's the correct version
208AC_CHECK_HEADERS([byteswap.h])
209
210# if <sys/endian.h> is found, have to check which version
211AC_CHECK_HEADER([sys/endian.h], [HAVE_SYS_ENDIAN_H="yes"], [HAVE_SYS_ENDIAN_H="no"])
212
213if test "x$HAVE_SYS_ENDIAN_H" = "xyes" ; then
214	AC_MSG_CHECKING([for __swap16 variant of <sys/endian.h> byteswapping macros])
215	AC_LINK_IFELSE([AC_LANG_PROGRAM([
216#include <sys/types.h>
217#include <sys/endian.h>
218 ], [
219int a = 1, b;
220b = __swap16(a);
221 ])
222], [SYS_ENDIAN__SWAP='yes'], [SYS_ENDIAN__SWAP='no'])
223	AC_MSG_RESULT([$SYS_ENDIAN__SWAP])
224
225	AC_MSG_CHECKING([for bswap16 variant of <sys/endian.h> byteswapping macros])
226	AC_LINK_IFELSE([AC_LANG_PROGRAM([
227#include <sys/types.h>
228#include <sys/endian.h>
229 ], [
230int a = 1, b;
231b = bswap16(a);
232 ])
233], [SYS_ENDIAN_BSWAP='yes'], [SYS_ENDIAN_BSWAP='no'])
234	AC_MSG_RESULT([$SYS_ENDIAN_BSWAP])
235
236    	if test "$SYS_ENDIAN_BSWAP" = "yes" ; then
237		USE_SYS_ENDIAN_H=yes
238		BSWAP=bswap
239	else	
240	    	if test "$SYS_ENDIAN__SWAP" = "yes" ; then
241			USE_SYS_ENDIAN_H=yes
242			BSWAP=__swap
243		else
244			USE_SYS_ENDIAN_H=no
245		fi
246	fi
247
248	if test "$USE_SYS_ENDIAN_H" = "yes" ; then
249	    AC_DEFINE([USE_SYS_ENDIAN_H], 1, 
250		[Define to use byteswap macros from <sys/endian.h>])
251	    AC_DEFINE_UNQUOTED([bswap_16], ${BSWAP}16, 
252			[Define to 16-bit byteswap macro])
253	    AC_DEFINE_UNQUOTED([bswap_32], ${BSWAP}32, 
254			[Define to 32-bit byteswap macro])
255	    AC_DEFINE_UNQUOTED([bswap_64], ${BSWAP}64, 
256			[Define to 64-bit byteswap macro])
257	fi
258fi
259
260AC_SUBST([moduledir])
261
262DRIVER_NAME=amdgpu
263AC_SUBST([DRIVER_NAME])
264
265AC_CONFIG_FILES([
266                Makefile
267                src/Makefile
268                man/Makefile
269                conf/Makefile
270])
271AC_OUTPUT
272
273dnl
274dnl Output some configuration info for the user
275dnl
276echo ""
277echo "        prefix:              $prefix"
278echo "        exec_prefix:         $exec_prefix"
279echo "        libdir:              $libdir"
280echo "        includedir:          $includedir"
281echo "        configdir:           $configdir"
282
283echo ""
284echo "        CFLAGS:              $CFLAGS"
285echo "        CXXFLAGS:            $CXXFLAGS"
286echo "        Macros:              $DEFINES"
287
288echo ""
289echo "        Run '${MAKE-make}' to build xf86-video-amdgpu"
290echo ""
291