Home | History | Annotate | Line # | Download | only in string
bcopy.S revision 1.5 
      1 /*-
      2  * Copyright (c) 1990 The Regents of the University of California.
      3  * All rights reserved.
      4  *
      5  * This code is derived from locore.s.
      6  *
      7  * Redistribution and use in source and binary forms, with or without
      8  * modification, are permitted provided that the following conditions
      9  * are met:
     10  * 1. Redistributions of source code must retain the above copyright
     11  *    notice, this list of conditions and the following disclaimer.
     12  * 2. Redistributions in binary form must reproduce the above copyright
     13  *    notice, this list of conditions and the following disclaimer in the
     14  *    documentation and/or other materials provided with the distribution.
     15  * 3. All advertising materials mentioning features or use of this software
     16  *    must display the following acknowledgement:
     17  *	This product includes software developed by the University of
     18  *	California, Berkeley and its contributors.
     19  * 4. Neither the name of the University nor the names of its contributors
     20  *    may be used to endorse or promote products derived from this software
     21  *    without specific prior written permission.
     22  *
     23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     33  * SUCH DAMAGE.
     34  */
     35 
     36 #include <machine/asm.h>
     37 
     38 #if defined(LIBC_SCCS)
     39 	RCSID("$NetBSD: bcopy.S,v 1.5 1995/04/28 22:57:57 jtc Exp $")
     40 #endif
     41 
     42 	/*
     43 	 * (ov)bcopy (src,dst,cnt)
     44 	 *  ws (at) tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
     45 	 */
     46 
     47 #ifdef MEMCOPY
     48 ENTRY(memcpy)
     49 #else
     50 #ifdef MEMMOVE
     51 ENTRY(memmove)
     52 #else
     53 ENTRY(bcopy)
     54 #endif
     55 #endif
     56 	pushl	%esi
     57 	pushl	%edi
     58 #if defined(MEMCOPY) || defined(MEMMOVE)
     59 	movl	12(%esp),%edi
     60 	movl	16(%esp),%esi
     61 #else
     62 	movl	12(%esp),%esi
     63 	movl	16(%esp),%edi
     64 #endif
     65 	movl	20(%esp),%ecx
     66 	cmpl	%esi,%edi	/* potentially overlapping? */
     67 	jnb	1f
     68 	cld			/* nope, copy forwards. */
     69 	shrl	$2,%ecx		/* copy by words */
     70 	rep
     71 	movsl
     72 	movl	20(%esp),%ecx
     73 	andl	$3,%ecx		/* any bytes left? */
     74 	rep
     75 	movsb
     76 #if defined(MEMCOPY) || defined(MEMMOVE)
     77 	movl	12(%esp),%eax
     78 #endif
     79 	popl	%edi
     80 	popl	%esi
     81 	ret
     82 1:
     83 	addl	%ecx,%edi	/* copy backwards. */
     84 	addl	%ecx,%esi
     85 	std
     86 	andl	$3,%ecx		/* any fractional bytes? */
     87 	decl	%edi
     88 	decl	%esi
     89 	rep
     90 	movsb
     91 	movl	20(%esp),%ecx	/* copy remainder by words */
     92 	shrl	$2,%ecx
     93 	subl	$3,%esi
     94 	subl	$3,%edi
     95 	rep
     96 	movsl
     97 #if defined(MEMCOPY) || defined(MEMMOVE)
     98 	movl	12(%esp),%eax
     99 #endif
    100 	popl	%edi
    101 	popl	%esi
    102 	cld
    103 	ret
    104