1# generated files 
2rules_compat_generated = []
3
4layout_mappings = files('layoutsMapping.lst')
5variant_mappings = files('variantsMapping.lst')
6map_variants_py = find_program('map-variants.py')
7
8ml_s_file = 'base.ml_s.part'
9ml_s = custom_target(ml_s_file,
10                     build_by_default: true,
11                     command: [
12                         map_variants_py,
13                         '--want=mls',
14                         '@OUTPUT@',
15                         layout_mappings,
16                         variant_mappings,
17                     ],
18                     output: ml_s_file,
19                     install: false)
20rules_compat_generated += [ml_s]
21
22# base.mlv_s.part and friends
23mlv_s_file = 'base.mlv_s.part'
24mlv_s = custom_target(mlv_s_file,
25                     build_by_default: true,
26                     command: [
27                         map_variants_py,
28                         '--want=mlvs',
29                         '@OUTPUT@',
30                         variant_mappings,
31                     ],
32                     output: mlv_s_file,
33                     install: false)
34rules_compat_generated += [mlv_s]
35
36foreach lvl: [1, 2, 3, 4]
37    # base.ml1_s.part and friends
38    ml_s_file = 'base.ml@0@_s.part'.format(lvl)
39    ml_s = custom_target(ml_s_file,
40                         build_by_default: true,
41                         command: [
42                             map_variants_py,
43                             '--want=mls',
44                             '--number=@0@'.format(lvl),
45                             '@OUTPUT@',
46                             layout_mappings,
47                             variant_mappings,
48                         ],
49                         output: ml_s_file,
50                         install: false)
51    rules_compat_generated += [ml_s]
52
53    # base.ml1v1_s.part and friends
54    mlv_s_file = 'base.ml@0@v@0@_s.part'.format(lvl)
55    mlv_s = custom_target(mlv_s_file,
56                         build_by_default: true,
57                         command: [
58                             map_variants_py,
59                             '--want=mlvs',
60                             '--number=@0@'.format(lvl),
61                             '@OUTPUT@',
62                             variant_mappings,
63                         ],
64                         output: mlv_s_file,
65                         install: false)
66    rules_compat_generated += [mlv_s]
67endforeach
68
69# Non-generated files
70others = [
71    'base.lists.part',
72    'base.lv_c.part',
73    'base.l1v1_c.part',
74    'base.l2v2_c.part',
75    'base.l3v3_c.part',
76    'base.l4v4_c.part',
77    'base.o_s.part',
78]
79foreach o: others
80    configure_file(output: o,
81                   input: o,
82                   copy: true,
83                   install: false)
84endforeach
85