Home | History | Annotate | Line # | Download | only in vax
n_sqrt.S revision 1.4 
      1 /*	$NetBSD: n_sqrt.S,v 1.4 2002/02/21 07:49:55 matt Exp $	*/
      2 /*
      3  * Copyright (c) 1985, 1993
      4  *	The Regents of the University of California.  All rights reserved.
      5  *
      6  * Redistribution and use in source and binary forms, with or without
      7  * modification, are permitted provided that the following conditions
      8  * are met:
      9  * 1. Redistributions of source code must retain the above copyright
     10  *    notice, this list of conditions and the following disclaimer.
     11  * 2. Redistributions in binary form must reproduce the above copyright
     12  *    notice, this list of conditions and the following disclaimer in the
     13  *    documentation and/or other materials provided with the distribution.
     14  * 3. All advertising materials mentioning features or use of this software
     15  *    must display the following acknowledgement:
     16  *	This product includes software developed by the University of
     17  *	California, Berkeley and its contributors.
     18  * 4. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  *
     34  *	@(#)sqrt.s	8.1 (Berkeley) 6/4/93
     35  */
     36 
     37 #include <machine/asm.h>
     38 
     39 /*
     40  * double sqrt(arg)   revised August 15,1982
     41  * double arg;
     42  * if(arg<0.0) { _errno = EDOM; return(<a reserved operand>); }
     43  * if arg is a reserved operand it is returned as it is
     44  * W. Kahan's magic square root
     45  * coded by Heidi Stettner and revised by Emile LeBlanc 8/18/82
     46  *
     47  * entry points:_d_sqrt		address of double arg is on the stack
     48  *		_sqrt		double arg is on the stack
     49  */
     50 	.set	EDOM,33
     51 
     52 ENTRY(d_sqrt, 0x003c)		# save r5,r4,r3,r2
     53 	movq	*4(ap),r0
     54 	jbr  	dsqrt2
     55 
     56 ENTRY(sqrt, 0x003c)		# save r5,r4,r3,r2
     57 	movq    4(ap),r0
     58 
     59 dsqrt2:	bicw3	$0x807f,r0,r2	# check exponent of input
     60 	jeql	noexp		# biased exponent is zero -> 0.0 or reserved
     61 	bsbb	__libm_dsqrt_r5_lcl+2
     62 noexp:	ret
     63 
     64 /* **************************** internal procedure */
     65 
     66 __libm_dsqrt_r5_lcl:
     67 ALTENTRY(__libm_dsqrt_r5)
     68 	nop
     69 	nop
     70 				/* ENTRY POINT FOR cdabs and cdsqrt	*/
     71 				/* returns double square root scaled by	*/
     72 				/* 2^r6	*/
     73 
     74 	movd	r0,r4
     75 	jleq	nonpos		# argument is not positive
     76 	movzwl	r4,r2
     77 	ashl	$-1,r2,r0
     78 	addw2	$0x203c,r0	# r0 has magic initial approximation
     79 /*
     80  * Do two steps of Heron's rule
     81  * ((arg/guess) + guess) / 2 = better guess
     82  */
     83 	divf3	r0,r4,r2
     84 	addf2	r2,r0
     85 	subw2	$0x80,r0	# divide by two
     86 
     87 	divf3	r0,r4,r2
     88 	addf2	r2,r0
     89 	subw2	$0x80,r0	# divide by two
     90 
     91 /* Scale argument and approximation to prevent over/underflow */
     92 
     93 	bicw3	$0x807f,r4,r1
     94 	subw2	$0x4080,r1		# r1 contains scaling factor
     95 	subw2	r1,r4
     96 	movl	r0,r2
     97 	subw2	r1,r2
     98 
     99 /* Cubic step
    100  *
    101  * b = a + 2*a*(n-a*a)/(n+3*a*a) where b is better approximation,
    102  * a is approximation, and n is the original argument.
    103  * (let s be scale factor in the following comments)
    104  */
    105 	clrl	r1
    106 	clrl	r3
    107 	muld2	r0,r2			# r2:r3 = a*a/s
    108 	subd2	r2,r4			# r4:r5 = n/s - a*a/s
    109 	addw2	$0x100,r2		# r2:r3 = 4*a*a/s
    110 	addd2	r4,r2			# r2:r3 = n/s + 3*a*a/s
    111 	muld2	r0,r4			# r4:r5 = a*n/s - a*a*a/s
    112 	divd2	r2,r4			# r4:r5 = a*(n-a*a)/(n+3*a*a)
    113 	addw2	$0x80,r4		# r4:r5 = 2*a*(n-a*a)/(n+3*a*a)
    114 	addd2	r4,r0			# r0:r1 = a + 2*a*(n-a*a)/(n+3*a*a)
    115 	rsb				# DONE!
    116 nonpos:
    117 	jneq	negarg
    118 	ret				# argument and root are zero
    119 negarg:
    120 	pushl	$EDOM
    121 	calls	$1,_C_LABEL(infnan)	# generate the reserved op fault
    122 	ret
    123