Home | History | Annotate | Line # | Download | only in string
bcmp.S revision 1.5 
      1 /*	$NetBSD: bcmp.S,v 1.5 1996/09/17 01:32:30 jonathan Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 1991, 1993
      5  *	The Regents of the University of California.  All rights reserved.
      6  *
      7  * This code is derived from software contributed to Berkeley by
      8  * Ralph Campbell.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  * 3. All advertising materials mentioning features or use of this software
     19  *    must display the following acknowledgement:
     20  *	This product includes software developed by the University of
     21  *	California, Berkeley and its contributors.
     22  * 4. Neither the name of the University nor the names of its contributors
     23  *    may be used to endorse or promote products derived from this software
     24  *    without specific prior written permission.
     25  *
     26  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     27  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     28  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     29  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     30  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     31  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     32  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     33  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     34  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     35  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     36  * SUCH DAMAGE.
     37  */
     38 
     39 #include <mips/asm.h>
     40 
     41 #if defined(LIBC_SCCS) && !defined(lint)
     42 	ASMSTR("from: @(#)bcmp.s	8.1 (Berkeley) 6/4/93")
     43 	ASMSTR("$NetBSD: bcmp.S,v 1.5 1996/09/17 01:32:30 jonathan Exp $")
     44 #endif /* LIBC_SCCS and not lint */
     45 
     46 #ifdef ABICALLS
     47 	.abicalls
     48 #endif
     49 
     50 /* bcmp(s1, s2, n) */
     51 
     52 #ifdef MIPSEL
     53 #	define	LWHI	lwr
     54 #	define	LWLO	lwl
     55 #	define	SWHI	swr
     56 #	define	SWLO	swl
     57 #endif
     58 #ifdef MIPSEB
     59 #	define	LWHI	lwl
     60 #	define	LWLO	lwr
     61 #	define	SWHI	swl
     62 #	define	SWLO	swr
     63 #endif
     64 
     65 LEAF(bcmp)
     66 	.set	noreorder
     67 	blt	a2, 16, small		# is it worth any trouble?
     68 	xor	v0, a0, a1		# compare low two bits of addresses
     69 	and	v0, v0, 3
     70 	subu	a3, zero, a1		# compute # bytes to word align address
     71 	bne	v0, zero, unaligned	# not possible to align addresses
     72 	and	a3, a3, 3
     73 
     74 	beq	a3, zero, 1f
     75 	subu	a2, a2, a3		# subtract from remaining count
     76 	move	v0, v1			# init v0,v1 so unmodified bytes match
     77 	LWHI	v0, 0(a0)		# read 1, 2, or 3 bytes
     78 	LWHI	v1, 0(a1)
     79 	addu	a1, a1, a3
     80 	bne	v0, v1, nomatch
     81 	addu	a0, a0, a3
     82 1:
     83 	and	a3, a2, ~3		# compute number of whole words left
     84 	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
     85 	addu	a3, a3, a0		# compute ending address
     86 2:
     87 	lw	v0, 0(a0)		# compare words
     88 	lw	v1, 0(a1)
     89 	addu	a0, a0, 4
     90 	bne	v0, v1, nomatch
     91 	addu	a1, a1, 4
     92 	bne	a0, a3, 2b
     93 	nop
     94 	b	small			# finish remainder
     95 	nop
     96 unaligned:
     97 	beq	a3, zero, 2f
     98 	subu	a2, a2, a3		# subtract from remaining count
     99 	addu	a3, a3, a0		# compute ending address
    100 1:
    101 	lbu	v0, 0(a0)		# compare bytes until a1 word aligned
    102 	lbu	v1, 0(a1)
    103 	addu	a0, a0, 1
    104 	bne	v0, v1, nomatch
    105 	addu	a1, a1, 1
    106 	bne	a0, a3, 1b
    107 	nop
    108 2:
    109 	and	a3, a2, ~3		# compute number of whole words left
    110 	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
    111 	addu	a3, a3, a0		# compute ending address
    112 3:
    113 	LWHI	v0, 0(a0)		# compare words a0 unaligned, a1 aligned
    114 	LWLO	v0, 3(a0)
    115 	lw	v1, 0(a1)
    116 	addu	a0, a0, 4
    117 	bne	v0, v1, nomatch
    118 	addu	a1, a1, 4
    119 	bne	a0, a3, 3b
    120 	nop
    121 small:
    122 	ble	a2, zero, match
    123 	addu	a3, a2, a0		# compute ending address
    124 1:
    125 	lbu	v0, 0(a0)
    126 	lbu	v1, 0(a1)
    127 	addu	a0, a0, 1
    128 	bne	v0, v1, nomatch
    129 	addu	a1, a1, 1
    130 	bne	a0, a3, 1b
    131 	nop
    132 match:
    133 	j	ra
    134 	move	v0, zero
    135 nomatch:
    136 	j	ra
    137 	li	v0, 1
    138 	.set	reorder
    139 END(bcmp)
    140