Home | History | Annotate | Line # | Download | only in string
bcmp.S revision 1.6.14.1 
      1 /*	$NetBSD: bcmp.S,v 1.6.14.1 2002/11/11 22:21:33 nathanw Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 1991, 1993
      5  *	The Regents of the University of California.  All rights reserved.
      6  *
      7  * This code is derived from software contributed to Berkeley by
      8  * Ralph Campbell.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  * 3. All advertising materials mentioning features or use of this software
     19  *    must display the following acknowledgement:
     20  *	This product includes software developed by the University of
     21  *	California, Berkeley and its contributors.
     22  * 4. Neither the name of the University nor the names of its contributors
     23  *    may be used to endorse or promote products derived from this software
     24  *    without specific prior written permission.
     25  *
     26  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     27  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     28  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     29  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     30  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     31  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     32  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     33  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     34  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     35  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     36  * SUCH DAMAGE.
     37  */
     38 
     39 #include <mips/asm.h>
     40 #define _LOCORE		/* XXX not really, just assembly-code source */
     41 #include <machine/endian.h>	/* LWLO/LWHI, SWLO/SWHI */
     42 
     43 #if defined(LIBC_SCCS) && !defined(lint)
     44 	ASMSTR("from: @(#)bcmp.s	8.1 (Berkeley) 6/4/93")
     45 	ASMSTR("$NetBSD: bcmp.S,v 1.6.14.1 2002/11/11 22:21:33 nathanw Exp $")
     46 #endif /* LIBC_SCCS and not lint */
     47 
     48 #ifdef __ABICALLS__
     49 	.abicalls
     50 #endif
     51 
     52 /* bcmp(s1, s2, n) */
     53 
     54 
     55 LEAF(bcmp)
     56 	.set	noreorder
     57 	blt	a2, 16, small		# is it worth any trouble?
     58 	xor	v0, a0, a1		# compare low two bits of addresses
     59 	and	v0, v0, 3
     60 	subu	a3, zero, a1		# compute # bytes to word align address
     61 	bne	v0, zero, unaligned	# not possible to align addresses
     62 	and	a3, a3, 3
     63 
     64 	beq	a3, zero, 1f
     65 	subu	a2, a2, a3		# subtract from remaining count
     66 	move	v0, v1			# init v0,v1 so unmodified bytes match
     67 	LWHI	v0, 0(a0)		# read 1, 2, or 3 bytes
     68 	LWHI	v1, 0(a1)
     69 	addu	a1, a1, a3
     70 	bne	v0, v1, nomatch
     71 	addu	a0, a0, a3
     72 1:
     73 	and	a3, a2, ~3		# compute number of whole words left
     74 	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
     75 	addu	a3, a3, a0		# compute ending address
     76 2:
     77 	lw	v0, 0(a0)		# compare words
     78 	lw	v1, 0(a1)
     79 	addu	a0, a0, 4
     80 	bne	v0, v1, nomatch
     81 	addu	a1, a1, 4
     82 	bne	a0, a3, 2b
     83 	nop
     84 	b	small			# finish remainder
     85 	nop
     86 unaligned:
     87 	beq	a3, zero, 2f
     88 	subu	a2, a2, a3		# subtract from remaining count
     89 	addu	a3, a3, a0		# compute ending address
     90 1:
     91 	lbu	v0, 0(a0)		# compare bytes until a1 word aligned
     92 	lbu	v1, 0(a1)
     93 	addu	a0, a0, 1
     94 	bne	v0, v1, nomatch
     95 	addu	a1, a1, 1
     96 	bne	a0, a3, 1b
     97 	nop
     98 2:
     99 	and	a3, a2, ~3		# compute number of whole words left
    100 	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
    101 	addu	a3, a3, a0		# compute ending address
    102 3:
    103 	LWHI	v0, 0(a0)		# compare words a0 unaligned, a1 aligned
    104 	LWLO	v0, 3(a0)
    105 	lw	v1, 0(a1)
    106 	addu	a0, a0, 4
    107 	bne	v0, v1, nomatch
    108 	addu	a1, a1, 4
    109 	bne	a0, a3, 3b
    110 	nop
    111 small:
    112 	ble	a2, zero, match
    113 	addu	a3, a2, a0		# compute ending address
    114 1:
    115 	lbu	v0, 0(a0)
    116 	lbu	v1, 0(a1)
    117 	addu	a0, a0, 1
    118 	bne	v0, v1, nomatch
    119 	addu	a1, a1, 1
    120 	bne	a0, a3, 1b
    121 	nop
    122 match:
    123 	j	ra
    124 	move	v0, zero
    125 nomatch:
    126 	j	ra
    127 	li	v0, 1
    128 	.set	reorder
    129 END(bcmp)
    130