Home | History | Annotate | Line # | Download | only in string
bzero.S revision 1.8 
      1 /*	$NetBSD: bzero.S,v 1.8 2003/08/07 16:42:16 agc Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 1991, 1993
      5  *	The Regents of the University of California.  All rights reserved.
      6  *
      7  * This code is derived from software contributed to Berkeley by
      8  * Ralph Campbell.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  * 3. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  */
     34 
     35 #include <mips/asm.h>
     36 
     37 #if defined(LIBC_SCCS) && !defined(lint)
     38 	ASMSTR("from: @(#)bzero.s	8.1 (Berkeley) 6/4/93")
     39 	ASMSTR("$NetBSD: bzero.S,v 1.8 2003/08/07 16:42:16 agc Exp $")
     40 #endif /* LIBC_SCCS and not lint */
     41 
     42 
     43 #define _LOCORE		/* XXX not really, just assembly-code source */
     44 #include <machine/endian.h>
     45 
     46 #ifdef __ABICALLS__
     47 	.abicalls
     48 #endif
     49 
     50 /* bzero(s1, n) */
     51 
     52 LEAF(bzero)
     53 	.set	noreorder
     54 	blt	a1, 12, smallclr	# small amount to clear?
     55 	subu	a3, zero, a0		# compute # bytes to word align address
     56 	and	a3, a3, 3
     57 	beq	a3, zero, 1f		# skip if word aligned
     58 	subu	a1, a1, a3		# subtract from remaining count
     59 	SWHI	zero, 0(a0)		# clear 1, 2, or 3 bytes to align
     60 	addu	a0, a0, a3
     61 1:
     62 	and	v0, a1, 3		# compute number of words left
     63 	subu	a3, a1, v0
     64 	move	a1, v0
     65 	addu	a3, a3, a0		# compute ending address
     66 2:
     67 	addu	a0, a0, 4		# clear words
     68 	bne	a0, a3, 2b		#   unrolling loop doesnt help
     69 	sw	zero, -4(a0)		#   since we are limited by memory speed
     70 smallclr:
     71 	ble	a1, zero, 2f
     72 	addu	a3, a1, a0		# compute ending address
     73 1:
     74 	addu	a0, a0, 1		# clear bytes
     75 	bne	a0, a3, 1b
     76 	sb	zero, -1(a0)
     77 2:
     78 	j	ra
     79 	nop
     80 END(bzero)
     81