Home | History | Annotate | Line # | Download | only in string
strcat_naive.S revision 1.2 
      1 /*-
      2  * Copyright (c) 2013 The NetBSD Foundation, Inc.
      3  * All rights reserved.
      4  *
      5  * This code is derived from software contributed to The NetBSD Foundation
      6  * by Matt Thomas of 3am Software Foundry.
      7  *
      8  * Redistribution and use in source and binary forms, with or without
      9  * modification, are permitted provided that the following conditions
     10  * are met:
     11  * 1. Redistributions of source code must retain the above copyright
     12  *    notice, this list of conditions and the following disclaimer.
     13  * 2. Redistributions in binary form must reproduce the above copyright
     14  *    notice, this list of conditions and the following disclaimer in the
     15  *    documentation and/or other materials provided with the distribution.
     16  *
     17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     27  * POSSIBILITY OF SUCH DAMAGE.
     28  */
     29 
     30 #include <machine/asm.h>
     31 
     32 RCSID("$NetBSD: strcat_naive.S,v 1.2 2013/08/19 02:54:02 matt Exp $")
     33 
     34 ENTRY(strcat)
     35 	mov	ip, r0			/* need to preserve r0 */
     36 #if defined(__thumb__)
     37 1:	ldrb	r2, [r0]		/* load next byte */
     38 	adds	r0, r0, #1		/* advance */
     39 #if defined(_ARM_ARCH_T2)
     40 	cbnz	r2, 1b			/* was it a NUL?  no, get next byte */
     41 #else
     42 	cmp	r2, #0			/* was it a NUL? */
     43 	bne	1b			/*   no, get next byte */
     44 #endif
     45 	subs	r0, r0, #1		/* back up one to the NUL */
     46 	subs	r1, r1, r0		/* save one increment */
     47 2:	ldrb	r2, [r1, r0]		/* load next byte from append */
     48 	strb	r2, [r0]		/* store it */
     49 	adds	r0, r0, #1		/* advance */
     50 #if defined(_ARM_ARCH_T2)
     51 	cbnz	r2, 1b			/* was it a NUL?  no, get next byte */
     52 #else
     53 	cmp	r2, #0			/* was it a NUL? */
     54 	bne	2b			/*   no, get next byte */
     55 #endif
     56 	mov	r0, ip			/* restore dst address */
     57 	RET				/* return */
     58 #else /* !__thumb__ */
     59 	mov	ip, r0			/* need to preserve r0 */
     60 1:	ldrb	r2, [ip], #1		/* load next byte */
     61 	teq	r2, #0			/* was it a NUL? */
     62 	bne	1b			/*   no, get next byte */
     63 	sub	ip, ip, #1		/* back up one to the NUL */
     64 2:	ldrb	r2, [r1], #1		/* load next byte from append */
     65 	strb	r2, [ip], #1		/* store it */
     66 	teq	r2, #0			/* was it a NUL? */
     67 	bne	2b			/*   no, get next byte */
     68 	RET				/* return */
     69 #endif
     70 END(strcat)
     71