atomic_or_32.S revision 1.4 
1/*	$NetBSD: atomic_or_32.S,v 1.4 2013/08/10 19:59:21 matt Exp $	*/
2/*-
3 * Copyright (c) 2008 The NetBSD Foundation, Inc.
4 * All rights reserved.
5 *
6 * This code is derived from software contributed to The NetBSD Foundation
7 * by Matt Thomas <matt@3am-software.com>
8 *
9 * Redistribution and use in source and binary forms, with or without
10 * modification, are permitted provided that the following conditions
11 * are met:
12 * 1. Redistributions of source code must retain the above copyright
13 *    notice, this list of conditions and the following disclaimer.
14 * 2. Redistributions in binary form must reproduce the above copyright
15 *    notice, this list of conditions and the following disclaimer in the
16 *    documentation and/or other materials provided with the distribution.
17 *
18 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
19 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
20 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
21 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
22 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
23 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
24 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
25 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
26 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
27 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
28 * POSSIBILITY OF SUCH DAMAGE.
29 */
30
31#include "atomic_op_asm.h"
32
33#ifdef _ARM_ARCH_6
34
35ENTRY_NP(_atomic_or_32)
361:	ldrex	r3, [r0]		/* load old value (to be returned) */
37	orr	r3, r3, r1		/* calculate new value */
38	strex	r2, r3, [r0]		/* try to store */
39	cmp	r2, #0			/*   succeed? */
40	bne	1b			/*     no, try again */
41#ifdef _ARM_ARCH_7
42	dmb
43#else
44	mcr	p15, 0, r2, c7, c10, 5	/* data memory barrier */
45#endif
46	RET				/* return old value */
47END(_atomic_or_32)
48
49ATOMIC_OP_ALIAS(atomic_or_32,_atomic_or_32)
50ATOMIC_OP_ALIAS(atomic_or_uint,_atomic_or_32)
51ATOMIC_OP_ALIAS(atomic_or_ulong,_atomic_or_32)
52STRONG_ALIAS(_atomic_or_uint,_atomic_or_32)
53STRONG_ALIAS(_atomic_or_ulong,_atomic_or_32)
54
55ENTRY_NP(_atomic_or_32_nv)
56	mov	ip, r0			/* need r0 for return value */
571:	ldrex	r0, [ip]		/* load old value */
58	orr	r0, r0, r1		/* calculate new value (return value) */
59	strex	r2, r0, [ip]		/* try to store */
60	cmp	r2, #0			/*   succeed? */
61	bne	1b			/*     no, try again? */
62#ifdef _ARM_ARCH_7
63	dmb
64#else
65	mcr	p15, 0, r2, c7, c10, 5	/* data memory barrier */
66#endif
67	RET				/* return new value */
68END(_atomic_or_32_nv)
69
70ATOMIC_OP_ALIAS(atomic_or_32_nv,_atomic_or_32_nv)
71ATOMIC_OP_ALIAS(atomic_or_uint_nv,_atomic_or_32_nv)
72ATOMIC_OP_ALIAS(atomic_or_ulong_nv,_atomic_or_32_nv)
73STRONG_ALIAS(_atomic_or_uint_nv,_atomic_or_32_nv)
74STRONG_ALIAS(_atomic_or_ulong_nv,_atomic_or_32_nv)
75
76#endif /* _ARM_ARCH_6 */
77