Home | History | Annotate | Line # | Download | only in string
strcpy_naive.S revision 1.1 
      1 /*-
      2  * Copyright (c) 2013 The NetBSD Foundation, Inc.
      3  * All rights reserved.
      4  *
      5  * This code is derived from software contributed to The NetBSD Foundation
      6  * by Matt Thomas of 3am Software Foundry.
      7  *
      8  * Redistribution and use in source and binary forms, with or without
      9  * modification, are permitted provided that the following conditions
     10  * are met:
     11  * 1. Redistributions of source code must retain the above copyright
     12  *    notice, this list of conditions and the following disclaimer.
     13  * 2. Redistributions in binary form must reproduce the above copyright
     14  *    notice, this list of conditions and the following disclaimer in the
     15  *    documentation and/or other materials provided with the distribution.
     16  *
     17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     27  * POSSIBILITY OF SUCH DAMAGE.
     28  */
     29 #include <machine/asm.h>
     30 
     31 RCSID("$NetBSD: strcpy_naive.S,v 1.1 2013/01/08 13:14:54 matt Exp $")
     32 
     33 /*
     34  * These are "naive" versions of the str*cpy routines designed to be simple
     35  * and small.
     36  */
     37 
     38 #if defined(STRLCPY)
     39 /* LINTSTUB: size_t strlcpy(char *, const char *, size_t) */
     40 ENTRY(strlcpy)
     41 	add	ip, r1, #1		/* save src pointer (+ NUL) */
     42 	subs	r2, r2, #1		/* make sure there's room for a NUL */
     43 	blt	3f			/*   no room, do the strlen */
     44 	add	r2, r2, r0		/* get end of dst */
     45 1:	cmp	r0, r2			/* room for another char? */
     46 	beq	2f			/*   no, write NUL and do the strlen */
     47 	ldrb	r3, [r1], #1		/* read a byte */
     48 	strb	r3, [r0], #1		/* write a byte */
     49 	teq	r3, #0			/* was it a NUL? */
     50 	bne	1b			/*   no, do next byte */
     51 	b	4f			/*   yes, end of string, so return */
     52 2:	mov	r3, #0			/* NUL */
     53 	strb	r3, [r0], #1		/* write to end of string */
     54 3:	ldrb	r3, [r1], #1		/* read a byte */
     55 	teq	r3, #0			/* was it a NUL? */
     56 	bne	3b			/*   no, get next byte */
     57 4:	sub	r0, r1, ip 		/* return length of src string */
     58 	RET
     59 END(strlcpy)
     60 #elif defined(STRNCPY)
     61 /* LINTSTUB: char * strncpy(char *, const char *, size_t) */
     62 ENTRY(strncpy)
     63 	mov	ip, r0			/* we want to preserve r0 */
     64 	add	r2, r2, r0		/* get end of dst buffer */
     65 1:	cmp	ip, r2			/* are at the end of dst already? */
     66 	RETc(eq)			/*   yes, just return. */
     67 	ldrb	r3, [r1], #1		/* read a byte */
     68 	strb	r3, [ip], #1		/* write a byte */
     69 	teq	r3, #0			/* was it a NUL? */
     70 	bne	1b			/*   no, try next byte */
     71 2:	cmp	ip, r2			/* are at the end of dst already? */
     72 	strltb	r3, [ip], #1		/*   no, write a NUL */
     73 	blt	2b			/*       until dst is filled */
     74 3:	RET				/* return dst pointer */
     75 END(strncpy)
     76 #else
     77 /* LINTSTUB: char * strcpy(char *, const char *) */
     78 ENTRY(strcpy)
     79 	mov	ip, r0			/* we want to preserve r0 */
     80 1:	ldrb	r3, [r1], #1		/* read a byte */
     81 	strb	r3, [ip], #1		/* write a byte */
     82 	teq	r3, #0			/* was it a NUL? */
     83 	bne	1b			/*   no, try next byte */
     84 	RET				/* return dst pointer */
     85 END(strcpy)
     86 #endif
     87