Home | History | Annotate | Line # | Download | only in string
memcpy.S revision 1.2.48.1 
      1 /*	$NetBSD: memcpy.S,v 1.2.48.1 2011/02/08 16:18:28 bouyer Exp $	*/
      2 /*-
      3  * Copyright (c) 1990, 1993
      4  *	The Regents of the University of California.  All rights reserved.
      5  *
      6  * Redistribution and use in source and binary forms, with or without
      7  * modification, are permitted provided that the following conditions
      8  * are met:
      9  * 1. Redistributions of source code must retain the above copyright
     10  *    notice, this list of conditions and the following disclaimer.
     11  * 2. Redistributions in binary form must reproduce the above copyright
     12  *    notice, this list of conditions and the following disclaimer in the
     13  *    documentation and/or other materials provided with the distribution.
     14  * 3. Neither the name of the University nor the names of its contributors
     15  *    may be used to endorse or promote products derived from this software
     16  *    without specific prior written permission.
     17  *
     18  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     28  * SUCH DAMAGE.
     29  */
     30 
     31 #include <machine/asm.h>
     32 
     33 /* .asciz "@(#)memcpy.s	8.1 (Berkeley) 6/4/93" */
     34 RCSID("$NetBSD: memcpy.S,v 1.2.48.1 2011/02/08 16:18:28 bouyer Exp $")
     35 
     36 /*
     37  * void *memcpy(dst, src, size)
     38  * returns dst
     39  *
     40  * This optimises the usual case (count < 65536) at the expense
     41  * of some extra memory references and branches when count >= 65536.
     42  */
     43 
     44 ENTRY(memcpy, 0)
     45 	movzwl	$65535,%r0	/* %r0 = 64K (needed below) */
     46 	movq	8(%ap),%r1	/* %r1 = src, %r2 = length */
     47 	movl	4(%ap),%r3	/* %r3 = dst */
     48 	cmpl	%r1,%r3
     49 	bgtru	1f		/* normal forward case */
     50 	beql	2f		/* equal, nothing to do */
     51 	addl2	%r2,%r1		/* overlaps iff src<dst but src+len>dst */
     52 	cmpl	%r1,%r3
     53 	bgtru	4f		/* overlapping, must move backwards */
     54 	subl2	%r2,%r1
     55 
     56 1:	/* move forward */
     57 	cmpl	%r2,%r0
     58 	bgtru	3f		/* stupid movc3 limitation */
     59 	movc3	%r2,(%r1),(%r3)	/* move it all */
     60 2:
     61 	movl	4(%ap),%r0	/* return original dst */
     62 	ret
     63 3:
     64 	subl2	%r0,12(%ap)	/* adjust length by 64K */
     65 	movc3	%r0,(%r1),(%r3)	/* move 64K */
     66 	movl	12(%ap),%r2
     67 	decw	%r0		/* from 0 to 65535 */
     68 	brb	1b		/* retry */
     69 
     70 4:	/* move backward */
     71 	addl2	%r2,%r3
     72 5:
     73 	cmpl	%r2,%r0
     74 	bgtru	6f		/* stupid movc3 limitation */
     75 	subl2	%r2,%r1
     76 	subl2	%r2,%r3
     77 	movc3	%r2,(%r1),(%r3)	/* move it all */
     78 	movl	4(%ap),%r0	/* return original dst */
     79 	ret
     80 6:
     81 	subl2	%r0,12(%ap)	/* adjust length by 64K */
     82 	subl2	%r0,%r1
     83 	subl2	%r0,%r3
     84 	movc3	%r0,(%r1),(%r3)	/* move 64K */
     85 	movl	12(%ap),%r2
     86 	decw	%r0
     87 	subl2	%r0,%r1
     88 	subl2	%r0,%r3
     89 	brb	5b
     90 END(memcpy)
     91