Home | History | Annotate | Line # | Download | only in gen
setjmp.S revision 1.1 
      1 /*.$NetBSD: setjmp.S,v 1.1 2014/08/10 05:47:36 matt Exp $.*/
      2 
      3 /*-
      4  * Copyright (c) 2014 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to The NetBSD Foundation
      8  * by Matt Thomas of 3am Software Foundry.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     29  * POSSIBILITY OF SUCH DAMAGE.
     30  */
     31 
     32 #include <machine/asm.h>
     33 #include "assym.h"
     34 
     35 /*
     36  * C library -- setjmp, longjmp
     37  *
     38  *	longjmp(a,v)
     39  * will generate a "return(v)" from the last call to
     40  *	setjmp(a)
     41  * by restoring registers from the stack.
     42  * The previous signal state is restored.
     43  */
     44 
     45 	.section	.rodata.cst8,"aM",@progbits,8
     46 	.align	3
     47 .L_MAGIC:
     48 	.xword	_JB_MAGIC_AARCH64_SETJMP
     49 
     50 ENTRY(__setjmp14)
     51 	adrp	x7, .L_MAGIC
     52 	ldr	x7, [x7, #:lo12:.L_MAGIC]
     53 
     54 	mov	x3, sp
     55 	stp	x7,  x3,  [x0, #_JB_MAGIC]
     56 
     57 	stp	x19, x20, [x0, #_JB_X19]
     58 	stp	x21, x22, [x0, #_JB_X21]
     59 	stp	x23, x24, [x0, #_JB_X23]
     60 	stp	x25, x26, [x0, #_JB_X25]
     61 	stp	x27, x28, [x0, #_JB_X27]
     62 	stp	x29, x30, [x0, #_JB_X29]
     63 
     64 	mrs	x5, tpidr_el0
     65 	str	x5, [x0, #_JB_TPIDR]
     66 
     67 	stp	d8,  d9,  [x0, #_JB_D8]
     68 	stp	d10, d11, [x0, #_JB_D10]
     69 	stp	d12, d13, [x0, #_JB_D12]
     70 	stp	d14, d15, [x0, #_JB_D14]
     71 
     72 	/* Get the signal mask. */
     73 	add	x2, x0, #_JB_SIGMASK
     74 	mov	x1, #0
     75 	mov	x0, #0
     76 
     77 	stp	x29, x30, [sp, #-16]!
     78 	mov	x29, sp
     79 	bl	_C_LABEL(__sigprocmask14)
     80 	ldp	x29, x30, [sp], #16
     81 
     82 	mov	x0, xzr
     83 	ret
     84 END(__setjmp14)
     85 
     86 ENTRY(__longjmp14)
     87 	adrp	x7, .L_MAGIC
     88 	ldr	x7, [x7, #:lo12:.L_MAGIC]
     89 	ldp	x2, x3, [x0, #_JB_MAGIC]
     90 	cmp	x2, x7
     91 	b.ne	.Lbotch
     92 
     93 	ldp	x4,  x5,  [x0, #_JB_X29]
     94 	cbz	x3, .Lbotch
     95 	cbz	x4, .Lbotch
     96 	cbz	x5, .Lbotch
     97 
     98 	ldp	x19, x20, [x0, #_JB_X19]
     99 	ldp	x21, x22, [x0, #_JB_X21]
    100 	ldp	x23, x24, [x0, #_JB_X23]
    101 	ldp	x25, x26, [x0, #_JB_X25]
    102 	ldp	x27, x28, [x0, #_JB_X27]
    103 
    104 	ldr	x5, [x0, #_JB_TPIDR]
    105 	msr	tpidr_el0, x5
    106 
    107 	ldp	d8,  d9,  [x0, #_JB_D8]
    108 	ldp	d10, d11, [x0, #_JB_D10]
    109 	ldp	d12, d13, [x0, #_JB_D12]
    110 	ldp	d14, d15, [x0, #_JB_D14]
    111 
    112 	sub	sp, x3, #32
    113 
    114 	stp	x4, x5, [sp, #16]
    115 	str	x1, [sp, #8]
    116 	add	x29, sp, #16
    117 
    118 	mov	x2, #0
    119 	add	x1, x0, #_JB_SIGMASK
    120 	mov	x0, #3				/* SIG_SETMASK */
    121 	bl	_C_LABEL(__sigprocmask14)
    122 
    123 	ldp	x29, x30, [sp, #16]
    124 	ldr	x0, [sp, #8]
    125 	add	sp, sp, #32
    126 	ret
    127 
    128 	/* validation failed, die die die. */
    129 .Lbotch:
    130 	bl	_C_LABEL(longjmperror)
    131 	bl	_C_LABEL(abort)
    132 1:	b	1b		/* Cannot get here */
    133 END(__longjmp14)
    134