Home | History | Annotate | Line # | Download | only in dist
configure.ac revision 1.1.1.21
      1 # Copyright (C) Internet Systems Consortium, Inc. ("ISC")
      2 #
      3 # SPDX-License-Identifier: MPL-2.0
      4 #
      5 # This Source Code Form is subject to the terms of the Mozilla Public
      6 # License, v. 2.0.  If a copy of the MPL was not distributed with this
      7 # file, you can obtain one at https://mozilla.org/MPL/2.0/.
      8 #
      9 # See the COPYRIGHT file distributed with this work for additional
     10 # information regarding copyright ownership.
     11 
     12 #
     13 # Defining the version in m4 requires a bit of dancing around,
     14 # so the strings are properly concatenated, as you can't use
     15 # a shell variable in AC_INIT
     16 #
     17 m4_define([bind_VERSION_MAJOR], 9)dnl
     18 m4_define([bind_VERSION_MINOR], 20)dnl
     19 m4_define([bind_VERSION_PATCH], 22)dnl
     20 m4_define([bind_VERSION_EXTRA], )dnl
     21 m4_define([bind_DESCRIPTION], [(Stable Release)])dnl
     22 m4_define([bind_SRCID], [m4_esyscmd_s([git rev-parse --short HEAD | cut -b1-7])])dnl
     23 m4_define([bind_PKG_VERSION], [[bind_VERSION_MAJOR.bind_VERSION_MINOR.bind_VERSION_PATCH]bind_VERSION_EXTRA])dnl
     24 
     25 #
     26 # Autoconf initialization
     27 #
     28 AC_INIT([BIND], bind_PKG_VERSION, [https://gitlab.isc.org/isc-projects/bind9/-/issues/new?issuable_template=Bug], [], [https://www.isc.org/downloads/])
     29 AC_PREREQ([2.69])
     30 
     31 AC_DEFINE([PACKAGE_VERSION_MAJOR], ["][bind_VERSION_MAJOR]["], [BIND 9 Major part of the version])
     32 AC_DEFINE([PACKAGE_VERSION_MINOR], ["][bind_VERSION_MINOR]["], [BIND 9 Minor part of the version])
     33 AC_DEFINE([PACKAGE_VERSION_PATCH], ["][bind_VERSION_PATCH]["], [BIND 9 Patch part of the version])
     34 AC_DEFINE([PACKAGE_VERSION_EXTRA], ["][bind_VERSION_EXTRA]["], [BIND 9 Extra part of the version])
     35 AC_DEFINE([PACKAGE_DESCRIPTION], [m4_ifnblank(bind_DESCRIPTION, [" ]bind_DESCRIPTION["], [])], [An extra string to print after PACKAGE_STRING])
     36 AC_DEFINE([PACKAGE_SRCID], ["][bind_SRCID]["], [A short hash from git])
     37 
     38 bind_CONFIGARGS="${ac_configure_args:-default}"
     39 AC_DEFINE_UNQUOTED([PACKAGE_CONFIGARGS], ["$bind_CONFIGARGS"], [Either 'defaults' or used ./configure options])
     40 
     41 AC_DEFINE([PACKAGE_BUILDER], ["make"], [make or Visual Studio])
     42 
     43 #
     44 # Get the Canonical System Type
     45 #
     46 AC_CANONICAL_BUILD
     47 AC_CANONICAL_HOST
     48 AC_CANONICAL_TARGET
     49 
     50 AC_CONFIG_SRCDIR([bin/named/main.c])
     51 AM_INIT_AUTOMAKE([1.14 tar-pax foreign subdir-objects dist-xz no-dist-gzip -Wall -Werror])
     52 AM_SILENT_RULES([yes])
     53 AM_EXTRA_RECURSIVE_TARGETS([test unit doc])
     54 
     55 AC_CONFIG_HEADERS([config.h])
     56 AC_CONFIG_MACRO_DIR([m4])
     57 
     58 #
     59 # Enable maintainer mode by default only when building from git repository
     60 # and not cross compling
     61 #
     62 AS_IF([test "$cross_compiling" = no],
     63       [AM_MAINTAINER_MODE(m4_ifset([bind_SRCID],[enable],[disable]))],
     64       [AM_MAINTAINER_MODE([disable])])
     65 
     66 #
     67 # Enable system extensions to C and POSIX
     68 #
     69 AC_USE_SYSTEM_EXTENSIONS
     70 
     71 #
     72 # Compiler compatibility flags
     73 #
     74 m4_version_prereq([2.70],
     75 		  [AC_PROG_CC],
     76 		  [AC_PROG_CC_C99])
     77 AC_PROG_CPP_WERROR
     78 
     79 #
     80 # Find build compiler when cross compiling
     81 #
     82 AX_PROG_CC_FOR_BUILD
     83 
     84 #
     85 # Find the machine's endian flavor.
     86 #
     87 AC_C_BIGENDIAN
     88 
     89 #
     90 # Enable large file support
     91 #
     92 AC_SYS_LARGEFILE
     93 AC_FUNC_FSEEKO
     94 
     95 # Enable RFC 3542 APIs on macOS
     96 AC_DEFINE([__APPLE_USE_RFC_3542], [1], [Select RFC3542 IPv6 API on macOS])
     97 
     98 AC_PROG_MAKE_SET
     99 
    100 # Checks for programs.
    101 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) # call AM_PROG_AR only if available
    102 
    103 AC_PROG_INSTALL
    104 AC_PROG_LN_S
    105 AX_POSIX_SHELL
    106 AC_PROG_MKDIR_P
    107 
    108 # Initialize libtool
    109 LT_INIT([disable-static dlopen pic-only])
    110 
    111 DLOPEN_LIBS="$lt_cv_dlopen_libs"
    112 AC_SUBST(DLOPEN_LIBS)
    113 
    114 AS_IF([test "$enable_static" != "no" && test "$enable_developer" != "yes"],
    115       [AC_MSG_ERROR([Static linking is not supported as it disables dlopen() and certain security features (e.g. RELRO, ASLR)])])
    116 
    117 
    118 #
    119 # Set the default CFLAGS, CPPFLAGS, and LDFLAGS
    120 #
    121 STD_CFLAGS="-Wall -Wextra -Wwrite-strings -Wpointer-arith -Wno-missing-field-initializers -Wformat -Wshadow"
    122 
    123 # These should be always errors
    124 STD_CFLAGS="$STD_CFLAGS -Werror=implicit-function-declaration -Werror=missing-prototypes -Werror=format-security -Werror=parentheses -Werror=implicit -Werror=strict-prototypes -Werror=vla"
    125 
    126 # Disable false positives generated by GCC 11+ and ASAN
    127 AC_COMPILE_IFELSE(
    128   [AC_LANG_PROGRAM([[]],
    129 		   [[#if __GNUC__ >= 11 && defined(__SANITIZE_ADDRESS__)
    130 		     #error Address Sanitizer enabled
    131 		     #endif
    132 		    ]])],
    133   [],
    134   [STD_CFLAGS="$STD_CFLAGS -Wno-stringop-overread"])
    135 
    136 # Silence GCC 11.1+ note about the changed alignment, see GL #4841
    137 AS_CASE([$target_cpu],[i?86],[STD_CFLAGS="$STD_CFLAGS -Wno-psabi"])
    138 
    139 STD_LDFLAGS=""
    140 
    141 # ... except in test code
    142 TEST_CFLAGS="-Wno-vla"
    143 
    144 # Fortify the sources by default (we undefine the macro first in case
    145 # the compiler has a different built-in setting)
    146 STD_CPPFLAGS="-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
    147 
    148 #
    149 # Additional compiler settings.
    150 #
    151 AX_CHECK_COMPILE_FLAG([-fno-strict-aliasing],
    152 		      [STD_CFLAGS="$STD_CFLAGS -fno-strict-aliasing"])
    153 # Clang only issues a warning so use -Werror to force a error.
    154 AX_CHECK_COMPILE_FLAG([-Werror -fno-delete-null-pointer-checks],
    155 		      [STD_CFLAGS="$STD_CFLAGS -fno-delete-null-pointer-checks"])
    156 AX_CHECK_COMPILE_FLAG([-fdiagnostics-show-option],
    157 		      [STD_CFLAGS="$STD_CFLAGS -fdiagnostics-show-option"])
    158 
    159 AX_CHECK_LINK_FLAG([-Wl,--export-dynamic],
    160 		   [STD_LDFLAGS="$STD_LDFLAGS -Wl,--export-dynamic"])
    161 
    162 host_macos=no
    163 AS_CASE([$host],[*-darwin*],[host_macos=yes])
    164 AM_CONDITIONAL([HOST_MACOS], [test "$host_macos" = "yes"])
    165 
    166 #
    167 # Change defaults for developers if not explicity set.
    168 # Needs to be before the option is tested.
    169 #
    170 # [pairwise: --enable-developer, --disable-developer]
    171 AC_ARG_ENABLE([developer],
    172 	      [AS_HELP_STRING([--enable-developer],
    173 			      [enable developer build settings])])
    174 
    175 AS_IF([test "$enable_developer" = "yes"],
    176       [DEVELOPER_MODE=yes
    177        STD_CPPFLAGS="$STD_CPPFLAGS -DISC_MEM_DEFAULTFILL=1 -DISC_MEM_TRACKLINES=1 -DISC_LIST_CHECKINIT=1 -DISC_STATS_CHECKUNDERFLOW=1 -DDNS_RBTDB_STRONG_RWLOCK_CHECK=1 -DISC_MUTEX_ERROR_CHECK=1"
    178        test "${enable_fixed_rrset+set}" = set || enable_fixed_rrset=yes
    179        test "${enable_querytrace+set}" = set || enable_querytrace=yes
    180        test "${with_cmocka+set}" = set || with_cmocka=yes
    181        test "${with_zlib+set}" = set || with_zlib=yes
    182        test "${enable_warn_error+set}" = set || enable_warn_error=yes
    183        ])
    184 
    185 AC_SUBST([DEVELOPER_MODE])
    186 AC_SUBST([STD_CFLAGS])
    187 AC_SUBST([STD_CPPFLAGS])
    188 AC_SUBST([STD_LDFLAGS])
    189 AC_SUBST([TEST_CFLAGS])
    190 
    191 # [pairwise: --enable-warn-error, --disable-warn-error]
    192 AC_ARG_ENABLE([warn_error],
    193 	      [AS_HELP_STRING([--enable-warn-error],
    194 			      [turn on -Werror when compiling])],
    195 	      [],[enable_warn_error=no])
    196 AS_IF([test "$enable_warn_error" = "yes"],
    197       [STD_CFLAGS="$STD_CFLAGS -Werror"])
    198 
    199 #
    200 # Use pkg-config
    201 #
    202 
    203 PKG_PROG_PKG_CONFIG
    204 AS_IF([test -z "$PKG_CONFIG"],
    205       [AC_MSG_ERROR([The pkg-config script could not be found or is too old.])])
    206 
    207 #
    208 # Pick Userspace-RCU flavor (developer only option)
    209 #
    210 # [pairwise: skip]
    211 AC_ARG_WITH([liburcu],
    212 	    [AS_HELP_STRING([--with-liburcu=FLAVOR],
    213 			     [Build with Userspace-RCU variant (developer-only option) (membarrier|qsbr|mb|bp) [default=membarrier]]))],
    214 	    [], [with_liburcu=membarrier])
    215 
    216 AC_MSG_CHECKING([liburcu flavor])
    217 AS_CASE([$with_liburcu],
    218 	[membarrier],
    219 	[RCU_FLAVOR="liburcu"
    220 	 AC_DEFINE([RCU_MEMBARRIER], [1], [Build with membarrier Userspace-RCU flavor])],
    221 	[qsbr],
    222 	[RCU_FLAVOR="liburcu-qsbr"
    223 	 AC_DEFINE([RCU_QSBR], [1], [Build with QSBR Userspace-RCU flavor])],
    224 	[mb],
    225 	[RCU_FLAVOR="liburcu-mb"
    226 	 AC_DEFINE([RCU_MB], [1], [Build with mb Userspace-RCU flavor])],
    227 	[bp],
    228 	[RCU_FLAVOR="liburcu-bp"
    229 	 AC_DEFINE([RCU_BP], [1], [Build with bulletproof Userspace-RCU flavor])],
    230 	[AC_MSG_ERROR([Invalid Userspace-RCU flavor picked])])
    231 
    232 AS_IF([test "$with_liburcu" != "membarrier" && test "$enable_developer" != "yes"],
    233       [AC_MSG_ERROR([Changing Userspace-RCU variant is allowed only in developer mode])])
    234 
    235 AC_MSG_RESULT([$RCU_FLAVOR])
    236 
    237 #
    238 # liburcu << v0.13.0 didn't add -lurcu-common and some toolchains would
    239 # not add it automatically - we need to add it explicitly in such case.
    240 #
    241 PKG_CHECK_MODULES([LIBURCU], [$RCU_FLAVOR >= 0.13.0 liburcu-cds >= 0.13.0], [],
    242 		  [PKG_CHECK_MODULES([LIBURCU], [$RCU_FLAVOR >= 0.10.0 liburcu-cds >= 0.10.0],
    243 				     [LIBURCU_LIBS="$LIBURCU_LIBS -lurcu-common"])])
    244 
    245 AC_DEFINE_UNQUOTED([RCU_FLAVOR], ["$RCU_FLAVOR"], [Chosen Userspace-RCU flavor])
    246 
    247 PKG_CHECK_VERSION([RCU_VERSION], [$RCU_FLAVOR])
    248 AC_DEFINE_UNQUOTED([RCU_VERSION], ["$RCU_VERSION"], [Compile-time Userspace-RCU version])
    249 
    250 CFLAGS="$CFLAGS $LIBURCU_CFLAGS"
    251 LIBS="$LIBS $LIBURCU_LIBS"
    252 
    253 #
    254 # Userspace-RCU inlining doesn't work for rcu_deference() with some combination
    255 # of C compiler and library version.
    256 #
    257 AC_MSG_CHECKING([whether we can inline small liburcu functions])
    258 AC_COMPILE_IFELSE(
    259   [AC_LANG_PROGRAM([[#define URCU_INLINE_SMALL_FUNCTIONS 1
    260 		     #include <urcu.h>]],
    261 		   [[struct opaque *a; struct opaque *b = rcu_dereference(a);]])],
    262   [AC_MSG_RESULT([yes])
    263    AC_DEFINE([URCU_INLINE_SMALL_FUNCTIONS], [1], [Inline small (less than 10 lines) functions])],
    264   [AC_MSG_RESULT([no])])
    265 
    266 # Fuzzing is not included in pairwise testing as fuzzing tools are
    267 # not present in the relevant Docker image.
    268 #
    269 # [pairwise: skip]
    270 AC_ARG_ENABLE([fuzzing],
    271 	      [AS_HELP_STRING([--enable-fuzzing=<afl|libfuzzer|ossfuzz>],
    272 			      [Enable fuzzing using American Fuzzy Lop or libFuzzer (default=no)])],
    273 	      [],
    274 	      [enable_fuzzing=no])
    275 
    276 AC_MSG_CHECKING([whether to enable fuzzing mode])
    277 AS_CASE([$enable_fuzzing],
    278 	[no],[AC_MSG_RESULT([no])],
    279 	[afl],[
    280 	  AC_MSG_RESULT([using AFL])
    281 	  AC_DEFINE([ENABLE_AFL], [1],
    282 		    [Define to enable American Fuzzy Lop test harness])
    283 	  STD_CFLAGS="$STD_CFLAGS -DFUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION=1"
    284 	  FUZZ_LOG_COMPILER="afl.sh"],
    285 	[libfuzzer],[
    286 	  AC_MSG_RESULT([using libFuzzer])
    287 	  STD_CFLAGS="$STD_CFLAGS -DFUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION=1 -fsanitize=fuzzer-no-link,address,undefined"
    288 	  LDFLAGS="$LDFLAGS -fsanitize=address,undefined"
    289 	  FUZZ_LDFLAGS="-fsanitize=fuzzer,address,undefined"
    290 	  FUZZ_LOG_COMPILER="libfuzzer.sh"],
    291 	[ossfuzz],[
    292 	    AC_MSG_RESULT([using OSS-Fuzz])
    293 	    FUZZ_LDFLAGS="$LIB_FUZZING_ENGINE"],
    294 	[*],[AC_MSG_ERROR([You need to explicitly select the fuzzer])])
    295 AM_CONDITIONAL([HAVE_FUZZ_LOG_COMPILER], [test -n "$FUZZ_LOG_COMPILER"])
    296 AC_SUBST([FUZZ_LOG_COMPILER])
    297 AC_SUBST([FUZZ_LDFLAGS])
    298 
    299 AS_IF([test "$enable_fuzzing" = "afl"],
    300       [AC_MSG_CHECKING("for AFL enabled compiler")
    301        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
    302 					  [#ifndef __AFL_COMPILER
    303 					   #error AFL compiler required
    304 					   #endif
    305 					  ])],
    306 			 [AC_MSG_RESULT([yes])],
    307 			 [AC_MSG_ERROR([set CC=afl-<gcc|clang> when --enable-fuzzing=afl is used])])
    308       ])
    309 
    310 #
    311 # Perl is optional; it is used only by some of the system test scripts.
    312 #
    313 AC_PATH_PROGS([PERL], [perl5 perl])
    314 AC_SUBST([PERL])
    315 AM_CONDITIONAL([HAVE_PERL], [test -n "$PERL"])
    316 
    317 #
    318 # Python is optional, it is used only by some of the system test scripts.
    319 #
    320 AM_PATH_PYTHON([3.10], [], [:])
    321 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != ":"])
    322 
    323 AC_PATH_PROGS([PYTEST], [pytest-3 py.test-3 pytest py.test pytest-pypy], [])
    324 AS_IF([test -z "$PYTEST"],
    325       [AC_MSG_WARN([pytest not found, some system tests will be skipped])])
    326 AC_SUBST([PYTEST])
    327 AM_CONDITIONAL([HAVE_PYTEST], [test -n "$PYTEST"])
    328 
    329 #
    330 # Optional utilities, only used by system tests.
    331 #
    332 AC_PATH_PROG([JQ], [jq])
    333 AC_PATH_PROG([XMLLINT], [xmllint])
    334 AC_PATH_PROG([XSLTPROC], [xsltproc])
    335 
    336 #
    337 # Using Solaris linker with gcc on Solaris breaks Thread Local Storage
    338 #
    339 AS_CASE([$host],
    340 	[*-solaris*],[
    341 	    AS_IF([test "$GCC" = "yes"],
    342 		  [LDFLAGS="$LDFLAGS -zrelax=transtls"
    343 		   AC_MSG_WARN([When using GNU C Compiler on Solaris, -zrelax=transtls linker flag is used to fix bug in Thread Local Storage])
    344 		  ])
    345 	])
    346 
    347 AC_CHECK_HEADERS([sys/param.h sys/socket.h])
    348 AC_CHECK_HEADERS([fcntl.h regex.h sys/time.h unistd.h sys/mman.h sys/sockio.h sys/select.h sys/sysctl.h net/if6.h net/route.h linux/netlink.h linux/rtnetlink.h], [], [],
    349 		 [$ac_includes_default
    350 		  #ifdef HAVE_SYS_PARAM_H
    351 		  # include <sys/param.h>
    352 		  #endif
    353 		  #ifdef HAVE_SYS_SOCKET_H
    354 		  # include <sys/socket.h>
    355 		  #endif
    356 		 ])
    357 
    358 #
    359 # Check for C11 thread local storage
    360 #
    361 # NOTE: OpenBSD doesn't ship <threads.h>, so we can't require it (yet).
    362 #
    363 AC_CHECK_HEADERS([threads.h])
    364 
    365 #
    366 # C11 Atomic Operations
    367 #
    368 
    369 AC_CHECK_HEADERS([stdatomic.h],
    370 		 [],
    371 		 [AC_MSG_ERROR([C11 Atomic Operations required, update your toolchain to build BIND 9])])
    372 
    373 AC_COMPILE_IFELSE(
    374   [AC_LANG_PROGRAM(
    375      [[#include <stdatomic.h>]],
    376      [[atomic_int_fast32_t val = 0; atomic_fetch_add_explicit(&val, 1, memory_order_relaxed);]]
    377    )],
    378   [AC_MSG_CHECKING([whether -latomic is needed for 64-bit stdatomic.h functions])
    379    AC_LINK_IFELSE(
    380      [AC_LANG_PROGRAM(
    381 	[[#include <stdatomic.h>]],
    382 	[[atomic_int_fast64_t val = 0; atomic_fetch_add_explicit(&val, 1, memory_order_relaxed);]]
    383       )],
    384      [AC_MSG_RESULT([no])],
    385      [LIBS="$LIBS -latomic"
    386       AC_LINK_IFELSE(
    387 	[AC_LANG_PROGRAM(
    388 	   [[#include <stdatomic.h>]],
    389 	   [[atomic_int_fast64_t val = 0; atomic_fetch_add_explicit(&val, 1, memory_order_relaxed);]]
    390 	 )],
    391 	[AC_MSG_RESULT([yes])],
    392 	[AC_MSG_FAILURE([libatomic needed, but linking with -latomic failed, please fix your toolchain.])])
    393      ])
    394   ],
    395   [AC_MSG_FAILURE([stdatomic.h header found, but compilation failed, please fix your toolchain.])])
    396 
    397 AC_CHECK_HEADERS([stdnoreturn.h],
    398 		 [],
    399 		 [AC_MSG_ERROR([C11 standard headers not found, update your toolchain.])])
    400 
    401 AC_C_CONST
    402 AC_C_INLINE
    403 AC_C_VOLATILE
    404 
    405 #
    406 # Check for yield support on ARM processors
    407 #
    408 AS_CASE([$host],
    409 	[arm*|aarch64*],
    410 	[AC_MSG_CHECKING([for ARM yield instruction support])
    411 	 AC_COMPILE_IFELSE(
    412 	     [AC_LANG_PROGRAM([[]],
    413 			     [[__asm__ __volatile__ ("yield")]])],
    414 	     [AC_MSG_RESULT([yes])
    415 	      AC_DEFINE([HAVE_ARM_YIELD], [1],
    416 			[define if the ARM yield instruction is available])],
    417 	     [AC_MSG_RESULT([no])])])
    418 
    419 #
    420 # Check for pause support on SPARC processors
    421 #
    422 AS_CASE([$host],
    423 	[sparc*],
    424 	[AC_MSG_CHECKING([for pause instruction support])
    425 	 AC_COMPILE_IFELSE(
    426 	     [AC_LANG_PROGRAM([[]],
    427 			     [[__asm__ __volatile__ ("pause")]])],
    428 	     [AC_MSG_RESULT([yes])
    429 	      AC_DEFINE([HAVE_SPARC_PAUSE], [1],
    430 			[define if the SPARC pause instruction is available])],
    431 	     [AC_MSG_RESULT([no])])])
    432 
    433 AC_CHECK_FUNCS([sysctlbyname])
    434 
    435 AC_TYPE_SIZE_T
    436 AC_TYPE_SSIZE_T
    437 AC_TYPE_UINTPTR_T
    438 
    439 #
    440 # check for uname library routine
    441 #
    442 AC_MSG_CHECKING([for uname])
    443 AC_COMPILE_IFELSE(
    444   [AC_LANG_PROGRAM(
    445      [[#include <sys/utsname.h>
    446        #include <stdio.h>
    447       ]],
    448      [[
    449        struct utsname uts;
    450        uname(&uts);
    451        printf("running on %s %s %s for %s\n",
    452 	      uts.sysname, uts.release, uts.version, uts.machine);
    453      ]])],
    454   [AC_MSG_RESULT(yes)
    455    AC_DEFINE([HAVE_UNAME], [1], [define if uname is available])
    456   ],
    457   [AC_MSG_RESULT(no)
    458    AC_MSG_WARN([uname is not correctly supported])
    459   ])
    460 
    461 #
    462 # check for GCC noreturn attribute
    463 #
    464 AX_GCC_FUNC_ATTRIBUTE([noreturn])
    465 
    466 #
    467 # check for GCC malloc attribute
    468 #
    469 AX_GCC_FUNC_ATTRIBUTE([malloc])
    470 
    471 AC_MSG_CHECKING([for extended malloc attributes])
    472 AC_COMPILE_IFELSE(
    473   [AC_LANG_PROGRAM(
    474      [[
    475        #include <stddef.h>
    476        #include <stdlib.h>
    477 	   __attribute__ ((malloc, malloc (free, 1))
    478 	   void * xmalloc(size_t sz) { return malloc(sz); }
    479      ]],
    480      [[
    481        void *p = xmalloc(8);
    482 	   free(p);
    483      ]])],
    484   [AC_MSG_RESULT(yes)
    485    AC_DEFINE([HAVE_MALLOC_EXT_ATTR], [1], [define if extended attributes for malloc are available])
    486   ],
    487   [AC_MSG_RESULT(no)])
    488 
    489 #
    490 # check for GCC returns_nonnull attribute
    491 #
    492 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
    493 
    494 #
    495 # how to link math functions?
    496 #
    497 AC_SEARCH_LIBS([sqrt],[m])
    498 
    499 #
    500 # GeoIP support?
    501 #
    502 # Should be on by default if libmaxminddb exists.
    503 #
    504 # [pairwise: --enable-geoip --with-maxminddb=auto, --enable-geoip --with-maxminddb=yes, --disable-geoip]
    505 AC_ARG_ENABLE([geoip],
    506 	      [AS_HELP_STRING([--disable-geoip],
    507 			      [support GeoIP2 geolocation ACLs if available [default=yes]])],
    508 	      [], [enable_geoip="yes"])
    509 
    510 # [pairwise: skip]
    511 AC_ARG_WITH([maxminddb],
    512 	    [AS_HELP_STRING([--with-maxminddb=PATH],
    513 			    [Build with MaxMind GeoIP2 support (auto|yes|no|path) [default=auto]])],
    514 	    [], [with_maxminddb="auto"])
    515 
    516 AS_IF([test "$enable_geoip" = "yes"],
    517       [AS_CASE([$with_maxminddb],
    518 	       [no],[AC_MSG_ERROR([Use '--disable-geoip' to disable the GeoIP])],
    519 	       [auto],[PKG_CHECK_MODULES([MAXMINDDB], [libmaxminddb],
    520 					 [AC_DEFINE([HAVE_GEOIP2], [1], [Build with GeoIP2 support])
    521 					  PKG_CHECK_VAR([MAXMINDDB_PREFIX], [libmaxminddb], [prefix], [], [AC_MSG_ERROR([libmaxminddb prefix not found in pkg-config; set MAXMINDDB_PREFIX in the environment])])
    522 					 ],[:])],
    523 	       [yes],[PKG_CHECK_MODULES([MAXMINDDB], [libmaxminddb],
    524 					[AC_DEFINE([HAVE_GEOIP2], [1], [Build with GeoIP2 support])
    525 					 PKG_CHECK_VAR([MAXMINDDB_PREFIX], [libmaxminddb], [prefix], [], [AC_MSG_ERROR([libmaxminddb prefix not found in pkg-config; set MAXMINDDB_PREFIX in the environment])])
    526 					])],
    527 	       [ # default
    528 		   AX_SAVE_FLAGS([maxminddb])
    529 		   MAXMINDDB_CFLAGS="-I$with_maxminddb/include"
    530 		   MAXMINDDB_LIBS="-L$with_maxminddb/lib"
    531 		   CFLAGS="$CFLAGS $MAXMINDDB_CFLAGS"
    532 		   LIBS="$LIBS $MAXMINDDB_LIBS"
    533 		   AC_SEARCH_LIBS([MMDB_open], [maxminddb],
    534 				  [AC_DEFINE([HAVE_GEOIP2], [1], [Build with GeoIP2 support])
    535 				   MAXMINDDB_LIBS="$MAXMINDDB_LIBS $ac_cv_search_MMDB_open"
    536 				   AC_MSG_NOTICE([GeoIP2 default database path set to $with_maxminddb/share/GeoIP])
    537 				   AS_VAR_COPY([MAXMINDDB_PREFIX], [with_maxminddb])
    538 				  ],
    539 				  [AC_MSG_ERROR([GeoIP2 requested, but libmaxminddb not found])])
    540 		   AX_RESTORE_FLAGS([maxminddb])
    541 	       ])
    542        AC_ARG_VAR([MAXMINDDB_PREFIX], [value of prefix for MAXMINDDB, overriding pkg-config])
    543 ])
    544 
    545 AM_CONDITIONAL([HAVE_GEOIP2], [test -n "$MAXMINDDB_LIBS"])
    546 
    547 AC_SUBST([MAXMINDDB_CFLAGS])
    548 AC_SUBST([MAXMINDDB_LIBS])
    549 
    550 AX_PTHREAD
    551 
    552 LIBS="$PTHREAD_LIBS $LIBS"
    553 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
    554 CC="$PTHREAD_CC"
    555 
    556 AC_MSG_CHECKING([for PTHREAD_MUTEX_ADAPTIVE_NP])
    557 AC_COMPILE_IFELSE(
    558   [AC_LANG_PROGRAM([[#include <pthread.h>]],
    559 		   [[(void)pthread_mutexattr_settype(&(pthread_mutexattr_t){ NULL }, PTHREAD_MUTEX_ADAPTIVE_NP);]])],
    560   [AC_MSG_RESULT([yes])
    561    AC_DEFINE([HAVE_PTHREAD_MUTEX_ADAPTIVE_NP], [1], [Define to 1 if PTHREAD_MUTEX_ADAPTIVE_NP is available])],
    562   [AC_MSG_RESULT([no])])
    563 
    564 AC_CHECK_FUNCS([pthread_attr_getstacksize pthread_attr_setstacksize pthread_barrier_init pthread_spin_init])
    565 
    566 AC_CHECK_HEADERS([sched.h])
    567 
    568 AC_SEARCH_LIBS([sched_yield],[rt])
    569 AC_CHECK_FUNCS([sched_yield pthread_yield pthread_yield_np])
    570 
    571 # Look for functions relating to thread naming
    572 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
    573 AC_CHECK_HEADERS([pthread_np.h], [], [], [#include <pthread.h>])
    574 
    575 # libuv
    576 PKG_CHECK_MODULES([LIBUV], [libuv >= 1.37.0], [],
    577 		  [PKG_CHECK_MODULES([LIBUV], [libuv >= 1.34.0 libuv < 1.35.0], [],
    578 				     [AC_MSG_ERROR([libuv >= 1.34.0 (except 1.35.0 and 1.36.0) not found])])])
    579 
    580 PKG_CHECK_VERSION([LIBUV_VERSION], [libuv])
    581 
    582 AX_SAVE_FLAGS([libuv])
    583 CFLAGS="$CFLAGS $LIBUV_CFLAGS"
    584 LIBS="$LIBS $LIBUV_LIBS"
    585 
    586 # libuv recvmmsg support
    587 AC_CHECK_DECLS([UV_UDP_MMSG_FREE, UV_UDP_MMSG_CHUNK], [], [], [[#include <uv.h>]])
    588 AC_MSG_CHECKING([whether struct msghdr uses padding for alignment])
    589 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/socket.h>],
    590 				   [const struct msghdr h = { .__pad1 = 0, .__pad2 = 0 };])],
    591 		  [AC_MSG_RESULT([yes])
    592 		   AC_DEFINE([HAVE_DECL_UV_UDP_RECVMMSG],
    593 			     [0], [Disable recvmmsg support on systems with MUSL glibc])],
    594 		  [AC_MSG_RESULT([no])
    595 		   AC_CHECK_DECLS([UV_UDP_RECVMMSG], [], [], [[#include <uv.h>]])])
    596 
    597 # libuv recverr support
    598 AC_CHECK_DECLS([UV_UDP_LINUX_RECVERR], [], [], [[#include <uv.h>]])
    599 
    600 AX_RESTORE_FLAGS([libuv])
    601 
    602 # [pairwise: --enable-doh --with-libnghttp2=auto, --enable-doh --with-libnghttp2=yes, --disable-doh]
    603 AC_ARG_ENABLE([doh],
    604 	      [AS_HELP_STRING([--disable-doh], [disable DNS over HTTPS, removes dependency on libnghttp2 (default is --enable-doh)])],
    605 	      [], [enable_doh=yes])
    606 
    607 # [pairwise: skip]
    608 AC_ARG_WITH([libnghttp2],
    609 	    [AS_HELP_STRING([--with-libnghttp2],
    610 			    [build with libnghttp2 library [yes|no|auto] (default is auto)])],
    611 	    [], [with_libnghttp2="auto"])
    612 
    613 AS_IF([test "$enable_doh" = "yes"],
    614       [AS_CASE([$with_libnghttp2],
    615 	       [no],[AC_MSG_ERROR([Use '--disable-doh' to disable DNS-over-HTTPS support])],
    616 	       [auto|yes],[PKG_CHECK_MODULES([LIBNGHTTP2], [libnghttp2 >= 1.6.0],
    617 					     [AC_DEFINE([HAVE_LIBNGHTTP2], [1], [Build with DNS-over-HTTPS support])],
    618 					     [AC_MSG_ERROR(m4_normalize([DNS-over-HTTPS support requested, but libnghttp2 not found.
    619 									 Either install libnghttp2 or use --disable-doh.]))])],
    620 	       [AC_MSG_ERROR([Specifying libnghttp2 installation path is not supported, adjust PKG_CONFIG_PATH instead])])])
    621 
    622 AM_CONDITIONAL([HAVE_LIBNGHTTP2], [test -n "$LIBNGHTTP2_LIBS"])
    623 
    624 
    625 #
    626 # flockfile is usually provided by pthreads
    627 #
    628 AC_CHECK_FUNCS([flockfile getc_unlocked])
    629 
    630 #
    631 # Look for sysconf or other ways to allow detection of the number of processors.
    632 #
    633 AC_CHECK_FUNCS([sysconf])
    634 AC_CHECK_FUNCS(sysconf sched_getaffinity cpuset_getaffinity)
    635 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
    636 		 [$ac_includes_default
    637 		  #ifdef HAVE_SYS_PARAM_H
    638 		  # include <sys/param.h>
    639 		  #endif
    640 		 ])
    641 
    642 #
    643 # Do we want to use pthread rwlock?
    644 #
    645 # [pairwise: --enable-pthread-rwlock, --disable-pthread-rwlock]
    646 AC_ARG_ENABLE([pthread_rwlock],
    647 	      [AS_HELP_STRING([--enable-pthread-rwlock],
    648 			      [use pthread rwlock instead of internal rwlock implementation])],
    649 	      [], [enable_pthread_rwlock=no])
    650 
    651 AS_IF([test "$enable_pthread_rwlock" = "yes"],
    652       [AC_CHECK_FUNCS([pthread_rwlock_rdlock], [],
    653 		      [AC_MSG_ERROR([pthread_rwlock_rdlock requested but not found])])
    654        AC_DEFINE([USE_PTHREAD_RWLOCK],[1],[Define if you want to use pthread rwlock implementation])
    655       ])
    656 AM_CONDITIONAL([USE_ISC_RWLOCK], [test "$enable_pthread_rwlock" != "yes"])
    657 
    658 CRYPTO=OpenSSL
    659 
    660 #
    661 # OpenSSL/LibreSSL is mandatory
    662 #
    663 PKG_CHECK_MODULES([OPENSSL], [libssl libcrypto], [PKG_CHECK_VERSION([OPENSSL_VERSION], [openssl])],
    664 		  [AX_CHECK_OPENSSL([:], [AC_MSG_FAILURE([OpenSSL/LibreSSL not found])])])
    665 
    666 AX_SAVE_FLAGS([openssl])
    667 
    668 CFLAGS="$OPENSSL_CFLAGS $CFLAGS"
    669 LIBS="$OPENSSL_LIBS $LIBS"
    670 
    671 AC_MSG_CHECKING([for OpenSSL >= 1.0.0 or LibreSSL >= 2.7.0])
    672 AC_COMPILE_IFELSE(
    673     [AC_LANG_PROGRAM([[#include <openssl/opensslv.h>]],
    674 		     [[#if (!defined(LIBRESSL_VERSION_NUMBER) && (OPENSSL_VERSION_NUMBER < 0x1000000fL)) || \\
    675 			   (defined(LIBRESSL_VERSION_NUMBER) && (LIBRESSL_VERSION_NUMBER < 0x02070000fL))
    676 		       #error OpenSSL >= 1.0.0 or LibreSSL >= 2.7.0 required
    677 		       #endif
    678 		      ]])],
    679     [AC_MSG_RESULT([yes])],
    680     [AC_MSG_FAILURE([not found])])
    681 
    682 #
    683 # Check for functions added in OpenSSL or LibreSSL
    684 #
    685 
    686 AC_CHECK_FUNCS([BIO_read_ex BIO_write_ex])
    687 AC_CHECK_FUNCS([BN_GENCB_new])
    688 AC_CHECK_FUNCS([CRYPTO_zalloc])
    689 AC_CHECK_FUNCS([ERR_get_error_all])
    690 AC_CHECK_FUNCS([EVP_CIPHER_CTX_new EVP_CIPHER_CTX_free])
    691 AC_CHECK_FUNCS([EVP_MD_CTX_new EVP_MD_CTX_free EVP_MD_CTX_reset EVP_MD_CTX_get0_md])
    692 AC_CHECK_FUNCS([EVP_PKEY_new_raw_private_key EVP_PKEY_eq])
    693 AC_CHECK_FUNCS([OPENSSL_init_ssl OPENSSL_init_crypto OPENSSL_cleanup])
    694 AC_CHECK_FUNCS([SSL_CTX_set_keylog_callback])
    695 AC_CHECK_FUNCS([SSL_CTX_set_min_proto_version])
    696 AC_CHECK_FUNCS([SSL_CTX_up_ref])
    697 AC_CHECK_FUNCS([SSL_read_ex SSL_peek_ex SSL_write_ex])
    698 AC_CHECK_FUNCS([SSL_CTX_set1_cert_store X509_STORE_up_ref])
    699 AC_CHECK_FUNCS([SSL_CTX_up_ref])
    700 AC_CHECK_FUNCS([SSL_SESSION_is_resumable])
    701 AC_CHECK_FUNCS([SSL_CTX_set_ciphersuites])
    702 
    703 #
    704 # Check for algorithm support in OpenSSL
    705 #
    706 
    707 AC_CHECK_FUNCS([EVP_DigestSignInit EVP_DigestVerifyInit], [:],
    708 	       [AC_MSG_FAILURE([EVP_DigestSignInit/EVP_DigestVerifyInit support in OpenSSL is mandatory.])])
    709 
    710 AC_MSG_CHECKING([for ECDSA P-256 support])
    711 AC_COMPILE_IFELSE(
    712     [AC_LANG_PROGRAM([[#include <openssl/evp.h>]],
    713 		     [[EVP_PKEY_CTX *kctx = EVP_PKEY_CTX_new_id(NID_X9_62_prime256v1, NULL);]])],
    714     [AC_MSG_RESULT([yes])],
    715     [AC_MSG_FAILURE([not found.  ECDSA P-256 support in OpenSSL is mandatory.])])
    716 
    717 AC_MSG_CHECKING([for ECDSA P-384 support])
    718 AC_COMPILE_IFELSE(
    719     [AC_LANG_PROGRAM([[#include <openssl/evp.h>]],
    720 		     [[EVP_PKEY_CTX *kctx = EVP_PKEY_CTX_new_id(NID_secp384r1, NULL);]])],
    721     [AC_MSG_RESULT([yes])],
    722     [AC_MSG_FAILURE([not found.  ECDSA P-384 support in OpenSSL is mandatory.])])
    723 
    724 AC_MSG_CHECKING([for Ed25519 support])
    725 AC_COMPILE_IFELSE(
    726     [AC_LANG_PROGRAM([[#include <openssl/evp.h>]],
    727 		     [[EVP_PKEY_CTX *kctx = EVP_PKEY_CTX_new_id(NID_ED25519, NULL);]])],
    728     [AC_DEFINE([HAVE_OPENSSL_ED25519], [1], [define if OpenSSL supports Ed25519])
    729      AC_MSG_RESULT([yes])],
    730     [AC_MSG_RESULT([no])])
    731 
    732 AC_MSG_CHECKING([for Ed448 support])
    733 AC_COMPILE_IFELSE(
    734     [AC_LANG_PROGRAM([[#include <openssl/evp.h>]],
    735 		     [[EVP_PKEY_CTX *kctx = EVP_PKEY_CTX_new_id(NID_ED448, NULL);]])],
    736     [AC_DEFINE([HAVE_OPENSSL_ED448], [1], [define if OpenSSL supports Ed448])
    737      AC_MSG_RESULT([yes])],
    738     [AC_MSG_RESULT([no])])
    739 
    740 #
    741 # Check for OpenSSL SHA-1 support
    742 #
    743 AC_CHECK_FUNCS([EVP_sha1], [:],
    744 	       [AC_MSG_FAILURE([SHA-1 support in OpenSSL is mandatory.])])
    745 
    746 #
    747 # Check for OpenSSL SHA-2 support
    748 #
    749 AC_CHECK_FUNCS([EVP_sha224 EVP_sha256 EVP_sha384 EVP_sha512], [:],
    750 	       [AC_MSG_FAILURE([SHA-2 support in OpenSSL is mandatory.])])
    751 
    752 #
    753 # Check for OpenSSL 1.1.x/LibreSSL functions
    754 #
    755 AC_CHECK_FUNCS([ECDSA_SIG_get0 EVP_PKEY_get0_EC_KEY])
    756 AC_CHECK_FUNCS([RSA_set0_key EVP_PKEY_get0_RSA])
    757 
    758 AC_CHECK_FUNCS([TLS_server_method TLS_client_method])
    759 
    760 #
    761 # Check whether FIPS mode is available and whether we should enable it
    762 #
    763 # FIPS is not included in pairwise testing as the relevant Docker image
    764 # does not support FIPS mode.
    765 #
    766 AC_CHECK_FUNCS(EVP_default_properties_enable_fips FIPS_mode)
    767 
    768 # [pairwise: skip]
    769 AC_ARG_ENABLE([fips-mode],
    770 	      [AS_HELP_STRING([--enable-fips-mode],
    771 			      [enable FIPS mode in OpenSSL library [default=no]])],
    772 	      [], [enable_fips_mode="no"])
    773 
    774 AC_MSG_CHECKING([whether to enable FIPS mode in OpenSSL library])
    775 AS_CASE([$enable_fips_mode],
    776 	[yes], [AC_MSG_RESULT([yes])
    777 	        AC_DEFINE([ENABLE_FIPS_MODE], [1], [Define to 1 if you want FIPS mode to be enabled])
    778 		AS_IF([test "x$ac_cv_func_FIPS_mode" != xyes -a "x$ac_cv_func_EVP_default_properties_enable_fips" != xyes],
    779 		      AC_MSG_FAILURE([OpenSSL FIPS mode requested but not available.]))],
    780 	[no], [AC_MSG_RESULT([no])])
    781 
    782 AX_RESTORE_FLAGS([openssl])
    783 
    784 AC_SUBST([OPENSSL_CFLAGS])
    785 AC_SUBST([OPENSSL_LIBS])
    786 
    787 AC_CHECK_FUNCS([clock_gettime])
    788 
    789 # [pairwise: --with-gssapi=yes, --with-gssapi=auto, --without-gssapi]
    790 AC_ARG_WITH([gssapi],
    791 	    [AS_HELP_STRING([--with-gssapi=[PATH|[/path/]krb5-config]],
    792 			   [Specify path for system-supplied GSSAPI
    793 				[default=auto]])],
    794 	    [], [with_gssapi="auto"])
    795 
    796 KRB5_CONFIG=
    797 AS_CASE([$with_gssapi],
    798 	[no],[AC_MSG_CHECKING([for GSSAPI support])
    799 	      AC_MSG_RESULT([no])],
    800 	[yes],[AC_PATH_PROG([KRB5_CONFIG], [krb5-config])
    801 	       AS_IF([test -z "$KRB5_CONFIG"],
    802 		     [AC_MSG_ERROR([krb5-config required but not found])])],
    803 	[auto],[AC_PATH_PROG([KRB5_CONFIG], [krb5-config])],
    804 	[*krb5-config*],[KRB5_CONFIG="$with_gssapi"],
    805 	[AC_MSG_ERROR([--with-gssapi requires yes|no|auto|/path/to/krb5-config])])
    806 
    807 GSSAPI_CFLAGS=
    808 GSSAPI_LIBS=
    809 KRB5_CFLAGS=
    810 KRB5_LIBS=
    811 AS_IF([test -n "$KRB5_CONFIG"],
    812       [AC_MSG_CHECKING([for gssapi libraries])
    813        AX_SAVE_FLAGS([gssapi])
    814        GSSAPI_CFLAGS=`"$KRB5_CONFIG" --cflags gssapi`
    815        GSSAPI_LIBS=`"$KRB5_CONFIG" --libs gssapi`
    816        CFLAGS="$CFLAGS $GSSAPI_CFLAGS"
    817        LIBS="$LIBS $GSSAPI_LIBS"
    818        AC_MSG_RESULT([$GSSAPI_CFLAGS $GSSAPI_LIBS])
    819        AC_CHECK_HEADERS([gssapi/gssapi.h], [],
    820 			[AC_CHECK_HEADERS([gssapi.h], [],
    821 					  [AC_MSG_ERROR([neither gssapi/gssapi.h nor gssapi.h found])])])
    822        AC_CHECK_HEADERS([gssapi/gssapi_krb5.h],
    823 			[AC_CHECK_HEADERS([gssapi_krb5.h], []
    824 					  [AC_MSG_ERROR([neither gssapi/gssapi_krb5.h nor gssapi_krb5.h found])])])
    825        AC_CHECK_FUNCS([gss_acquire_cred],[],
    826 		      [AC_MSG_ERROR([linking with $GSSAPI_LIBS does not work])])
    827        AX_RESTORE_FLAGS([gssapi])
    828 
    829        AC_MSG_CHECKING([for krb5 libraries])
    830        AX_SAVE_FLAGS([krb5])
    831        KRB5_CFLAGS=`"$KRB5_CONFIG" --cflags krb5`
    832        KRB5_LIBS=`$KRB5_CONFIG --libs krb5`
    833        CFLAGS="$CFLAGS $KRB5_CFLAGS"
    834        LIBS="$CFLAGS $KRB5_LIBS"
    835        AC_MSG_RESULT([$KRB5_CFLAGS $KRB5_LIBS])
    836        AC_CHECK_HEADERS([krb5/krb5.h], [],
    837 			[AC_CHECK_HEADERS([krb5.h], [],
    838 					  [AC_MSG_ERROR([neither krb5/krb5.h nor krb5 found])])])
    839        AC_CHECK_FUNCS([krb5_init_context], [],
    840 		      [AC_MSG_ERROR([linking with $KRB5_LIBS failed])])
    841        AX_RESTORE_FLAGS([krb5])
    842 
    843        AC_DEFINE([HAVE_GSSAPI], [1], [Define to 1 if you have the Kerberos Framework available])
    844        # kludge to silence compiler warnings which recommend use of GSS.framework on macOS
    845        AS_CASE([$host],[*-darwin*],[CFLAGS="$CFLAGS -Wno-deprecated-declarations"])])
    846 AM_CONDITIONAL([HAVE_GSSAPI], [test -n "$GSSAPI_LIBS"])
    847 AC_SUBST([GSSAPI_CFLAGS])
    848 AC_SUBST([GSSAPI_LIBS])
    849 AC_SUBST([KRB5_CFLAGS])
    850 AC_SUBST([KRB5_LIBS])
    851 
    852 #
    853 # was --with-lmdb specified?
    854 #
    855 
    856 # [pairwise: --with-lmdb=auto, --with-lmdb=yes, --without-lmdb]
    857 AC_ARG_WITH([lmdb],
    858 	    [AS_HELP_STRING([--with-lmdb=@<:@PATH@:>@],
    859 			    [use LMDB library @<:@default=auto@:>@, optionally specify the prefix for lmdb library])],
    860 	    [:],
    861 	    [with_lmdb="auto"])
    862 
    863 ac_lib_lmdb_found=no
    864 AS_CASE([$with_lmdb],
    865 	[no],[],
    866 	[auto|yes], [PKG_CHECK_MODULES([LMDB], [lmdb],
    867 				       [ac_lib_lmdb_found=yes],
    868 				       [for ac_lib_lmdb_path in /usr /usr/local /opt /opt/local; do
    869 						AX_LIB_LMDB([$ac_lib_lmdb_path],
    870 							    [ac_lib_lmdb_found=yes
    871 							     break])
    872 					done
    873 				       ])],
    874 	[AX_LIB_LMDB([$with_lmdb],[ac_lib_lmdb_found=yes])])
    875 
    876 # don't fail when in automatic mode
    877 AS_IF([test "$with_lmdb" = "auto" && test "$ac_lib_lmdb_found" = "no"],
    878       [with_lmdb=no])
    879 
    880 # hard fail when LMDB requested, but not found
    881 AS_IF([test "$with_lmdb" != "no" && test "$ac_lib_lmdb_found" != "yes"],
    882       [AC_MSG_ERROR([LMDB requested, but not found])])
    883 
    884 AS_IF([test "$ac_lib_lmdb_found" = "yes"],
    885       [AC_DEFINE([HAVE_LMDB], [1], [Use lmdb library])])
    886 
    887 AC_SUBST([LMDB_CFLAGS])
    888 AC_SUBST([LMDB_LIBS])
    889 AM_CONDITIONAL([HAVE_LMDB], [test -n "$LMDB_LIBS"])
    890 
    891 #
    892 # was --with-libxml2 specified?
    893 #
    894 # [pairwise: --with-libxml2=auto, --with-libxml2=yes, --without-libxml2]
    895 AC_ARG_WITH([libxml2],
    896 	    [AS_HELP_STRING([--with-libxml2],
    897 			    [build with libxml2 library [yes|no|auto] (default is auto)])],
    898 	    [], [with_libxml2="auto"])
    899 
    900 AS_CASE([$with_libxml2],
    901 	[no],[],
    902 	[auto],[PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6.0],
    903 				  [AC_DEFINE([HAVE_LIBXML2], [1], [Use libxml2 library])],
    904 				  [:])],
    905 	[yes],[PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6.0],
    906 				 [AC_DEFINE([HAVE_LIBXML2], [1], [Use libxml2 library])])],
    907 	[AC_MSG_ERROR([Specifying libxml2 installation path is not supported, adjust PKG_CONFIG_PATH instead])])
    908 
    909 AM_CONDITIONAL([HAVE_LIBXML2], [test -n "$LIBXML2_LIBS"])
    910 
    911 #
    912 # was --with-json-c specified?
    913 #
    914 # [pairwise: --with-json-c=detect, --with-json-c=yes, --without-json-c]
    915 AC_ARG_WITH([json-c],
    916 	    [AS_HELP_STRING([--with-json-c],
    917 			    [build with json-c library [yes|no|detect] (default is detect)])],
    918 	    [], [with_json_c="detect"])
    919 
    920 AS_CASE([$with_json_c],
    921 	[no],[],
    922 	[detect],[PKG_CHECK_MODULES([JSON_C], [json-c >= 0.11],
    923 				    [AC_DEFINE([HAVE_JSON_C], [1], [Use json-c library])],
    924 				    [:])],
    925 	[yes],[PKG_CHECK_MODULES([JSON_C], [json-c >= 0.11],
    926 				 [AC_DEFINE([HAVE_JSON_C], [1], [Use json-c library])])],
    927 	[AC_MSG_ERROR([Specifying json-c installation path is not supported, adjust PKG_CONFIG_PATH instead])]
    928        )
    929 
    930 AM_CONDITIONAL([HAVE_JSON_C], [test -n "$JSON_C_LIBS"])
    931 
    932 AC_SUBST([JSON_C_CFLAGS])
    933 AC_SUBST([JSON_C_LIBS])
    934 
    935 #
    936 # was --with-zlib specified?
    937 #
    938 # [pairwise: --with-zlib=auto, --with-zlib=yes, --without-zlib]
    939 AC_ARG_WITH([zlib],
    940 	    [AS_HELP_STRING([--with-zlib],
    941 			    [build with zlib for HTTP compression
    942 			     [default=yes]])],
    943 	    [], with_zlib="auto")
    944 
    945 AS_CASE([$with_zlib],
    946        [no],[],
    947        [auto],[PKG_CHECK_MODULES([ZLIB], [zlib],
    948 				 [AC_DEFINE([HAVE_ZLIB], [1], [Use zlib library])],
    949 				 [:])],
    950        [yes],[PKG_CHECK_MODULES([ZLIB], [zlib],
    951 				[AC_DEFINE([HAVE_ZLIB], [1], [Use zlib library])])],
    952        [AC_MSG_ERROR([Specifying zlib installation path is not supported, adjust PKG_CONFIG_PATH instead])])
    953 AC_SUBST([ZLIB_CFLAGS])
    954 AC_SUBST([ZLIB_LIBS])
    955 
    956 #
    957 # Check if the system supports glibc-compatible backtrace() function.
    958 #
    959 AC_CHECK_HEADERS([execinfo.h],
    960 		 [AC_SEARCH_LIBS([backtrace_symbols], [execinfo],
    961 				 [AC_CHECK_FUNCS([backtrace_symbols])])])
    962 
    963 #
    964 # We do the IPv6 compilation checking after libtool so that we can put
    965 # the right suffix on the files.
    966 #
    967 AC_MSG_CHECKING([for IPv6 structures])
    968 AC_COMPILE_IFELSE(
    969   [AC_LANG_PROGRAM(
    970      [[
    971        #include <sys/types.h>
    972        #include <sys/socket.h>
    973        #include <netinet/in.h>
    974      ]],
    975      [[
    976        struct sockaddr_in6 sin6;
    977        struct in6_addr in6;
    978        struct in6_pktinfo in6_pi;
    979        struct sockaddr_storage storage;
    980        in6 = in6addr_any;
    981        in6 = in6addr_loopback;
    982        sin6.sin6_scope_id = 0;
    983        return (0);
    984      ]])],
    985   [AC_MSG_RESULT([yes])],
    986   [AC_MSG_FAILURE([IPv6 support is mandatory])])
    987 
    988 #
    989 # Allow forcibly disabling TCP Fast Open support as autodetection might yield
    990 # confusing results on some systems (e.g. FreeBSD; see set_tcp_fastopen()
    991 # comment in lib/isc/socket.c).
    992 #
    993 # [pairwise: --enable-tcp-fastopen, --disable-tcp-fastopen]
    994 AC_ARG_ENABLE([tcp_fastopen],
    995 	      [AS_HELP_STRING([--disable-tcp-fastopen],
    996 			      [disable TCP Fast Open support [default=yes]])],
    997 	      [], [enable_tcp_fastopen="yes"])
    998 
    999 AS_IF([test "$enable_tcp_fastopen" = "yes"],
   1000       [AC_DEFINE([ENABLE_TCP_FASTOPEN], [1], [define if you want TCP_FASTOPEN enabled if available])])
   1001 
   1002 #
   1003 # Check for some other useful functions that are not ever-present.
   1004 #
   1005 AC_CHECK_FUNCS([strlcpy strlcat strnstr])
   1006 
   1007 #
   1008 # Check for readline support
   1009 #
   1010 
   1011 # editline is not included in pairwise testing as the library
   1012 # is not present in the relevant Docker image.
   1013 #
   1014 # GNU Readline is not included in pairwise testing as the library
   1015 # in the relevant Docker image does not support pkg-config.
   1016 #
   1017 # [pairwise: --with-readline=auto, --with-readline=yes, --with-readline=libedit, --without-readline]
   1018 AC_ARG_WITH([readline],
   1019 	    [AS_HELP_STRING([--with-readline=yes|no|libedit|readline],
   1020 			    [specify readline library [default auto]])],
   1021 	    [], [with_readline="auto"])
   1022 
   1023 AS_CASE([$with_readline],
   1024 	[no],[],
   1025 	[auto|yes],
   1026 	[PKG_CHECK_MODULES([READLINE], [libedit],
   1027 			   [AC_DEFINE([HAVE_READLINE_LIBEDIT], [1], [Build with libedit support])],
   1028 			   [PKG_CHECK_MODULES([READLINE], [libeditline],
   1029 					      [AC_DEFINE([HAVE_READLINE_EDITLINE], [1], [Build with editline support.])],
   1030 					      [PKG_CHECK_MODULES([READLINE], [readline],
   1031 								 [AC_DEFINE([HAVE_READLINE_READLINE], [1], [Build with readline support.])],
   1032 								 [AS_IF([test "$with_readline" = "yes"],
   1033 									[AC_MSG_ERROR([readline support requested, but none of the libraries have been found.])])])])])],
   1034 	[libedit],
   1035 	[PKG_CHECK_MODULES([READLINE], [libedit],
   1036 			   [AC_DEFINE([HAVE_READLINE_LIBEDIT], [1], [Build with libedit support])])],
   1037 	[editline],
   1038 	[PKG_CHECK_MODULES([READLINE], [libeditline],
   1039 			   [AC_DEFINE([HAVE_READLINE_EDITLINE], [1], [Build with editline support])])],
   1040 	[readline],
   1041 	[PKG_CHECK_MODULES([READLINE], [readline],
   1042 			   [AC_DEFINE([HAVE_READLINE_READLINE], [1], [Build with readline support])])],
   1043 	[AC_MSG_ERROR([Unknown readline '$with_readline' library requested.])])
   1044 AM_CONDITIONAL([HAVE_READLINE], [test -n "$READLINE_LIBS"])
   1045 AC_SUBST([READLINE_CFLAGS])
   1046 AC_SUBST([READLINE_LIBS])
   1047 
   1048 #
   1049 # Security Stuff
   1050 #
   1051 # Note it is very recommended to *not* disable chroot(),
   1052 # this is only because chroot() was made obsolete by Posix.
   1053 #
   1054 # [pairwise: --enable-chroot, --disable-chroot]
   1055 AC_ARG_ENABLE(chroot, AS_HELP_STRING([--disable-chroot], [disable chroot]))
   1056 case "$enable_chroot" in
   1057 	yes|'')
   1058 		AC_CHECK_FUNCS(chroot)
   1059 		;;
   1060 	no)
   1061 		;;
   1062 esac
   1063 
   1064 AS_CASE([$host],
   1065 	[*-linux*],
   1066 	[PKG_CHECK_MODULES([LIBCAP], [libcap],
   1067 			   [AC_DEFINE([HAVE_LIBCAP], [1], [Define to 1 if libcap was found])])])
   1068 
   1069 case "$host" in
   1070 *-solaris*)
   1071 	AC_DEFINE(NEED_SECURE_DIRECTORY, 1,
   1072 		  [Define if connect does not honour the permission on the UNIX domain socket.])
   1073 	;;
   1074 esac
   1075 
   1076 #
   1077 # Time Zone Stuff
   1078 #
   1079 AC_CHECK_FUNCS([tzset])
   1080 
   1081 AC_MSG_CHECKING(for optarg declaration)
   1082 AC_COMPILE_IFELSE(
   1083   [AC_LANG_PROGRAM(
   1084      [[#include <unistd.h>]],
   1085      [[optarg = 0;]]
   1086    )],
   1087   [AC_MSG_RESULT(yes)],
   1088   [AC_MSG_RESULT(no)
   1089    GEN_NEED_OPTARG="-DNEED_OPTARG=1"
   1090    AC_DEFINE(NEED_OPTARG, 1, [Defined if extern char *optarg is not declared.])]
   1091 )
   1092 
   1093 #
   1094 # Check for nanoseconds in file stats
   1095 #
   1096 AC_MSG_CHECKING([for st_mtim.tv_nsec])
   1097 AC_COMPILE_IFELSE(
   1098   [AC_LANG_PROGRAM(
   1099      [[#include <sys/stat.h>]],
   1100      [[struct stat s;
   1101        return(s.st_mtim.tv_nsec);
   1102       ]])],
   1103   [AC_MSG_RESULT([yes])
   1104    AC_DEFINE([HAVE_STAT_NSEC], [1], [define if struct stat has st_mtim.tv_nsec field])],
   1105   [AC_MSG_RESULT([no])])
   1106 
   1107 #
   1108 # Check for if_nametoindex() for IPv6 scoped addresses support
   1109 #
   1110 AC_CHECK_FUNCS([if_nametoindex])
   1111 
   1112 AC_CHECK_HEADERS([uchar.h])
   1113 
   1114 #
   1115 # Check for __builtin_unreachable
   1116 #
   1117 AC_MSG_CHECKING([compiler support for __builtin_unreachable()])
   1118 AC_LINK_IFELSE(
   1119   [AC_LANG_PROGRAM(
   1120      [[]],
   1121      [[__builtin_unreachable();]]
   1122    )],
   1123   [AC_MSG_RESULT([yes])
   1124    AC_DEFINE([HAVE_BUILTIN_UNREACHABLE], [1], [define if the compiler supports __builtin_unreachable().])
   1125   ],
   1126   [AC_MSG_RESULT([no])
   1127   ])
   1128 
   1129 #
   1130 # Check for __builtin_clz
   1131 #
   1132 AC_MSG_CHECKING([compiler support for __builtin_clz])
   1133 AC_LINK_IFELSE(
   1134   [AC_LANG_PROGRAM(
   1135      [[]],
   1136      [[return (__builtin_clz(0xff) == 24 ? 1 : 0);]]
   1137    )],
   1138   [AC_MSG_RESULT([yes])
   1139    AC_DEFINE(HAVE_BUILTIN_CLZ, 1, [Define to 1 if the compiler supports __builtin_clz.])
   1140   ],
   1141   [AC_MSG_RESULT([no])]
   1142 )
   1143 
   1144 #
   1145 # Check for __builtin_*_overflow
   1146 #
   1147 AC_MSG_CHECKING([compiler support for __builtin_add_overflow()])
   1148 AC_LINK_IFELSE(
   1149   [AC_LANG_PROGRAM(
   1150      [[#include <limits.h>]],
   1151      [[return (__builtin_add_overflow((unsigned int)UINT_MAX, (unsigned int)UINT_MAX, &(unsigned int){ 0 }));]]
   1152    )],
   1153   [AC_MSG_RESULT([yes])
   1154    AC_DEFINE([HAVE_BUILTIN_ADD_OVERFLOW], [1], [define if the compiler supports __builtin_add_overflow().])
   1155   ],
   1156   [AC_MSG_RESULT([no])
   1157   ])
   1158 
   1159 AC_MSG_CHECKING([compiler support for __builtin_sub_overflow()])
   1160 AC_LINK_IFELSE(
   1161   [AC_LANG_PROGRAM(
   1162      [[#include <limits.h>]],
   1163      [[return (__builtin_sub_overflow((unsigned int)0, (unsigned int)UINT_MAX, &(unsigned int){ 0 }));]]
   1164    )],
   1165   [AC_MSG_RESULT([yes])
   1166    AC_DEFINE([HAVE_BUILTIN_SUB_OVERFLOW], [1], [define if the compiler supports __builtin_sub_overflow().])
   1167   ],
   1168   [AC_MSG_RESULT([no])
   1169   ])
   1170 
   1171 AC_MSG_CHECKING([compiler support for __builtin_mul_overflow()])
   1172 AC_LINK_IFELSE(
   1173   [AC_LANG_PROGRAM(
   1174      [[#include <limits.h>
   1175        #include <stdint.h>
   1176      ]],
   1177      [[return (__builtin_mul_overflow(UINT64_MAX, UINT64_MAX, &(uint64_t){ 0 }));]]
   1178    )],
   1179   [AC_MSG_RESULT([yes])
   1180    AC_DEFINE([HAVE_BUILTIN_MUL_OVERFLOW], [1], [define if the compiler supports __builtin_mul_overflow().])
   1181   ],
   1182   [AC_MSG_RESULT([no])
   1183   ])
   1184 
   1185 #
   1186 # Activate "rrset-order fixed" or not?
   1187 #
   1188 # [pairwise: --enable-fixed-rrset, --disable-fixed-rrset]
   1189 AC_ARG_ENABLE([fixed-rrset],
   1190 	      [AS_HELP_STRING([--enable-fixed-rrset],
   1191 			      [enable fixed rrset ordering [default=no]])],
   1192 	      [], [enable_fixed_rrset="no"])
   1193 AS_IF([test "$enable_fixed_rrset" = "yes"],
   1194       [AC_MSG_WARN([fixed rrset ordering is deprecated and will be removed in the future release])
   1195        AC_DEFINE([DNS_RDATASET_FIXED], [1], [Define to enable "rrset-order fixed" syntax.])])
   1196 
   1197 #
   1198 # Activate dnstap?
   1199 #
   1200 # [pairwise: --enable-dnstap, --disable-dnstap]
   1201 AC_ARG_ENABLE([dnstap],
   1202 	      [AS_HELP_STRING([--enable-dnstap],
   1203 			      [enable dnstap support
   1204 			       (requires fstrm, protobuf-c)])],
   1205 	      [], [enable_dnstap=no])
   1206 
   1207 AS_IF([test "$enable_dnstap" != "no"],
   1208       [PKG_CHECK_MODULES([DNSTAP], [libfstrm libprotobuf-c], [],
   1209 			 [AC_MSG_FAILURE([Required libraries (fstrm, protobuf-c) were not found, please install them.])])
   1210        AC_PATH_PROG([FSTRM_CAPTURE], [fstrm_capture])
   1211        AC_PATH_PROG([PROTOC_C], [protoc-c])
   1212        AS_IF([test -z "$PROTOC_C"],
   1213 	     [AC_MSG_ERROR([protoc-c compiler not found])])
   1214        AC_DEFINE([HAVE_DNSTAP], 1, [Define to 1 to enable dnstap support])
   1215       ])
   1216 
   1217 AC_SUBST([DNSTAP_CFLAGS])
   1218 AC_SUBST([DNSTAP_LIBS])
   1219 AM_CONDITIONAL([HAVE_DNSTAP], [test "$enable_dnstap" != "no"])
   1220 #
   1221 # The following sections deal with tools used for formatting
   1222 # the documentation.  They are all optional, unless you are
   1223 # a developer editing the documentation source.
   1224 #
   1225 
   1226 #
   1227 # Look for sphinx-build
   1228 #
   1229 AC_ARG_VAR([SPHINX_BUILD], [path to sphinx-build binary used to build the documentation])
   1230 AC_PATH_PROG([SPHINX_BUILD], [sphinx-build], [])
   1231 AM_CONDITIONAL([HAVE_SPHINX_BUILD], [test -n "$SPHINX_BUILD"])
   1232 
   1233 #
   1234 # Build the man pages only if we have prebuilt manpages or we can build them from RST sources
   1235 #
   1236 AM_CONDITIONAL([BUILD_MANPAGES], [test -e doc/man/named.conf.5in || test -n "$SPHINX_BUILD"])
   1237 
   1238 #
   1239 # Pull release date from changelog.rst file last modification date
   1240 # for reproducible builds
   1241 #
   1242 release_date=`date -u -r doc/arm/changelog.rst +%Y-%m-%d`
   1243 AC_SUBST([RELEASE_DATE], $release_date)
   1244 
   1245 #
   1246 # Look for Doxygen
   1247 #
   1248 AC_PATH_PROGS([DOXYGEN], [doxygen])
   1249 
   1250 AC_CONFIG_FILES([doc/doxygen/doxygen-input-filter],
   1251 		[chmod +x doc/doxygen/doxygen-input-filter])
   1252 
   1253 #
   1254 # Look for curl
   1255 #
   1256 
   1257 AC_PATH_PROG(CURL, curl, curl)
   1258 AC_SUBST(CURL)
   1259 
   1260 #
   1261 # Look for nc
   1262 #
   1263 
   1264 AC_PATH_PROGS(NC, nc, nc)
   1265 AC_SUBST(NC)
   1266 
   1267 #
   1268 # IDN support using libidn2
   1269 #
   1270 
   1271 LIBIDN2_CFLAGS=
   1272 LIBIDN2_LIBS=
   1273 
   1274 # [pairwise: --with-libidn2=yes, --without-libidn2]
   1275 AC_ARG_WITH([libidn2],
   1276 	    [AS_HELP_STRING([--with-libidn2[=PATH]], [enable IDN support using GNU libidn2 [yes|no(default)|path]])],
   1277 	    [with_libidn2="$withval"], [with_libidn2="no"])
   1278 AS_CASE([$with_libidn2],
   1279 	[yes],	[PKG_CHECK_MODULES([LIBIDN2], [libidn2],
   1280 				   [AC_DEFINE([HAVE_LIBIDN2], [1], [Define if libidn2 was found])])],
   1281 	[no],	[],
   1282 	[*],	[AX_SAVE_FLAGS([libidn2])
   1283 		 LIBIDN2_CFLAGS="-I$with_libidn2/include"
   1284 		 LIBIDN2_LIBS="-L$with_libidn2/lib"
   1285 		 CFLAGS="$CFLAGS $LIBIDN2_CFLAGS"
   1286 		 LIBS="$LIBS $LIBIDN2_LIBS"
   1287 		 AC_CHECK_HEADERS([idn2.h],
   1288 				  [],
   1289 				  [AC_MSG_ERROR([idn2.h not found])])
   1290 		 AC_SEARCH_LIBS([idn2_to_ascii_lz], [idn2],
   1291 				[LIBIDN2_LIBS="$LIBIDN2_LIBS $ac_cv_search_idn2_to_ascii_lz"
   1292 				 AC_DEFINE([HAVE_LIBIDN2], [1], [Define if libidn2 was found])],
   1293 				[AC_MSG_ERROR([libidn2 requested, but not found])])
   1294 		AX_RESTORE_FLAGS([libidn2])])
   1295 AC_SUBST([LIBIDN2_CFLAGS])
   1296 AC_SUBST([LIBIDN2_LIBS])
   1297 
   1298 #
   1299 # Check whether to build with cmocka unit testing framework
   1300 #
   1301 # [pairwise: --with-cmocka=detect, --with-cmocka=yes, --without-cmocka]
   1302 AC_ARG_WITH([cmocka],
   1303 	    [AS_HELP_STRING([--with-cmocka=detect],[enable CMocka based tests (default is detect)])],
   1304 	    [],[with_cmocka=detect])
   1305 
   1306 AS_CASE([$with_cmocka],
   1307 	[no],[],
   1308 	[detect],[PKG_CHECK_MODULES([CMOCKA], [cmocka >= 1.1.3],
   1309 				    [AC_DEFINE([HAVE_CMOCKA], [1], [Use CMocka])
   1310 				     with_cmocka=yes],[with_cmocka=no])],
   1311 	[yes],[PKG_CHECK_MODULES([CMOCKA], [cmocka >= 1.1.3],
   1312 				 [AC_DEFINE([HAVE_CMOCKA], [1], [Use CMocka])])],
   1313 	[AC_MSG_ERROR([Use PKG_CONFIG_PATH to specify path to CMocka library])]
   1314        )
   1315 AC_SUBST([CMOCKA_CFLAGS])
   1316 AC_SUBST([CMOCKA_LIBS])
   1317 
   1318 AM_CONDITIONAL([HAVE_CMOCKA], [test "$with_cmocka" = "yes"])
   1319 
   1320 #
   1321 # Compile with jemalloc (either provided as package or wired in the system on FreeBSD)
   1322 #
   1323 # [pairwise: --with-jemalloc=detect, --with-jemalloc=yes, --without-jemalloc]
   1324 AC_ARG_WITH([jemalloc],
   1325 	    [AS_HELP_STRING([--with-jemalloc=detect],[enable jemalloc memory allocator (default is detect)])],
   1326 	    [],[with_jemalloc=detect])
   1327 
   1328 AS_CASE([$with_jemalloc],
   1329 	[no],[],
   1330 	[yes],[AX_CHECK_JEMALLOC(
   1331 		 [AC_DEFINE([HAVE_JEMALLOC], [1], [Define to 1 if jemalloc is available])],
   1332 		 [AC_MSG_ERROR([jemalloc not found])])],
   1333 	[AX_CHECK_JEMALLOC(
   1334 	   [AC_DEFINE([HAVE_JEMALLOC], [1], [Define to 1 if jemalloc is available])
   1335 	    with_jemalloc=yes],
   1336 	   [AC_MSG_WARN([jemalloc not found; performance will be reduced])
   1337 	    with_jemalloc=no])])
   1338 
   1339 AS_IF([test "$with_jemalloc" = "no"],
   1340       [AS_CASE([$host],
   1341 	       [*-freebsd*],[AC_MSG_ERROR([You cannot compile without jemalloc; jemalloc is the system allocator on FreeBSD])])])
   1342 
   1343 AM_CONDITIONAL([HAVE_JEMALLOC], [test "$with_jemalloc" = "yes"])
   1344 
   1345 #
   1346 # Check memory leaks in external libraries
   1347 #
   1348 # [pairwise: --enable-leak-detection, --disable-leak-detection]
   1349 AC_ARG_ENABLE([leak-detection],
   1350 	      [AS_HELP_STRING([--enable-leak-detection],[enable the memory leak detection in external libraries (libxml2, libuv, OpenSSL) (disabled by default)])],
   1351 	      [],[enable_leak_detection=no])
   1352 AS_CASE([$enable_leak_detection],
   1353 	[yes],[AC_DEFINE([ENABLE_LEAK_DETECTION], [1], [Define to enable memory leak detection in external libraries])])
   1354 
   1355 #
   1356 # was --enable-querytrace or --enable-singletrace specified?
   1357 #
   1358 # [pairwise: --enable-singletrace --enable-querytrace, --disable-singletrace --enable-querytrace, --disable-singletrace --disable-querytrace]
   1359 AC_ARG_ENABLE([singletrace],
   1360 	      AS_HELP_STRING([--enable-singletrace],
   1361 			     [enable single-query trace logging
   1362 			      [default=no]]),
   1363 	      enable_singletrace="$enableval", enable_singletrace="no")
   1364 
   1365 AC_MSG_CHECKING([whether to enable single-query trace logging])
   1366 case "$enable_singletrace" in
   1367 yes)
   1368 	enable_querytrace=yes
   1369 	AC_MSG_RESULT(yes)
   1370 	AC_DEFINE(WANT_SINGLETRACE, 1, [Define to enable single-query tracing.])
   1371 	;;
   1372 no)
   1373 	AC_MSG_RESULT(no)
   1374 	;;
   1375 *)
   1376 	AC_MSG_ERROR("--enable-singletrace requires yes or no")
   1377 	;;
   1378 esac
   1379 
   1380 # [pairwise: skip]
   1381 AC_ARG_ENABLE(querytrace,
   1382 	      AS_HELP_STRING([--enable-querytrace],
   1383 			     [enable very verbose query trace logging
   1384 				[default=no]]),
   1385 	      enable_querytrace="$enableval",
   1386 	      enable_querytrace="$enable_singletrace")
   1387 
   1388 AC_MSG_CHECKING([whether to enable query trace logging])
   1389 case "$enable_querytrace" in
   1390 yes)
   1391 	AC_MSG_RESULT(yes)
   1392 	AC_DEFINE(WANT_QUERYTRACE, 1, [Define to enable very verbose query trace logging.])
   1393 	;;
   1394 no)
   1395        AS_IF([test "$enable_singletrace" = "yes"],
   1396 	     [AC_MSG_ERROR([--enable-singletrace requires --enable-querytrace])])
   1397 	AC_MSG_RESULT(no)
   1398 	;;
   1399 *)
   1400 	AC_MSG_ERROR(["--enable-querytrace requires yes or no (not $enable_querytrace)"])
   1401 	;;
   1402 esac
   1403 
   1404 #
   1405 # Was --disable-auto-validation specified?
   1406 #
   1407 
   1408 validation_default=auto
   1409 
   1410 # [pairwise: --enable-auto-validation, --disable-auto-validation]
   1411 AC_ARG_ENABLE(auto-validation,
   1412 	      AS_HELP_STRING([--enable-auto-validation],
   1413 			     [turn on DNSSEC validation by default, using the IANA root key [default=yes]]),
   1414 	      [:],[enable_auto_validation=yes])
   1415 AS_IF([test "$enable_auto_validation" = "no"],[validation_default=yes])
   1416 AC_DEFINE_UNQUOTED([VALIDATION_DEFAULT], ["$validation_default"], [the default value of dnssec-validation option])
   1417 
   1418 #
   1419 #
   1420 # Response policy rewriting using DNS Response Policy Service (DNSRPS)
   1421 # interface.
   1422 #
   1423 # DNSRPS can be compiled into BIND everywhere with a reasonably
   1424 # modern C compiler.  It is enabled on systems with dlopen() and librpz.so.
   1425 #
   1426 dnsrps_avail=yes
   1427 AC_MSG_CHECKING([for librpz __attribute__s])
   1428 AC_COMPILE_IFELSE(
   1429   [AC_LANG_PROGRAM(
   1430      [[]],
   1431      [[
   1432        extern void f(char *p __attribute__((unused)), ...)
   1433        __attribute__((format(printf,1,2))) __attribute__((__noreturn__));
   1434      ]])],
   1435   [
   1436     librpz_have_attr=yes
   1437     AC_DEFINE([LIBRPZ_HAVE_ATTR], [1], [have __attribute__s used in librpz.h])
   1438     AC_MSG_RESULT([yes])
   1439   ],[
   1440     librpz_have_attr=no
   1441     AC_MSG_RESULT([no])
   1442   ])
   1443 
   1444 # [pairwise: --enable-dnsrps --enable-dnsrps-dl, --disable-dnsrps]
   1445 AC_ARG_ENABLE([dnsrps-dl],
   1446 	      [AS_HELP_STRING([--enable-dnsrps-dl],
   1447 			      [DNS Response Policy Service delayed link
   1448 			       [default=yes]])],
   1449 	      [enable_dnsrps_dl="$enableval"], [enable_dnsrps_dl="yes"])
   1450 
   1451 AS_IF([test "$enable_dnsrps_dl" = "yes" -a "$with_dlopen" = "no"],
   1452       [AC_MSG_ERROR([DNS Response Policy Service delayed link requires dlopen to be enabled])])
   1453 
   1454 # [pairwise: skip]
   1455 AC_ARG_WITH([dnsrps-libname],
   1456 	    [AS_HELP_STRING([--with-dnsrps-libname],
   1457 			    [DNSRPS provider library name (librpz.so)])],
   1458 	    [librpz_name="$withval"], [librpz_name="librpz.so"])
   1459 
   1460 # [pairwise: skip]
   1461 AC_ARG_WITH([dnsrps-dir],
   1462 	    [AS_HELP_STRING([--with-dnsrps-dir],
   1463 			    [path to DNSRPS provider library])],
   1464 	    [librpz_path="$withval/$librpz_name"], [librpz_path="$librpz_name"])
   1465 AC_DEFINE_UNQUOTED([DNSRPS_LIBRPZ_PATH], ["$librpz_path"],
   1466 		   [dnsrps $librpz_name])
   1467 AS_IF([test "$enable_dnsrps_dl" = "yes"],
   1468       [
   1469 	dnsrps_lib_open=2
   1470       ],[
   1471 	dnsrps_lib_open=1
   1472 	# Add librpz.so to linked libraries if we are not using dlopen()
   1473 	AC_SEARCH_LIBS([librpz_client_create], [rpz], [],
   1474 		[dnsrps_lib_open=0
   1475 		 dnsrps_avail=no])
   1476       ])
   1477 AC_DEFINE_UNQUOTED([DNSRPS_LIB_OPEN], [$dnsrps_lib_open],
   1478 		   [0=no DNSRPS  1=static link  2=dlopen()])
   1479 
   1480 # [pairwise: skip]
   1481 AC_ARG_ENABLE([dnsrps],
   1482 	      AS_HELP_STRING([--enable-dnsrps],
   1483 			     [enable DNS Response Policy Service API]),
   1484 	      [enable_dnsrps=$enableval], [enable_dnsrps=no])
   1485 
   1486 AS_IF([test "$enable_dnsrps" != "no"],[
   1487 	AS_IF([test "$dnsrps_lib_open" = "0"],
   1488 	      [AC_MSG_ERROR([dlopen and librpz.so needed for DNSRPS])])
   1489 	AC_DEFINE([USE_DNSRPS], [1], [Enable DNS Response Policy Service API])
   1490       ])
   1491 
   1492 AM_CONDITIONAL([DNSRPS], [test "$enable_dnsrps" != "no"])
   1493 
   1494 AC_CHECK_HEADERS([glob.h])
   1495 
   1496 #
   1497 # Support for constructor and destructor attributes
   1498 #
   1499 AX_GCC_FUNC_ATTRIBUTE([constructor])
   1500 AX_GCC_FUNC_ATTRIBUTE([destructor])
   1501 
   1502 #
   1503 # Check whether to enable User Statically Defined Tracing.
   1504 #
   1505 # This is supported only on Linux now and requires SystemTap libraries.
   1506 #
   1507 # [pairwise: --enable-tracing=auto, --enable-tracing=yes, --disable-tracing]
   1508 AC_ARG_ENABLE([tracing],
   1509 	      [AS_HELP_STRING([--enable-tracing],
   1510 			      [enable User Statically Defined Tracing])],
   1511 	      [],
   1512 	      [enable_tracing=auto])
   1513 
   1514 AC_ARG_VAR([DTRACE], [path to dtrace binary used to build User Statically Defined Tracing probes])
   1515 AC_PATH_PROGS([DTRACE], [dtrace])
   1516 AC_CHECK_HEADERS([sys/sdt.h])
   1517 
   1518 AC_MSG_CHECKING([whether to enable User Statically Defined Tracing support (default is auto)])
   1519 AS_CASE([$enable_tracing],
   1520 	[auto],	[enable_tracing=yes
   1521 		 AS_IF([test "$ac_cv_header_sys_sdt_h" != "yes"], [enable_tracing=no])
   1522 		 AS_IF([test -z "$DTRACE"],[enable_tracing=no])
   1523 		 AC_COMPILE_IFELSE(
   1524 		   [AC_LANG_PROGRAM([[]],
   1525 				    [[#if !defined(__has_feature)
   1526 				      #define __has_feature(x) 0
   1527 				      #endif /* if !defined(__has_feature) */
   1528 				      #if __has_feature(address_sanitizer)
   1529 				      #define __SANITIZE_ADDRESS__ 1
   1530 				      #endif /* if __has_feature(address_sanitizer) */
   1531 				      #if defined(__SANITIZE_ADDRESS__)
   1532 				      #error Address Sanitizer enabled
   1533 				      #endif
   1534 				     ]])],
   1535 		   [],
   1536 		   [enable_tracing=no]
   1537 		 )])
   1538 AS_CASE([$enable_tracing],
   1539 	[yes], [AS_IF([test "$ac_cv_header_sys_sdt_h" != "yes"],
   1540 		      [AC_MSG_ERROR([sys/sdt.h header not found])])
   1541 		AS_IF([test -z "$DTRACE"],
   1542 		      [AC_MSG_ERROR([The dtrace command not found])])
   1543 		AC_MSG_RESULT([yes])],
   1544 	[DTRACE=""
   1545 	 AC_MSG_RESULT([no])])
   1546 
   1547 AS_CASE([$host],
   1548 	[*-linux*],[have_systemtap=true])
   1549 
   1550 AM_CONDITIONAL([HAVE_SYSTEMTAP], [test -n "$have_systemtap"])
   1551 AM_CONDITIONAL([HAVE_DTRACE], [test -n "$DTRACE"])
   1552 
   1553 # Use shim script if dtrace is not available
   1554 AS_IF([test -z "$DTRACE"],
   1555       [DTRACE='$(top_srcdir)/util/dtrace.sh'])
   1556 
   1557 AC_SUBST([DTRACE])
   1558 
   1559 #
   1560 # Which should be the default zone database, RBTDB or QPZONE?
   1561 # [pairwise: --with-zonedb=qp, --with-zonedb=rbt]
   1562 #
   1563 AC_ARG_WITH([zonedb],
   1564 	    [AS_HELP_STRING([--with-zonedb=detect],[specify default zone database type (default is "qpzone")])],
   1565 	    [],[with_zonedb=qp])
   1566 zonedb="qpzone"
   1567 AS_CASE([$with_zonedb],
   1568 	[RBT*|rbt*],[zonedb="rbt"],
   1569         [QP|qp],[],
   1570 	[AC_MSG_ERROR([Unknown zone database type])]
   1571        )
   1572 AC_DEFINE_UNQUOTED([ZONEDB_DEFAULT], ["$zonedb"], [Default zone database type])
   1573 
   1574 #
   1575 # Which should be the default zone database, RBTDB or QPCACHE?
   1576 # [pairwise: --with-cachedb=qp, --with-cachedb=rbt]
   1577 #
   1578 AC_ARG_WITH([cachedb],
   1579 	    [AS_HELP_STRING([--with-cachedb=detect],[specify default cache database type (default is "qpcache")])],
   1580 	    [],[with_cachedb=qp])
   1581 cachedb="qpcache"
   1582 AS_CASE([$with_cachedb],
   1583 	[RBT*|rbt*],[cachedb="rbt"],
   1584         [QP*|qp*],[],
   1585 	[AC_MSG_ERROR([Unknown cache database type])]
   1586        )
   1587 AC_DEFINE_UNQUOTED([CACHEDB_DEFAULT], ["$cachedb"], [Default cache database type])
   1588 
   1589 #
   1590 # Files to configure.  These are listed here because we used to
   1591 # specify them as arguments to AC_OUTPUT.
   1592 #
   1593 
   1594 # Top
   1595 
   1596 AC_CONFIG_FILES([Makefile])
   1597 
   1598 # Binaries
   1599 
   1600 AC_CONFIG_FILES([bin/Makefile
   1601 		 bin/named/Makefile
   1602 		 bin/rndc/Makefile
   1603 		 bin/dig/Makefile
   1604 		 bin/delv/Makefile
   1605 		 bin/dnssec/Makefile
   1606 		 bin/tools/Makefile
   1607 		 bin/nsupdate/Makefile
   1608 		 bin/check/Makefile
   1609 		 bin/confgen/Makefile
   1610 		 bin/plugins/Makefile])
   1611 
   1612 # Libraries
   1613 
   1614 AC_CONFIG_FILES([lib/Makefile
   1615 		 lib/isc/Makefile
   1616 		 lib/dns/Makefile
   1617 		 lib/ns/Makefile
   1618 		 lib/isccfg/Makefile
   1619 		 lib/isccc/Makefile])
   1620 
   1621 # Documentation
   1622 
   1623 AC_CONFIG_FILES([doc/Makefile
   1624 		 doc/arm/Makefile
   1625 		 doc/man/Makefile
   1626 		 doc/misc/Makefile])
   1627 
   1628 # Unit tests and benchmarks
   1629 
   1630 AC_CONFIG_FILES([tests/Makefile
   1631 		 tests/bench/Makefile
   1632 		 tests/isc/Makefile
   1633 		 tests/dns/Makefile
   1634 		 tests/ns/Makefile
   1635 		 tests/isccfg/Makefile
   1636 		 tests/libtest/Makefile])
   1637 
   1638 AC_CONFIG_FILES([tests/unit-test-driver.sh],
   1639 		[chmod +x tests/unit-test-driver.sh])
   1640 
   1641 # System Tests
   1642 
   1643 AC_CONFIG_FILES([bin/tests/Makefile
   1644 		 bin/tests/system/Makefile
   1645 		 bin/tests/system/isctest/vars/.ac_vars/TOP_BUILDDIR
   1646 		 bin/tests/system/isctest/vars/.ac_vars/TOP_SRCDIR
   1647 		 bin/tests/system/isctest/vars/.ac_vars/FSTRM_CAPTURE
   1648 		 bin/tests/system/isctest/vars/.ac_vars/JQ
   1649 		 bin/tests/system/isctest/vars/.ac_vars/SHELL
   1650 		 bin/tests/system/isctest/vars/.ac_vars/PYTHON
   1651 		 bin/tests/system/isctest/vars/.ac_vars/PERL
   1652 		 bin/tests/system/isctest/vars/.ac_vars/CURL
   1653 		 bin/tests/system/isctest/vars/.ac_vars/NC
   1654 		 bin/tests/system/isctest/vars/.ac_vars/XMLLINT
   1655 		 bin/tests/system/isctest/vars/.ac_vars/XSLTPROC
   1656 		 bin/tests/system/isctest/vars/.ac_vars/PYTEST
   1657 		 bin/tests/system/dyndb/driver/Makefile
   1658 		 bin/tests/system/dlzexternal/driver/Makefile
   1659 		 bin/tests/system/hooks/driver/Makefile
   1660 		 bin/tests/system/rpz/testlib/Makefile
   1661                  ])
   1662 
   1663 AC_CONFIG_FILES([bin/tests/system/ifconfig.sh],
   1664 		[chmod +x bin/tests/system/ifconfig.sh])
   1665 AC_CONFIG_FILES([bin/tests/system/start.sh],
   1666 		[chmod +x bin/tests/system/start.sh])
   1667 AC_CONFIG_FILES([bin/tests/system/stop.sh],
   1668 		[chmod +x bin/tests/system/stop.sh])
   1669 
   1670 # Fuzz Tests
   1671 
   1672 AC_CONFIG_FILES([fuzz/Makefile])
   1673 
   1674 # Misc
   1675 
   1676 AC_CONFIG_FILES([util/check-make-install.sh])
   1677 
   1678 #
   1679 # Do it
   1680 #
   1681 
   1682 AC_OUTPUT
   1683 
   1684 # [pairwise: --enable-full-report, --disable-full-report]
   1685 AC_ARG_ENABLE(full-report,
   1686 	      AS_HELP_STRING([--enable-full-report],
   1687 			     [report values of all configure options]))
   1688 
   1689 report() {
   1690     echo "==============================================================================="
   1691     echo "Configuration summary:"
   1692     echo "-------------------------------------------------------------------------------"
   1693     echo "Optional features enabled:"
   1694     if test "yes" = "$with_jemalloc"; then
   1695 	echo "    Memory allocator: jemalloc"
   1696     fi
   1697     if test "yes" = "$enable_full_report" -o "rbt" = "$zonedb"; then
   1698             echo "    Default zone database type: $zonedb"
   1699     fi
   1700     if test "yes" = "$enable_full_report" -o "rbt" = "$zonedb"; then
   1701             echo "    Default cache database type: $cachedb"
   1702     fi
   1703     test "no" = "$enable_dnstap" || \
   1704 	    echo "    Allow 'dnstap' packet logging (--enable-dnstap)"
   1705     test -z "$MAXMINDDB_LIBS" || echo "    GeoIP2 access control (--enable-geoip)"
   1706     test -z "$GSSAPI_LIBS" || echo "    GSS-API (--with-gssapi)"
   1707 
   1708     # these lines are only printed if run with --enable-full-report
   1709     if test "yes" = "$enable_full_report"; then
   1710 	test -z "$LIBXML2_LIBS" || echo "    XML statistics (--with-libxml2)"
   1711 	test -z "$JSON_C_LIBS" || echo "    JSON statistics (--with-json-c): $JSON_C_CFLAGS $JSON_C_LIBS"
   1712 	test -z "$ZLIB_LIBS" || echo "    HTTP zlib compression (--with-zlib)"
   1713 	test -z "$LMDB_LIBS" || echo "    LMDB database to store configuration for 'addzone' zones (--with-lmdb)"
   1714 	test -z "$LIBIDN2_LIBS" || echo "    IDN support (--with-libidn2)"
   1715     fi
   1716 
   1717     test "yes" = "$enable_dnsrps" && \
   1718 	echo "    DNS Response Policy Service interface (--enable-dnsrps)"
   1719     test "yes" = "$enable_fixed_rrset" && \
   1720 	echo "    Allow 'fixed' rrset-order (--enable-fixed-rrset)"
   1721     test "yes" = "$enable_fips_mode" && \
   1722 	echo "    FIPS mode in OpenSSL (--enable-fips-mode)"
   1723 
   1724     test "yes" = "$enable_querytrace" && \
   1725 	echo "    Very verbose query trace logging (--enable-querytrace)"
   1726     test "yes" = "$enable_singletrace" && \
   1727 	echo "    Single-query trace logging (--enable-singletrace)"
   1728     test -z "$HAVE_CMOCKA" || echo "    CMocka Unit Testing Framework (--with-cmocka)"
   1729 
   1730     test "auto" = "$validation_default" && echo "    DNSSEC validation active by default (--enable-auto-validation)"
   1731 
   1732     echo "-------------------------------------------------------------------------------"
   1733     echo "    Library versions:"
   1734     echo "      OpenSSL:		$OPENSSL_VERSION"
   1735     echo "      libuv:		$LIBUV_VERSION"
   1736     echo "      Userspace-RCU:	$RCU_VERSION"
   1737     if test "no" != "$with_jemalloc"; then
   1738       echo "      jemalloc:		$JEMALLOC_VERSION"
   1739     fi
   1740     echo "-------------------------------------------------------------------------------"
   1741 
   1742     echo "Features disabled or unavailable on this platform:"
   1743     if test "no" = "$with_jemalloc"; then
   1744       echo "    Memory allocator: system"
   1745       echo
   1746       echo "    +------------------------------------------+"
   1747       echo "    |             ==== WARNING ====            |"
   1748       echo "    |                                          |"
   1749       echo "    | This is NOT a recommended configuration. |"
   1750       echo "    | Using the system memory allocator causes |"
   1751       echo "    | reduced performance and increased memory |"
   1752       echo "    | fragmentation. Installing the jemalloc   |"
   1753       echo "    | memory allocator (version >= 4.0.0) is   |"
   1754       echo "    | strongly recommended.                    |"
   1755       echo "    +------------------------------------------+"
   1756       echo
   1757     fi
   1758 
   1759     test "no" = "$enable_dnstap" && \
   1760 	    echo "    Allow 'dnstap' packet logging (--enable-dnstap)"
   1761     test -z "$MAXMINDDB_LIBS" && echo "    GeoIP2 access control (--enable-geoip)"
   1762     test -z "$GSSAPI_LIBS" && echo "    GSS-API (--with-gssapi)"
   1763 
   1764     test "no" = "$enable_dnsrps" && \
   1765 	echo "    DNS Response Policy Service interface (--enable-dnsrps)"
   1766 
   1767     test "yes" = "$enable_fixed_rrset" || \
   1768 	echo "    Allow 'fixed' rrset-order (--enable-fixed-rrset)"
   1769 
   1770     test "yes" = "$validation_default" && echo "    DNSSEC validation requires configuration (--enable-auto-validation)"
   1771 
   1772     test "yes" = "$enable_fips_mode" || \
   1773 	echo "    FIPS mode in OpenSSL (--enable-fips-mode)"
   1774 
   1775     test "yes" = "$enable_querytrace" || \
   1776 	echo "    Very verbose query trace logging (--enable-querytrace)"
   1777     test "yes" = "$enable_singletrace" || \
   1778 	echo "    Single-query trace logging (--enable-singletrace)"
   1779 
   1780     test "no" = "$with_cmocka" && echo "    CMocka Unit Testing Framework (--with-cmocka)"
   1781 
   1782     test -z "$LIBXML2_LIBS" && echo "    XML statistics (--with-libxml2)"
   1783     test -z "$JSON_C_LIBS" && echo "    JSON statistics (--with-json-c)"
   1784     test -z "$ZLIB_LIBS" && echo "    HTTP zlib compression (--with-zlib)"
   1785     test -z "$LMDB_LIBS" && echo "    LMDB database to store configuration for 'addzone' zones (--with-lmdb)"
   1786     test -z "$LIBIDN2_LIBS" && echo "    IDN support (--with-libidn2)"
   1787 
   1788     echo "-------------------------------------------------------------------------------"
   1789     echo "Configured paths:"
   1790     echo "    prefix: $prefix"
   1791     echo "    sysconfdir: $sysconfdir"
   1792     echo "    localstatedir: $localstatedir"
   1793     echo "-------------------------------------------------------------------------------"
   1794     echo "Compiler: $CC"
   1795     AS_IF([test "$GCC" = "yes"],
   1796 	  [$CC --version 2>&1 | sed 's/^/    /'],
   1797 	  [AS_CASE([$host],
   1798 		   [*-solaris*],[$CC -V 2>&1 | sed 's/^/    /'],
   1799 		   [$CC --version 2>&1 | sed 's/^/    /'])])
   1800     echo "CFLAGS: $STD_CFLAGS $CFLAGS"
   1801     echo "CPPFLAGS: $STD_CPPFLAGS $CPPFLAGS"
   1802     echo "LDFLAGS: $LDFLAGS"
   1803 
   1804     if test "X$ac_unrecognized_opts" != "X"; then
   1805 	echo "-------------------------------------------------------------------------------"
   1806 	echo "Unrecognized options:"
   1807 	echo "    $ac_unrecognized_opts"
   1808     fi
   1809 
   1810     if test "yes" != "$enable_full_report"; then
   1811 	echo "-------------------------------------------------------------------------------"
   1812 	echo "For more detail, use --enable-full-report."
   1813     fi
   1814     echo "==============================================================================="
   1815 }
   1816 
   1817 if test "yes" != "$silent"; then
   1818 	report
   1819 fi
   1820 
   1821 # Tell Emacs to edit this file in shell mode.
   1822 # Local Variables:
   1823 # mode: sh
   1824 # End:
   1825