Home | History | Annotate | Line # | Download | only in sys
__clone.S revision 1.3.16.2 
      1 /*	$NetBSD: __clone.S,v 1.3.16.2 2007/01/04 18:52:58 bouyer Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 2001 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to The NetBSD Foundation
      8  * by Jason R. Thorpe.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  * 3. All advertising materials mentioning features or use of this software
     19  *    must display the following acknowledgement:
     20  *	This product includes software developed by the NetBSD
     21  *	Foundation, Inc. and its contributors.
     22  * 4. Neither the name of The NetBSD Foundation nor the names of its
     23  *    contributors may be used to endorse or promote products derived
     24  *    from this software without specific prior written permission.
     25  *
     26  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     27  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     28  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     29  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     30  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     31  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     32  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     33  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     34  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     35  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     36  * POSSIBILITY OF SUCH DAMAGE.
     37  */
     38 
     39 #include <sys/errno.h>
     40 
     41 #include "SYS.h"
     42 
     43 #ifdef WEAK_ALIAS
     44 WEAK_ALIAS(clone, __clone)
     45 #endif
     46 
     47 /*
     48  * int __clone(int (*fn)(void *), void *stack, int flags, void *arg);
     49  */
     50 ENTRY(__clone)
     51 	save	%sp, -CCFSZ, %sp
     52 
     53 	/*
     54 	 * Sanity checks: func and stack may not be NULL.
     55 	 */
     56 	tst	%i0
     57 	be	8f		! func == NULL, bail
     58 	 orcc	%i1, %g0, %o1	! setup stack arg for syscall, test
     59 	be	8f		! stack == NULL, bail
     60 	 mov	%i2, %o0	! setup flags arg for syscall
     61 
     62 	/*
     63 	 * Allocate "caller's" frame in the child stack as ABI
     64 	 * requires.
     65 	 *
     66 	 * We pass the function and the argument to the child by
     67 	 * stashing them at the bottom of the frame.  There they are
     68 	 * safe from window spill would we need to take one as it's
     69 	 * below the window save area.
     70 	 */
     71 	sub	%o1, CCFSZ, %o1	! make space on the child's stack
     72 	st	%i0, [%o1+CCFSZ-8]	! save func
     73 	st	%i3, [%o1+CCFSZ-4]	! save arg
     74 
     75 	/*
     76 	 * Args are now set up for system call as (flags, stack).
     77 	 */
     78 	mov	SYS___clone, %g1
     79 	t	ST_SYSCALL
     80 	bcs	9f
     81 	 tst	%o1		! %o1 (rv[1]) == 0 in parent
     82 
     83 1:	bz	2f		! yes, parent
     84 	 ld	[%sp+CCFSZ-8], %l0	! grab the function...
     85 	call	%l0 		! Call the clone's entry point.
     86 	 ld	[%sp+CCFSZ-4], %o0	! ...and the argument from the stack
     87 
     88 	CALL(_C_LABEL(_exit))
     89 	/* NOTREACHED */
     90 
     91 2:	ret
     92 	 restore %g0, %o0, %o0
     93 
     94 8:	restore	%g0, EINVAL, %o0
     95 	ERROR()
     96 	/* NOTREACHED */
     97 
     98 9:	restore %g0, %o0, %o0
     99 	ERROR()
    100 	/* NOTREACHED */
    101