Home | History | Annotate | Line # | Download | only in string
strlen.S revision 1.2.2.1 
      1 /* $NetBSD: strlen.S,v 1.2.2.1 2018/09/06 06:51:32 pgoyette Exp $ */
      2 
      3 /*-
      4  * Copyright (c) 2014 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to The NetBSD Foundation
      8  * by Matt Thomas of 3am Software Foundry.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     29  * POSSIBILITY OF SUCH DAMAGE.
     30  */
     31 
     32 #include <machine/asm.h>
     33 
     34 RCSID("$NetBSD: strlen.S,v 1.2.2.1 2018/09/06 06:51:32 pgoyette Exp $")
     35 
     36 #ifdef STRNLEN
     37 #define FUNCNAME	strnlen
     38 /* LINTSTUB: size_t strnlen(const char *, size_t); */
     39 #else
     40 #define FUNCNAME	strlen
     41 /* LINTSTUB: size_t strlen(const char *); */
     42 #endif
     43 
     44 #define	MASK8_0x01	0x0101010101010101
     45 #define	MASK8_0x7f	0x7f7f7f7f7f7f7f7f
     46 
     47 ENTRY(FUNCNAME)
     48 	mov	x4, x0			/* need x0 for return */
     49 	add	x9, x0, #8		/* start + dword */
     50 	bic	x9, x9, #7		/* and aligned */
     51 #ifdef STRNLEN
     52 	adds	x10, x0, x1		/* x10 = s + maxlen */
     53 	b.cc	1f			/* if go past, */
     54 	mvn	x10, xzr		/* set limit 0xffffffffffffffff */
     55 1:
     56 #endif
     57 	mov	x11, #MASK8_0x01	/* test mask */
     58 
     59 	ands	x3, x4, #7		/* extract alignment */
     60 	neg	x0, x3			/* alignment fixup */
     61 	b.eq	.Lstrlen_dword_loop	/* already dword aligned */
     62 
     63 	/*
     64 	 * Load the dword containing the leading bytes.  Make sure bytes
     65 	 * before the data won't match as NUL.
     66 	 */
     67 	add	x4, x4, x0		/* make dword aligned */
     68 	ldr	x7, [x4], #8		/* load dword */
     69 	lsl	x3, x3, #3		/* convert bytes to bits */
     70 #ifdef __AARCH64EB__
     71 	lsr	x5, x11, x3		/* make mask for BE */
     72 #else
     73 	lsl	x5, x11, x3		/* make mask for LE */
     74 #endif
     75 	eor	x5, x5, x11		/* invert mask */
     76 	orr	x7, x7, x5		/* prevent NULs */
     77 	b	.Lstrlen_dword_loop_noload
     78 
     79 .Lstrlen_dword_loop:
     80 #ifdef STRNLEN
     81 	cmp	x4, x10
     82 	b.hs	.Lstrlen_done
     83 #endif
     84 	ldr	x7, [x4], #8		/* load dword */
     85 .Lstrlen_dword_loop_noload:
     86 	/*
     87 	 * Use the formula (X - 1) & ~(X | 0x7f) to find NUL bytes.
     88 	 * Any NUL byte found will be replaced by 0x80 otherwise any byte
     89 	 * will be replaced by 0x00.
     90 	 */
     91 	sub	x6, x7, x11		/* a = X - 1 */
     92 	orr	x7, x7, #MASK8_0x7f	/* b = X | 0x7f */
     93 	bic	x6, x6, x7		/* a & ~b */
     94 	cbz	x6, .Lstrlen_dword_loop	/* no NULs so get next dword */
     95 
     96 	/*
     97 	 * We know there is a NUL in this dword.  Use clz to find it.
     98 	 */
     99 #ifdef __AARCH64EL__
    100 	rev	x6, x6			/* convert to BE */
    101 #endif
    102 	clz	x6, x6			/* find null byte */
    103 	add	x0, x0, x6, lsr #3	/* add offset to the length */
    104 
    105 	add	x0, x0, x4		/* add end to the length */
    106 	sub	x0, x0, x9		/* subtract start from the length */
    107 #ifdef STRNLEN
    108 	cmp	x0, x1			/* did we go too far? */
    109 	csel	x0, x0, x1, lo		/* yes, return max length */
    110 #endif
    111 	ret
    112 #ifdef STRNLEN
    113 .Lstrlen_done:
    114 	mov	x0, x1
    115 	ret
    116 #endif
    117 END(FUNCNAME)
    118