Home | History | Annotate | Line # | Download | only in string
ffs.S revision 1.6.26.3 
      1 /*	$NetBSD: ffs.S,v 1.6.26.3 2020/04/21 19:37:44 martin Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 1990 The Regents of the University of California.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to Berkeley by
      8  * the Systems Programming Group of the University of Utah Computer
      9  * Science Department.
     10  *
     11  * Redistribution and use in source and binary forms, with or without
     12  * modification, are permitted provided that the following conditions
     13  * are met:
     14  * 1. Redistributions of source code must retain the above copyright
     15  *    notice, this list of conditions and the following disclaimer.
     16  * 2. Redistributions in binary form must reproduce the above copyright
     17  *    notice, this list of conditions and the following disclaimer in the
     18  *    documentation and/or other materials provided with the distribution.
     19  * 3. Neither the name of the University nor the names of its contributors
     20  *    may be used to endorse or promote products derived from this software
     21  *    without specific prior written permission.
     22  *
     23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     33  * SUCH DAMAGE.
     34  */
     35 
     36 #include <machine/asm.h>
     37 
     38 #if defined(LIBC_SCCS) && !defined(lint)
     39 #if 0
     40 	RCSID("from: @(#)ffs.s	5.1 (Berkeley) 5/12/90")
     41 #else
     42 	RCSID("$NetBSD: ffs.S,v 1.6.26.3 2020/04/21 19:37:44 martin Exp $")
     43 #endif
     44 #endif /* LIBC_SCCS and not lint */
     45 
     46 /* bit = ffs(value) */
     47 
     48 #ifdef _LIBC
     49 WEAK_ALIAS(__ffssi2,ffs)
     50 #else /* KERNEL */
     51 /*
     52  * Our in-kernel linker does not understand weak references, which
     53  * prevents modules depended on __ffssi2 from being loaded. Also,
     54  * we do not provide ffs(9) as a kernel routine. Let's rename it!
     55  */
     56 #define ffs __ffssi2
     57 #endif
     58 
     59 #if (!defined(__mc68010__) && !defined(__mcoldfire__)) || defined(__mcfisac__)
     60 
     61 ENTRY(ffs)
     62 	movl	4(%sp),%d0
     63 	movl	%d0,%d1
     64 	negl	%d0
     65 	andl	%d0,%d1
     66 	movql	#32,%d0
     67 #if defined(__mcfisac__)
     68 	ff1.l	%d1		| count leading zeros
     69 #else
     70 	bfffo	%d1{#0:#32},%d1
     71 #endif
     72 	subl	%d1,%d0
     73 	rts
     74 END(ffs)
     75 
     76 #elif defined(__mcoldfire__)
     77 
     78 ENTRY(ffs)
     79 	clrl	%d0
     80 	movl	4(%sp),%d1
     81 	jeq	.L2		| return 0 if 0
     82 .L1:
     83 	addql	#1,%d0
     84 	lsrl	#1,%d1		| shift low bit into carry
     85 	jcc	.L1		| keep looping while carry is clear.
     86 .L2:
     87 	rts
     88 END(ffs)
     89 
     90 #else	/* __mc68010__ */
     91 
     92 ENTRY(ffs)
     93 	movl	4(%sp),%d0
     94 	jeq	.L2
     95 	movql	#31,%d1
     96 .L1:
     97 	lsrl	#1,%d0
     98 	dbcs	%d1,.L1
     99 	movql	#32,%d0
    100 	subl	%d1,%d0
    101 .L2:
    102 	rts
    103 END(ffs)
    104 
    105 #endif	/* __mc68010__ */
    106