Home | History | Annotate | Line # | Download | only in gen
ldexp.S revision 1.6 
      1 /*
      2  * Copyright (c) 1983, 1993
      3  *	The Regents of the University of California.  All rights reserved.
      4  *
      5  * Redistribution and use in source and binary forms, with or without
      6  * modification, are permitted provided that the following conditions
      7  * are met:
      8  * 1. Redistributions of source code must retain the above copyright
      9  *    notice, this list of conditions and the following disclaimer.
     10  * 2. Redistributions in binary form must reproduce the above copyright
     11  *    notice, this list of conditions and the following disclaimer in the
     12  *    documentation and/or other materials provided with the distribution.
     13  * 3. Neither the name of the University nor the names of its contributors
     14  *    may be used to endorse or promote products derived from this software
     15  *    without specific prior written permission.
     16  *
     17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     27  * SUCH DAMAGE.
     28  */
     29 
     30 #if defined(LIBC_SCCS) && !defined(lint)
     31 	/*.asciz "@(#)ldexp.s	8.1 (Berkeley) 6/4/93" */
     32 	.asciz "$NetBSD: ldexp.S,v 1.6 2003/08/07 16:42:31 agc Exp $"
     33 #endif /* LIBC_SCCS and not lint */
     34 
     35 /*
     36  * double ldexp (value, exp)
     37  * double value;
     38  * int exp;
     39  *
     40  * Ldexp returns value*2**exp, if that result is in range.
     41  * If underflow occurs, it returns zero.  If overflow occurs,
     42  * it returns a value of appropriate sign and largest
     43  * possible magnitude.  In case of either overflow or underflow,
     44  * errno is set to ERANGE.  Note that errno is not modified if
     45  * no error occurs.
     46  */
     47 
     48 #include "DEFS.h"
     49 
     50 /*
     51  * don't include errno.h, ANSI C says it defines errno.
     52  *
     53  * #include <errno.h>
     54  */
     55 #define	ERANGE	34
     56 
     57 	.globl	_C_LABEL(errno)
     58 
     59 ENTRY(ldexp, 0)
     60 	movd	4(%ap),%r0	/* fetch "value" */
     61 	extzv	$7,$8,%r0,%r2	/* %r2 := biased exponent */
     62 	jeql	1f		/* if zero, done */
     63 
     64 	addl2	12(%ap),%r2	/* %r2 := new biased exponent */
     65 	jleq	2f		/* if <= 0, underflow */
     66 	cmpl	%r2,$256		/* otherwise check if too big */
     67 	jgeq	3f		/* jump if overflow */
     68 	insv	%r2,$7,$8,%r0	/* put exponent back in result */
     69 1:
     70 	ret
     71 2:
     72 	clrd	%r0
     73 	jbr	1f
     74 3:
     75 	movd	huge,%r0		/* largest possible floating magnitude */
     76 	jbc	$15,4(%ap),1f	/* jump if argument was positive */
     77 	mnegd	%r0,%r0		/* if arg < 0, make result negative */
     78 1:
     79 #ifdef _REENTRANT
     80 	pushl	%r0
     81 	calls	$0,_C_LABEL(__errno)
     82 	movl	$ ERANGE,(%r0)
     83 	movl	(%sp)+,%r0
     84 #else
     85 	movl	$ ERANGE,_C_LABEL(errno)
     86 #endif
     87 	ret
     88 
     89 	.data
     90 huge:	.word	0x7fff		/* the largest number that can */
     91 	.word	0xffff		/*   be represented in a long floating */
     92 	.word	0xffff		/*   number.  This is given in hex in order */
     93 	.word	0xffff		/*   to avoid floating conversions */
     94