Home | History | Annotate | Line # | Download | only in gen
compat_setjmp.S revision 1.1 
      1 /*	$NetBSD: compat_setjmp.S,v 1.1 2005/10/15 22:11:22 uwe Exp $	*/
      2 
      3 /*
      4  * Copyright (c) 1992, 1993
      5  *	The Regents of the University of California.  All rights reserved.
      6  *
      7  * This software was developed by the Computer Systems Engineering group
      8  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
      9  * contributed to Berkeley.
     10  *
     11  * Redistribution and use in source and binary forms, with or without
     12  * modification, are permitted provided that the following conditions
     13  * are met:
     14  * 1. Redistributions of source code must retain the above copyright
     15  *    notice, this list of conditions and the following disclaimer.
     16  * 2. Redistributions in binary form must reproduce the above copyright
     17  *    notice, this list of conditions and the following disclaimer in the
     18  *    documentation and/or other materials provided with the distribution.
     19  * 3. Neither the name of the University nor the names of its contributors
     20  *    may be used to endorse or promote products derived from this software
     21  *    without specific prior written permission.
     22  *
     23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     33  * SUCH DAMAGE.
     34  *
     35  * from: Header: setjmp.s,v 1.2 92/06/25 03:18:43 torek Exp
     36  */
     37 
     38 #include <machine/asm.h>
     39 #if defined(LIBC_SCCS) && !defined(lint)
     40 #if 0
     41 	.asciz "@(#)setjmp.s	8.1 (Berkeley) 6/4/93"
     42 #else
     43 	RCSID("$NetBSD: compat_setjmp.S,v 1.1 2005/10/15 22:11:22 uwe Exp $")
     44 #endif
     45 #endif /* LIBC_SCCS and not lint */
     46 
     47 /*
     48  * C library -- setjmp, longjmp
     49  *
     50  *	longjmp(a,v)
     51  * will generate a "return(v)" from
     52  * the last call to
     53  *	setjmp(a)
     54  * by restoring registers from the stack,
     55  * and a struct sigcontext, see <signal.h>
     56  */
     57 
     58 #include "SYS.h"
     59 
     60 ENTRY(setjmp)
     61 	/*
     62 	 * We use the caller's `arg dump' area (%sp+0x44; there are 6 ints
     63 	 * reserved there for us) to avoid having to allocate stack space
     64 	 * here.
     65 	 */
     66 	mov	%o0, %o2	/* build sigcontext in [%o2] */
     67 	mov	1, %o0		/* SIG_BLOCK */
     68 	mov	SYS_compat_13_sigprocmask13, %g1
     69 	clr	%o1		/* sigprocmask(SIG_BLOCK, (sigset_t *)NULL) */
     70 	t	ST_SYSCALL
     71 	st	%o0, [%o2 + 4]	/* sc.sc_mask = current mask; */
     72 	mov	SYS___sigaltstack14, %g1
     73 	clr	%o0		/* sigaltstack(NULL, &foo) */
     74 	add	%sp, 0x48, %o1	/* (foo being in arg dump area) */
     75 	t	ST_SYSCALL
     76 	ld	[%sp + 0x50], %o0	/* foo.ss_flags */
     77 	and	%o0, 1, %o1	/* onstack = foo.ss_flags & 1; */
     78 	st	%o0, [%o2 + 0]	/* sc.sc_onstack = current onstack; */
     79 	st	%sp, [%o2 + 8]	/* sc.sc_sp = sp (both ours and caller's) */
     80 	add	%o7, 8, %o0
     81 	st	%o0, [%o2 + 12]	/* sc.sc_pc = return_pc */
     82 	add	%o7, 12, %o0
     83 	st	%o0, [%o2 + 16]	/* sc.sc_npc = return_pc + 4 */
     84 	st	%g0, [%o2 + 20]	/* sc.sc_psr = (clean psr) */
     85 	st	%fp, [%o2 + 24]	/* sc.sc_g1 = %fp (misuse, but what the heck) */
     86 				/* sc.sc_o0 = random(), set in longjmp */
     87 	retl			/* return 0 */
     88 	 clr	%o0
     89 
     90 /*
     91  * All we need to do here is force sigreturn to load a new stack pointer,
     92  * new <pc,npc>, and appropriate %o0 return value from the sigcontext built
     93  * in setjmp.  The %i and %l registers will be reloaded from the place to
     94  * which %sp points, due to sigreturn() semantics (sigreturn does not modify
     95  * the window pointer in the psr, hence it must force all windows to reload).
     96  */
     97 ENTRY(longjmp)
     98 	save	%sp, -96, %sp
     99 	ld	[%i0 + 8], %o2	/* make sure sc->sc_sp, sc->sc_fp nonzero */
    100 	ld	[%i0 + 24], %o3
    101 	orcc	%o2, %o3, %g0
    102 	bz	Lbotch
    103 	 tst	%i1		/* if (v == 0) v = 1; */
    104 	bz,a	1f
    105 	 mov	1, %i1
    106 1:
    107 	st	%i1, [%i0 + 28]	/* sc.sc_o0 = v; */
    108 	mov	SYS_compat_13_sigreturn13, %g1
    109 	mov	%i0, %o0
    110 	t	ST_SYSCALL	/* sigreturn(scp); */
    111 
    112 Lbotch:
    113 	/* oops, caller botched it */
    114 	call	_C_LABEL(longjmperror)
    115 	 nop
    116 	unimp	0
    117