Home | History | Annotate | Line # | Download | only in string
swab.S revision 1.1 
      1 /*
      2  * Copyright (c) 1993 Winning Strategies, Inc.
      3  * All rights reserved.
      4  *
      5  * Redistribution and use in source and binary forms, with or without
      6  * modification, are permitted provided that the following conditions
      7  * are met:
      8  * 1. Redistributions of source code must retain the above copyright
      9  *    notice, this list of conditions and the following disclaimer.
     10  * 2. Redistributions in binary form must reproduce the above copyright
     11  *    notice, this list of conditions and the following disclaimer in the
     12  *    documentation and/or other materials provided with the distribution.
     13  * 3. All advertising materials mentioning features or use of this software
     14  *    must display the following acknowledgement:
     15  *      This product includes software developed by Winning Strategies, Inc.
     16  * 4. The name of the author may not be used to endorse or promote products
     17  *    derived from this software withough specific prior written permission
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
     20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
     21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
     22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
     23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
     24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
     28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
     29  *
     30  *	$Id: swab.S,v 1.1 1993/10/07 00:19:37 cgd Exp $
     31  */
     32 
     33 #if defined(LIBC_RCS) && !defined(lint)
     34 	.text
     35 	.asciz "$Id: swab.S,v 1.1 1993/10/07 00:19:37 cgd Exp $"
     36 #endif
     37 
     38 #include "DEFS.h"
     39 
     40 /*
     41  * void
     42  * swab (const void *src, void *dst, size_t len)
     43  *	copy len bytes from src to dst, swapping adjacent bytes
     44  *
     45  * On the i486, this code is negligibly faster than the code generated
     46  * by gcc at about half the size.  If my i386 databook is correct, it
     47  * should be considerably faster than the gcc code on a i386.
     48  *
     49  * Written by:
     50  *	J.T. Conklin (jtc (at) wimsey.com), Winning Strategies, Inc.
     51  */
     52 
     53 ENTRY(swab)
     54 	pushl	%esi
     55 	pushl	%edi
     56 	movl	12(%esp),%esi
     57 	movl	16(%esp),%edi
     58 	movl	20(%esp),%ecx
     59 	shrl	$1,%ecx
     60 	jz	L4			# len = 0, jmp to func exit
     61 
     62 	cld				# set direction forward
     63 
     64 	testl	$7,%ecx			# copy first group of 1 to 7 words
     65 	je	L2			# while swaping alternate bytes.
     66 	.align	2,0x90
     67 L1:	lodsw
     68 	xchgb	%al,%ah
     69 	stosw
     70 	decl	%ecx
     71 	testl	$7,%ecx
     72 	jne	L1
     73 
     74 L2:	shrl	$3,%ecx			# copy remainder 8 words at a time
     75 	jz	L4			# while swapping alternate bytes.
     76 	.align	2,0x90
     77 L3:	lodsw
     78 	xchgb	%al,%ah
     79 	stosw
     80 	lodsw
     81 	xchgb	%al,%ah
     82 	stosw
     83 	lodsw
     84 	xchgb	%al,%ah
     85 	stosw
     86 	lodsw
     87 	xchgb	%al,%ah
     88 	stosw
     89 	lodsw
     90 	xchgb	%al,%ah
     91 	stosw
     92 	lodsw
     93 	xchgb	%al,%ah
     94 	stosw
     95 	lodsw
     96 	xchgb	%al,%ah
     97 	stosw
     98 	lodsw
     99 	xchgb	%al,%ah
    100 	stosw
    101 	decl	%ecx
    102 	jnz	L3
    103 
    104 L4:
    105 	popl	%edi
    106 	popl	%esi
    107 	ret
    108