Home | History | Annotate | Line # | Download | only in gen
__sigsetjmp14.S revision 1.3.26.1 
      1 /*	$NetBSD: __sigsetjmp14.S,v 1.3.26.1 2024/08/23 16:59:52 martin Exp $	*/
      2 
      3 /*
      4  * Copyright (c) 2001 Wasabi Systems, Inc.
      5  * All rights reserved.
      6  *
      7  * Written by Frank van der Linden for Wasabi Systems, Inc.
      8  *
      9  * Redistribution and use in source and binary forms, with or without
     10  * modification, are permitted provided that the following conditions
     11  * are met:
     12  * 1. Redistributions of source code must retain the above copyright
     13  *    notice, this list of conditions and the following disclaimer.
     14  * 2. Redistributions in binary form must reproduce the above copyright
     15  *    notice, this list of conditions and the following disclaimer in the
     16  *    documentation and/or other materials provided with the distribution.
     17  * 3. All advertising materials mentioning features or use of this software
     18  *    must display the following acknowledgement:
     19  *      This product includes software developed for the NetBSD Project by
     20  *      Wasabi Systems, Inc.
     21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
     22  *    or promote products derived from this software without specific prior
     23  *    written permission.
     24  *
     25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
     26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
     29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     35  * POSSIBILITY OF SUCH DAMAGE.
     36  */
     37 
     38 
     39 #include <machine/asm.h>
     40 #include <machine/setjmp.h>
     41 
     42 #if defined(LIBC_SCCS)
     43 	RCSID("$NetBSD: __sigsetjmp14.S,v 1.3.26.1 2024/08/23 16:59:52 martin Exp $")
     44 #endif
     45 
     46 /*
     47  * C library -- _setjmp, _longjmp
     48  *
     49  *	longjmp(a,v)
     50  * will generate a "return(v)" from the last call to
     51  *	setjmp(a)
     52  * by restoring registers from the stack.
     53  * The previous signal state is restored.
     54  */
     55 
     56 /*
     57  * sigsetjmp(sigjmp_buf env@rdi, int savemask@esi)
     58  *
     59  * ELF symbol: __sigsetjmp14, because the size of sigjmp_buf changed on
     60  * some platforms in 1.4.
     61  */
     62 ENTRY(__sigsetjmp14)
     63 	/*
     64 	 * Save the callee-saves registers: %rbx, %rbp, %r12-r15,
     65 	 * plus %rsp and the return address on the stack since it
     66 	 * will be overwritten if the caller makes any subroutine
     67 	 * calls before siglongjmp.
     68 	 */
     69 	movq	(%rsp),%r11
     70 	movq	%rbx,(_JB_RBX * 8)(%rdi)
     71 	movq	%rbp,(_JB_RBP * 8)(%rdi)
     72 	movq	%r12,(_JB_R12 * 8)(%rdi)
     73 	movq	%r13,(_JB_R13 * 8)(%rdi)
     74 	movq	%r14,(_JB_R14 * 8)(%rdi)
     75 	movq	%r15,(_JB_R15 * 8)(%rdi)
     76 	movq	%rsp,(_JB_RSP * 8)(%rdi)
     77 	movq	%r11,(_JB_PC  * 8)(%rdi)
     78 
     79 	movq	%rsi,(_JB_SIGFLAG  * 8)(%rdi)	/* store savemask */
     80 	testl	%esi,%esi		/* savemask == 0? */
     81 	jz	2f			/* jump if savemask == 0 */
     82 
     83 	leaq	(_JB_SIGMASK * 8)(%rdi),%rdx	/* oset@rdx */
     84 	xorl	%edi,%edi		/* how@edi := 0 (ignored) */
     85 	xorl	%esi,%esi		/* set@rsi := NULL */
     86 
     87 #ifdef __PIC__
     88 	call	PIC_PLT(_C_LABEL(__sigprocmask14))
     89 #else
     90 	call	_C_LABEL(__sigprocmask14)
     91 #endif
     92 2:	xorl	%eax,%eax		/* return 0 first time around */
     93 	ret
     94 END(__sigsetjmp14)
     95 
     96 /*
     97  * siglongjmp(sigjmp_buf env@rdi, int val@esi)
     98  *
     99  * ELF symbol: __siglongjmp14, because the size of sigjmp_buf changed
    100  * on some platforms in 1.4.
    101  */
    102 ENTRY(__siglongjmp14)
    103 	/*
    104 	 * Restore the callee-saves registers: %rbx, %rbp, %r12-r15,
    105 	 * plus %rsp and the return address on the stack.
    106 	 */
    107 	movq	(_JB_RBX * 8)(%rdi),%rbx
    108 	movq	(_JB_RBP * 8)(%rdi),%rbp
    109 	movq	(_JB_R12 * 8)(%rdi),%r12
    110 	movq	(_JB_R13 * 8)(%rdi),%r13
    111 	movq	(_JB_R14 * 8)(%rdi),%r14
    112 	movq	(_JB_R15 * 8)(%rdi),%r15
    113 	movq	(_JB_RSP * 8)(%rdi),%rsp
    114 	movq	(_JB_PC  * 8)(%rdi),%r11
    115 	movq	%r11,0(%rsp)
    116 
    117 	/*
    118 	 * Use  pushq %rsi  instead of  pushl %esi  in order to keep
    119 	 * 16-byte stack alignment, even though we only care about the
    120 	 * 32-bit int in esi.
    121 	 */
    122 	pushq	%rsi		/* save val@esi */
    123 
    124 	cmpl	$0, (_JB_SIGFLAG * 8)(%rdi)	/* test savemask == 0? */
    125 	jz	2f		/* jump if savemask == 0 */
    126 
    127 	leaq	(_JB_SIGMASK * 8)(%rdi),%rsi	/* set@rsi */
    128 	movl	$3,%edi		/* how@edi := SIG_SETMASK */
    129 	xorl	%edx,%edx	/* oset@rdx := NULL */
    130 
    131 #ifdef __PIC__
    132 	call	PIC_PLT(_C_LABEL(__sigprocmask14))
    133 #else
    134 	call	_C_LABEL(__sigprocmask14)
    135 #endif
    136 
    137 2:	popq	%rax		/* restore val@eax */
    138 
    139 	testl	%eax,%eax	/* val@eax == 0? */
    140 	jz	1f		/* jump if val@eax == 0 */
    141 	ret			/* return val@eax */
    142 1:	incl	%eax		/* val@eax := 1 */
    143 	ret			/* return val@eax */
    144 END(__siglongjmp14)
    145