Home | History | Annotate | Line # | Download | only in gen
setjmp.S revision 1.8 
      1 /*	$NetBSD: setjmp.S,v 1.8 2005/10/16 17:26:24 christos Exp $	*/
      2 
      3 /*
      4  * Copyright (c) 1997 Mark Brinicombe
      5  * All rights reserved.
      6  *
      7  * Redistribution and use in source and binary forms, with or without
      8  * modification, are permitted provided that the following conditions
      9  * are met:
     10  * 1. Redistributions of source code must retain the above copyright
     11  *    notice, this list of conditions and the following disclaimer.
     12  * 2. Redistributions in binary form must reproduce the above copyright
     13  *    notice, this list of conditions and the following disclaimer in the
     14  *    documentation and/or other materials provided with the distribution.
     15  * 3. All advertising materials mentioning features or use of this software
     16  *    must display the following acknowledgement:
     17  *	This product includes software developed by Mark Brinicombe
     18  * 4. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  */
     34 
     35 #include <machine/asm.h>
     36 #include <machine/setjmp.h>
     37 
     38 /*
     39  * C library -- setjmp, longjmp
     40  *
     41  *	longjmp(a,v)
     42  * will generate a "return(v)" from the last call to
     43  *	setjmp(a)
     44  * by restoring registers from the stack.
     45  * The previous signal state is restored.
     46  */
     47 
     48 ENTRY(__setjmp14)
     49 	/* Get the signal mask. */
     50 	stmfd	sp!, {r0-r2, r14}
     51 	add	r2, r0, #(_JB_SIGMASK * 4)
     52 	mov	r1, #0x00000000
     53 	mov	r0, #0x00000000
     54 	bl	PIC_SYM(_C_LABEL(__sigprocmask14), PLT)
     55 	ldmfd	sp!, {r0-r2, r14}
     56 
     57 	ldr	r1, .Lsetjmp_magic
     58 	str	r1, [r0], #4
     59 
     60 #ifdef SOFTFLOAT
     61 	add	r0, r0, #52
     62 #else
     63 	/* Store fp registers */
     64 	sfm	f4, 4, [r0], #48
     65 	/* Store fpsr */
     66 	rfs	r1
     67 	str	r1, [r0], #0x0004
     68 #endif	/*SOFTFLOAT*/
     69 	/* Store integer registers */
     70         stmia	r0, {r4-r14}
     71         mov	r0, #0x00000000
     72         RET
     73 
     74 .Lsetjmp_magic:
     75 	.word	_JB_MAGIC_SETJMP
     76 
     77 
     78 ENTRY(__longjmp14)
     79 	ldr	r2, .Lsetjmp_magic
     80 	ldr	r3, [r0]
     81 	teq	r2, r3
     82 	bne	.Lbotch
     83 
     84 	/* Restore the signal mask. */
     85 	stmfd	sp!, {r0-r2, r14}
     86 	mov	r2, #0x00000000
     87 	add	r1, r0, #(_JB_SIGMASK * 4)
     88 	mov	r0, #3				/* SIG_SETMASK */
     89 	bl	PIC_SYM(_C_LABEL(__sigprocmask14), PLT)
     90 	ldmfd	sp!, {r0-r2, r14}
     91 
     92 	add	r0, r0, #4
     93 #ifdef SOFTFLOAT
     94 	add	r0, r0, #52
     95 #else
     96 	/* Restore fp registers */
     97 	lfm	f4, 4, [r0], #48
     98 	/* Restore FPSR */
     99 	ldr	r4, [r0], #0x0004
    100 	wfs	r4
    101 #endif	/* SOFTFLOAT */
    102 	/* Restore integer registers */
    103         ldmia	r0, {r4-r14}
    104 
    105 	/* Validate sp and r14 */
    106 	teq	sp, #0
    107 	teqne	r14, #0
    108 	beq	.Lbotch
    109 
    110 	/* Set return value */
    111 
    112 	mov	r0, r1
    113 	teq	r0, #0x00000000
    114 	moveq	r0, #0x00000001
    115 	RET
    116 
    117 	/* validation failed, die die die. */
    118 .Lbotch:
    119 	bl	PIC_SYM(_C_LABEL(longjmperror), PLT)
    120 	bl	PIC_SYM(_C_LABEL(abort), PLT)
    121 	b	. - 8		/* Cannot get here */
    122