Home | History | Annotate | Line # | Download | only in vax
n_sqrt.S revision 1.1 
      1 /*	$NetBSD: n_sqrt.S,v 1.1 1995/10/10 23:40:29 ragge Exp $	*/
      2 /*
      3  * Copyright (c) 1985, 1993
      4  *	The Regents of the University of California.  All rights reserved.
      5  *
      6  * Redistribution and use in source and binary forms, with or without
      7  * modification, are permitted provided that the following conditions
      8  * are met:
      9  * 1. Redistributions of source code must retain the above copyright
     10  *    notice, this list of conditions and the following disclaimer.
     11  * 2. Redistributions in binary form must reproduce the above copyright
     12  *    notice, this list of conditions and the following disclaimer in the
     13  *    documentation and/or other materials provided with the distribution.
     14  * 3. All advertising materials mentioning features or use of this software
     15  *    must display the following acknowledgement:
     16  *	This product includes software developed by the University of
     17  *	California, Berkeley and its contributors.
     18  * 4. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  *
     34  *	@(#)sqrt.s	8.1 (Berkeley) 6/4/93
     35  */
     36 
     37 /*
     38  * double sqrt(arg)   revised August 15,1982
     39  * double arg;
     40  * if(arg<0.0) { _errno = EDOM; return(<a reserved operand>); }
     41  * if arg is a reserved operand it is returned as it is
     42  * W. Kahan's magic square root
     43  * coded by Heidi Stettner and revised by Emile LeBlanc 8/18/82
     44  *
     45  * entry points:_d_sqrt		address of double arg is on the stack
     46  *		_sqrt		double arg is on the stack
     47  */
     48 	.text
     49 	.align	1
     50 	.globl	_sqrt
     51 	.globl	_d_sqrt
     52 	.globl	libm$dsqrt_r5
     53 	.set	EDOM,33
     54 
     55 _d_sqrt:
     56 	.word	0x003c          # save r5,r4,r3,r2
     57 	movq	*4(ap),r0
     58 	jmp  	dsqrt2
     59 _sqrt:
     60 	.word	0x003c          # save r5,r4,r3,r2
     61 	movq    4(ap),r0
     62 dsqrt2:	bicw3	$0x807f,r0,r2	# check exponent of input
     63 	jeql	noexp		# biased exponent is zero -> 0.0 or reserved
     64 	bsbb	libm$dsqrt_r5
     65 noexp:	ret
     66 
     67 /* **************************** internal procedure */
     68 
     69 libm$dsqrt_r5:			/* ENTRY POINT FOR cdabs and cdsqrt	*/
     70 				/* returns double square root scaled by	*/
     71 				/* 2^r6	*/
     72 
     73 	movd	r0,r4
     74 	jleq	nonpos		# argument is not positive
     75 	movzwl	r4,r2
     76 	ashl	$-1,r2,r0
     77 	addw2	$0x203c,r0	# r0 has magic initial approximation
     78 /*
     79  * Do two steps of Heron's rule
     80  * ((arg/guess) + guess) / 2 = better guess
     81  */
     82 	divf3	r0,r4,r2
     83 	addf2	r2,r0
     84 	subw2	$0x80,r0	# divide by two
     85 
     86 	divf3	r0,r4,r2
     87 	addf2	r2,r0
     88 	subw2	$0x80,r0	# divide by two
     89 
     90 /* Scale argument and approximation to prevent over/underflow */
     91 
     92 	bicw3	$0x807f,r4,r1
     93 	subw2	$0x4080,r1		# r1 contains scaling factor
     94 	subw2	r1,r4
     95 	movl	r0,r2
     96 	subw2	r1,r2
     97 
     98 /* Cubic step
     99  *
    100  * b = a + 2*a*(n-a*a)/(n+3*a*a) where b is better approximation,
    101  * a is approximation, and n is the original argument.
    102  * (let s be scale factor in the following comments)
    103  */
    104 	clrl	r1
    105 	clrl	r3
    106 	muld2	r0,r2			# r2:r3 = a*a/s
    107 	subd2	r2,r4			# r4:r5 = n/s - a*a/s
    108 	addw2	$0x100,r2		# r2:r3 = 4*a*a/s
    109 	addd2	r4,r2			# r2:r3 = n/s + 3*a*a/s
    110 	muld2	r0,r4			# r4:r5 = a*n/s - a*a*a/s
    111 	divd2	r2,r4			# r4:r5 = a*(n-a*a)/(n+3*a*a)
    112 	addw2	$0x80,r4		# r4:r5 = 2*a*(n-a*a)/(n+3*a*a)
    113 	addd2	r4,r0			# r0:r1 = a + 2*a*(n-a*a)/(n+3*a*a)
    114 	rsb				# DONE!
    115 nonpos:
    116 	jneq	negarg
    117 	ret			# argument and root are zero
    118 negarg:
    119 	pushl	$EDOM
    120 	calls	$1,_infnan	# generate the reserved op fault
    121 	ret
    122