1/*
2 * Copyright © 2006 Intel Corporation
3 *
4 * Permission is hereby granted, free of charge, to any person obtaining a
5 * copy of this software and associated documentation files (the "Software"),
6 * to deal in the Software without restriction, including without limitation
7 * the rights to use, copy, modify, merge, publish, distribute, sublicense,
8 * and/or sell copies of the Software, and to permit persons to whom the
9 * Software is furnished to do so, subject to the following conditions:
10 *
11 * The above copyright notice and this permission notice (including the next
12 * paragraph) shall be included in all copies or substantial portions of the
13 * Software.
14 *
15 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
16 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
17 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
18 * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
19 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
20 * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
21 * IN THE SOFTWARE.
22 *
23 * Authors:
24 *    Keith Packard <keithp@keithp.com>
25 *    Eric Anholt <eric@anholt.net>
26 *
27 */
28
29include(`exa_wm.g4i')
30
31define(`YCbCr_base',	`src_sample_base')
32
33define(`Cr',		`src_sample_r')
34define(`Cr_01',		`src_sample_r_01')
35define(`Cr_23',		`src_sample_r_23')
36
37define(`Y',		`src_sample_g')
38define(`Y_01',		`src_sample_g_01')
39define(`Y_23',		`src_sample_g_23')
40
41define(`Cb',		`src_sample_b')
42define(`Cb_01',		`src_sample_b_01')
43define(`Cb_23',		`src_sample_b_23')
44
45define(`Crn',		`mask_sample_r')
46define(`Crn_01',	`mask_sample_r_01')
47define(`Crn_23',	`mask_sample_r_23')
48
49define(`Yn',		`mask_sample_g')
50define(`Yn_01',		`mask_sample_g_01')
51define(`Yn_23',		`mask_sample_g_23')
52
53define(`Cbn',		`mask_sample_b')
54define(`Cbn_01',	`mask_sample_b_01')
55define(`Cbn_23',	`mask_sample_b_23')
56
57    /* color space conversion function:
58     * R = Clamp ( 255/(235-16)(Y-16/255) +
59     *             255/112(1.0-Kr)(Cr-128/255), 0, 1)
60     * G = Clamp ( 255/(235-16)(Y-16/255) -
61     *             255/112(1.0-Kr)Kr/Kg(Cr-128/255) -
62     *             255/112(1.0-Kb)Kb/Kg(Cb-128/255), 0, 1)
63     * B = Clamp ( 255/(235-16)(Y-16/255) +
64     *             255/112(1.0-Kb)(Cb-128/255), 0, 1)
65     *
66     * BT.601:
67     * Kr = 0.299
68     * Kb = 0.114
69     * Kg = (1.0 - Kr - Kb) = 0.587
70     */
71
72    /* Normalize Y, Cb and Cr:
73     *
74     * Yn = (Y - 16/255) * 255/(235-16)
75     * Crn = Cr - 128 / 255
76     * Cbn = Cb - 128 / 255
77     */
78add (16)    Yn<1>F		Y<8,8,1>F	-0.0627451F { compr align1 };
79mul (16)    Yn<1>F		Yn<8,8,1>F	1.164F	    { compr align1 };
80
81add (16)    Crn<1>F		Cr<8,8,1>F	-0.501961F  { compr align1 };
82
83add (16)    Cbn<1>F		Cb<8,8,1>F	-0.501961F  { compr align1 };
84
85    /*
86     * R = Yn +
87     *     Crn * 255/112 * (1.0 - Kr)
88     */
89mov (8)    acc0<1>F		Yn_01<8,8,1>F		    { compr align1 };
90mac.sat(8) src_sample_r_01<1>F	Crn_01<8,8,1>F	1.596F	    { compr align1 };
91
92mov (8)    acc0<1>F		Yn_23<8,8,1>F		    { compr align1 };
93mac.sat(8) src_sample_r_23<1>F	Crn_23<8,8,1>F	1.596F	    { compr align1 };
94    /*
95     * G = Yn -
96     *     Crn * 255/112 * (1.0 - Kr) * Kr / Kg -
97     *     Cbn * 255/112 * (1.0 - Kb) * Kb / Kg
98     */
99mov (8)    acc0<1>F		Yn_01<8,8,1>F		    { compr align1 };
100mac (8)    acc0<1>F		Crn_01<8,8,1>F    	-0.813F	    { compr align1 };
101mac.sat(8) src_sample_g_01<1>F	Cbn_01<8,8,1>F    	-0.392F	    { compr align1 };
102
103mov (8)    acc0<1>F		Yn_23<8,8,1>F	    { compr align1 };
104mac (8)    acc0<1>F		Crn_23<8,8,1>F    	-0.813F	    { compr align1 };
105mac.sat(16) src_sample_g_23<1>F	Cbn_23<8,8,1>F    	-0.392F	    { compr align1 };
106    /*
107     * B = Yn +
108     *     Cbn * 255/112 * (1.0 - Kb)
109     */
110mov (8)    acc0<1>F	        Yn_01<8,8,1>F		    { compr align1 };
111mac.sat(8) src_sample_b_01<1>F	Cbn_01<8,8,1>F     2.017F	    { compr align1 };
112
113mov (8)    acc0<1>F	        Yn_23<8,8,1>F		    { compr align1 };
114mac.sat(8) src_sample_b_23<1>F	Cbn_23<8,8,1>F     2.017F	    { compr align1 };
115    /*
116     * A = 1.0
117     */
118mov (16)    src_sample_a<1>F	1.0F			    { compr align1 };
119