Home | History | Annotate | Line # | Download | only in string
bcmp.S revision 1.8 
      1 /*	$NetBSD: bcmp.S,v 1.8 2003/08/07 16:42:16 agc Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 1991, 1993
      5  *	The Regents of the University of California.  All rights reserved.
      6  *
      7  * This code is derived from software contributed to Berkeley by
      8  * Ralph Campbell.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  * 3. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  */
     34 
     35 #include <mips/asm.h>
     36 #define _LOCORE		/* XXX not really, just assembly-code source */
     37 #include <machine/endian.h>	/* LWLO/LWHI, SWLO/SWHI */
     38 
     39 #if defined(LIBC_SCCS) && !defined(lint)
     40 	ASMSTR("from: @(#)bcmp.s	8.1 (Berkeley) 6/4/93")
     41 	ASMSTR("$NetBSD: bcmp.S,v 1.8 2003/08/07 16:42:16 agc Exp $")
     42 #endif /* LIBC_SCCS and not lint */
     43 
     44 #ifdef __ABICALLS__
     45 	.abicalls
     46 #endif
     47 
     48 /* bcmp(s1, s2, n) */
     49 
     50 
     51 LEAF(bcmp)
     52 	.set	noreorder
     53 	blt	a2, 16, small		# is it worth any trouble?
     54 	xor	v0, a0, a1		# compare low two bits of addresses
     55 	and	v0, v0, 3
     56 	subu	a3, zero, a1		# compute # bytes to word align address
     57 	bne	v0, zero, unaligned	# not possible to align addresses
     58 	and	a3, a3, 3
     59 
     60 	beq	a3, zero, 1f
     61 	subu	a2, a2, a3		# subtract from remaining count
     62 	move	v0, v1			# init v0,v1 so unmodified bytes match
     63 	LWHI	v0, 0(a0)		# read 1, 2, or 3 bytes
     64 	LWHI	v1, 0(a1)
     65 	addu	a1, a1, a3
     66 	bne	v0, v1, nomatch
     67 	addu	a0, a0, a3
     68 1:
     69 	and	a3, a2, ~3		# compute number of whole words left
     70 	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
     71 	addu	a3, a3, a0		# compute ending address
     72 2:
     73 	lw	v0, 0(a0)		# compare words
     74 	lw	v1, 0(a1)
     75 	addu	a0, a0, 4
     76 	bne	v0, v1, nomatch
     77 	addu	a1, a1, 4
     78 	bne	a0, a3, 2b
     79 	nop
     80 	b	small			# finish remainder
     81 	nop
     82 unaligned:
     83 	beq	a3, zero, 2f
     84 	subu	a2, a2, a3		# subtract from remaining count
     85 	addu	a3, a3, a0		# compute ending address
     86 1:
     87 	lbu	v0, 0(a0)		# compare bytes until a1 word aligned
     88 	lbu	v1, 0(a1)
     89 	addu	a0, a0, 1
     90 	bne	v0, v1, nomatch
     91 	addu	a1, a1, 1
     92 	bne	a0, a3, 1b
     93 	nop
     94 2:
     95 	and	a3, a2, ~3		# compute number of whole words left
     96 	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
     97 	addu	a3, a3, a0		# compute ending address
     98 3:
     99 	LWHI	v0, 0(a0)		# compare words a0 unaligned, a1 aligned
    100 	LWLO	v0, 3(a0)
    101 	lw	v1, 0(a1)
    102 	addu	a0, a0, 4
    103 	bne	v0, v1, nomatch
    104 	addu	a1, a1, 4
    105 	bne	a0, a3, 3b
    106 	nop
    107 small:
    108 	ble	a2, zero, match
    109 	addu	a3, a2, a0		# compute ending address
    110 1:
    111 	lbu	v0, 0(a0)
    112 	lbu	v1, 0(a1)
    113 	addu	a0, a0, 1
    114 	bne	v0, v1, nomatch
    115 	addu	a1, a1, 1
    116 	bne	a0, a3, 1b
    117 	nop
    118 match:
    119 	j	ra
    120 	move	v0, zero
    121 nomatch:
    122 	j	ra
    123 	li	v0, 1
    124 	.set	reorder
    125 END(bcmp)
    126