1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-siliconmotion],
26        [1.7.10],
27        [https://gitlab.freedesktop.org/xorg/driver/xf86-video-siliconmotion/issues],
28        [xf86-video-siliconmotion])
29
30# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
31m4_ifndef([XORG_MACROS_VERSION],
32          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
33XORG_MACROS_VERSION(1.8)
34XORG_DEFAULT_OPTIONS
35
36AC_CONFIG_SRCDIR([Makefile.am])
37AC_CONFIG_HEADERS([config.h])
38AC_CONFIG_AUX_DIR(.)
39
40# Initialize Automake
41AM_INIT_AUTOMAKE([foreign dist-xz])
42
43# Initialize libtool
44AC_DISABLE_STATIC
45AC_PROG_LIBTOOL
46
47AH_TOP([#include "xorg-server.h"])
48
49# Define a configure option for an alternate module directory
50AC_ARG_WITH(xorg-module-dir,
51            AS_HELP_STRING([--with-xorg-module-dir=DIR],
52                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
53            [moduledir="$withval"],
54            [moduledir="$libdir/xorg/modules"])
55
56# Store the list of server defined optional extensions in REQUIRED_MODULES
57XORG_DRIVER_CHECK_EXT(XV, videoproto)
58XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
59
60# Obtain compiler/linker options for the driver dependencies
61PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto $REQUIRED_MODULES])
62PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
63                  HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
64                  HAVE_XEXTPROTO_71="no")
65AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
66
67# Checks for libraries.
68SAVE_CPPFLAGS="$CPPFLAGS"
69CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
70AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
71              [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
72              [#include "xorg-server.h"])
73AC_CHECK_HEADER(xf86Modes.h,
74		[XMODES=yes], [XMODES=no], [#include "xorg-server.h"])
75CPPFLAGS="$SAVE_CPPFLAGS"
76
77if test "x$XSERVER_LIBPCIACCESS" = xyes; then
78    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
79fi
80AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
81AM_CONDITIONAL(XMODES, test "x$XMODES" = xyes)
82
83if test "x$XMODES" = xyes; then
84    AC_DEFINE(HAVE_XMODES, 1, [X server has new mode code])
85fi
86AC_ARG_ENABLE(xaa,
87              AS_HELP_STRING([--enable-xaa],
88                             [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
89              [XAA="$enableval"],
90              [XAA=auto])
91if test "x$XAA" != xno; then
92        save_CFLAGS=$CFLAGS
93        save_CPPFLAGS=$CPPFLAGS
94        CFLAGS=$XORG_CFLAGS
95        CPPFLAGS="$XORG_CFLAGS"
96        AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
97        CFLAGS=$save_CFLAGS
98        CPPFLAGS=$save_CPPFLAGS
99fi
100AC_MSG_CHECKING([whether to include XAA support])
101AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
102AC_MSG_RESULT([$XAA])
103
104AC_SUBST([moduledir])
105
106DRIVER_NAME=siliconmotion
107AC_SUBST([DRIVER_NAME])
108
109AC_CONFIG_FILES([
110                Makefile
111                src/Makefile
112                man/Makefile
113])
114AC_OUTPUT
115