Home | History | Annotate | Line # | Download | only in string
bzero.S revision 1.6 
      1 /*
      2  * Copyright (c) 1993 Winning Strategies, Inc.
      3  * All rights reserved.
      4  *
      5  * Redistribution and use in source and binary forms, with or without
      6  * modification, are permitted provided that the following conditions
      7  * are met:
      8  * 1. Redistributions of source code must retain the above copyright
      9  *    notice, this list of conditions and the following disclaimer.
     10  * 2. Redistributions in binary form must reproduce the above copyright
     11  *    notice, this list of conditions and the following disclaimer in the
     12  *    documentation and/or other materials provided with the distribution.
     13  * 3. All advertising materials mentioning features or use of this software
     14  *    must display the following acknowledgement:
     15  *      This product includes software developed by Winning Strategies, Inc.
     16  * 4. The name of the author may not be used to endorse or promote products
     17  *    derived from this software without specific prior written permission
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
     20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
     21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
     22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
     23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
     24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
     28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
     29  *
     30  *	$Id: bzero.S,v 1.6 1995/02/05 14:58:44 mycroft Exp $
     31  */
     32 
     33 #include <machine/asm.h>
     34 
     35 #if defined(LIBC_SCCS)
     36 	RCSID("$Id: bzero.S,v 1.6 1995/02/05 14:58:44 mycroft Exp $")
     37 #endif
     38 
     39 /*
     40  * bzero (void *b, size_t len)
     41  *	write len zero bytes to the string b.
     42  *
     43  * Written by:
     44  *	J.T. Conklin (jtc (at) wimsey.com), Winning Strategies, Inc.
     45  */
     46 
     47 ENTRY(bzero)
     48 	pushl	%edi
     49 	movl	8(%esp),%edi
     50 	movl	12(%esp),%edx
     51 
     52 	cld				/* set fill direction forward */
     53 	xorl	%eax,%eax		/* set fill data to 0 */
     54 
     55 	/*
     56 	 * if the string is too short, it's really not worth the overhead
     57 	 * of aligning to word boundries, etc.  So we jump to a plain
     58 	 * unaligned set.
     59 	 */
     60 	cmpl	$16,%edx
     61 	jb	L1
     62 
     63 	movl	%edi,%ecx		/* compute misalignment */
     64 	negl	%ecx
     65 	andl	$3,%ecx
     66 	subl	%ecx,%edx
     67 	rep				/* zero until word aligned */
     68 	stosb
     69 
     70 	movl	%edx,%ecx		/* zero by words */
     71 	shrl	$2,%ecx
     72 	andl	$3,%edx
     73 	rep
     74 	stosl
     75 
     76 L1:	movl	%edx,%ecx		/* zero remainder by bytes */
     77 	rep
     78 	stosb
     79 
     80 	popl	%edi
     81 	ret
     82