configure.ac revision d31dbc53 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23AC_PREREQ(2.57)
24AC_INIT([xf86-video-mach64],
25        6.8.1,
26        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
27        xf86-video-mach64)
28
29AC_CONFIG_SRCDIR([Makefile.am])
30AM_CONFIG_HEADER([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33AM_INIT_AUTOMAKE([dist-bzip2])
34
35AM_MAINTAINER_MODE
36
37# Require xorg-macros: XORG_CWARNFLAGS, XORG_CHANGELOG
38m4_ifndef([XORG_MACROS_VERSION], [AC_FATAL([must install xorg-macros 1.2 or later before running autoconf/autogen])])
39XORG_MACROS_VERSION(1.2)
40
41# Checks for programs.
42AC_DISABLE_STATIC
43AC_PROG_LIBTOOL
44AC_PROG_CC
45XORG_CWARNFLAGS
46
47AH_TOP([#include "xorg-server.h"])
48
49AC_ARG_WITH(xorg-module-dir,
50            AC_HELP_STRING([--with-xorg-module-dir=DIR],
51                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
52            [moduledir="$withval"],
53            [moduledir="$libdir/xorg/modules"])
54
55AC_ARG_ENABLE(dri, AC_HELP_STRING([--disable-dri],
56                                  [Disable DRI support [[default=auto]]]),
57              [DRI="$enableval"],
58              [DRI=auto])
59
60AC_ARG_ENABLE(exa,
61              AC_HELP_STRING([--disable-exa],
62                             [Disable EXA support [[default=enabled]]]),
63              [EXA="$enableval"],
64              [EXA=yes])
65
66# Checks for extensions
67XORG_DRIVER_CHECK_EXT(XINERAMA, xineramaproto)
68XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
69XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
70XORG_DRIVER_CHECK_EXT(XV, videoproto)
71XORG_DRIVER_CHECK_EXT(XF86MISC, xf86miscproto)
72XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
73
74# Checks for pkg-config packages
75PKG_CHECK_MODULES(XORG, [xorg-server >= 1.2 xproto fontsproto $REQUIRED_MODULES])
76sdkdir=$(pkg-config --variable=sdkdir xorg-server)
77
78# Checks for libraries.
79
80# Checks for header files.
81AC_HEADER_STDC
82
83if test "$DRI" != no; then
84	AC_CHECK_FILE([${sdkdir}/dri.h],
85                      [have_dri_h="yes"], [have_dri_h="no"])
86	AC_CHECK_FILE([${sdkdir}/sarea.h],
87                      [have_sarea_h="yes"], [have_sarea_h="no"])
88	AC_CHECK_FILE([${sdkdir}/dristruct.h],
89                      [have_dristruct_h="yes"], [have_dristruct_h="no"])
90	AC_CHECK_FILE([${sdkdir}/damage.h],
91                      [have_damage_h="yes"], [have_damage_h="no"])
92fi
93
94AC_MSG_CHECKING([whether to include DRI support])
95if test x$DRI = xauto; then
96	if test "$have_dri_h" = yes -a \
97                "$have_sarea_h" = yes -a \
98                "$have_dristruct_h" = yes; then
99		DRI="yes"
100	else
101		DRI="no"
102	fi
103fi
104AC_MSG_RESULT([$DRI])
105
106AM_CONDITIONAL(DRI, test x$DRI = xyes)
107if test "$DRI" = yes; then
108	PKG_CHECK_MODULES(DRI, [libdrm >= 2.2 xf86driproto])
109        AC_DEFINE(XF86DRI,1,[Enable DRI driver support])
110        AC_DEFINE(XF86DRI_DEVEL,1,[Enable developmental DRI driver support])
111fi
112
113# Note that this is sort of inverted from drivers/ati/Imakefile in
114# the monolith.  We test for foo, not for !foo (i.e. ATMISC_CPIO, not
115# ATIMISC_AVOID_CPIO), but the defines are negative.  So beware.  Oh yeah,
116# TV_OUT is the special case where it's a positive define, not AVOID_TV_OUT.
117
118# AVOID_CPIO: Only x86, amd64, and alpha are cool with CPIO.  It needs a
119# little-endian, undirected PIO space of at least 64kB.
120# AVOID_DGA: ???
121# ATI_TV_OUT: This only works on x86.
122
123ATIMISC_CPIO=no
124ATIMISC_DGA=yes
125ATIMISC_TV_OUT=no
126
127case $host_cpu in
128  i*86)
129    ATIMISC_TV_OUT=yes
130    ATIMISC_CPIO=yes
131    ;;
132  x86_64|amd64|alpha|ia64)
133    ATIMISC_CPIO=yes
134    ;;
135  sparc)
136    ATIMISC_DGA=no
137    ;;
138  *)
139    ;;
140esac
141
142AC_MSG_CHECKING([whether to include PIO support])
143AM_CONDITIONAL(ATIMISC_CPIO, test "x$ATIMISC_CPIO" = xyes)
144if test "x$ATIMISC_CPIO" = xyes; then
145	AC_MSG_RESULT([yes, PIO])
146else
147	AC_DEFINE(AVOID_CPIO, 1, [Avoid PIO and use MMIO for atimisc.])
148	AC_MSG_RESULT([no, MMIO])
149fi
150
151AC_MSG_CHECKING([whether to include DGA support])
152AC_MSG_RESULT([$ATIMISC_DGA])
153AM_CONDITIONAL(ATIMISC_DGA, test "x$ATIMISC_DGA" = xyes)
154if ! test "x$ATIMISC_DGA" = xyes; then
155	AC_DEFINE(AVOID_DGA, 1, [Do not build DGA support.])
156fi
157
158AC_MSG_CHECKING([whether to include TV Out support])
159AC_MSG_RESULT([$ATIMISC_TV_OUT])
160AM_CONDITIONAL(ATIMISC_TV_OUT, test "x$ATIMISC_TV_OUT" = xyes)
161if test "x$ATIMISC_TV_OUT" = xyes; then
162	AC_DEFINE(TV_OUT, 1, [Build TV-Out support for atimisc.])
163fi
164
165AC_DEFINE(USE_XAA, 1, [Build support for XAA])
166
167# Properly handle EXA.
168AC_MSG_CHECKING([whether to enable EXA support])
169if test "x$EXA" = xyes; then
170        AC_MSG_RESULT(yes)
171
172        SAVE_CPPFLAGS="$CPPFLAGS"
173        CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
174        AC_CHECK_HEADER(exa.h,
175                       [have_exa_h="yes"], [have_exa_h="no"])
176        CPPFLAGS="$SAVE_CPPFLAGS"
177else
178        AC_MSG_RESULT(no)
179fi 
180
181SAVE_CPPFLAGS="$CPPFLAGS"
182CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
183if test "x$have_exa_h" = xyes; then
184        AC_MSG_CHECKING([whether EXA version is at least 2.0.0])
185        AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
186#include "exa.h"
187#if EXA_VERSION_MAJOR < 2
188#error OLD EXA!
189#endif
190                          ]])],
191                          [USE_EXA=yes],
192                          [USE_EXA=no])
193        AC_MSG_RESULT($USE_EXA)
194
195        if test "x$USE_EXA" = xyes; then
196                AC_DEFINE(USE_EXA, 1, [Build support for Exa])
197        fi
198fi
199
200AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
201	      [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
202	      [#include "xorg-server.h"])
203
204CPPFLAGS="$SAVE_CPPFLAGS"
205
206AM_CONDITIONAL(USE_EXA, test "x$USE_EXA" = xyes)
207
208if test "x$XSERVER_LIBPCIACCESS" = xyes; then
209    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
210    XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
211fi
212AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
213
214AC_SUBST([XORG_CFLAGS])
215AC_SUBST([DRI_CFLAGS])
216AC_SUBST([moduledir])
217
218DRIVER_NAME=mach64
219AC_SUBST([DRIVER_NAME])
220
221XORG_MANPAGE_SECTIONS
222XORG_RELEASE_VERSION
223XORG_CHECK_LINUXDOC
224XORG_CHANGELOG
225
226AC_MSG_NOTICE(
227[Please change the Driver line in xorg.conf from "ati" to "mach64"]
228[ or install the ati wrapper as well:]
229[    git://anongit.freedesktop.org/git/xorg/driver/xf86-video-ati]
230)
231
232AC_OUTPUT([
233	Makefile
234	src/Makefile
235	man/Makefile
236])
237