Home | History | Annotate | Line # | Download | only in vax
n_sqrt.S revision 1.8.40.1 
      1 /*	$NetBSD: n_sqrt.S,v 1.8.40.1 2014/08/20 00:02:18 tls Exp $	*/
      2 /*
      3  * Copyright (c) 1985, 1993
      4  *	The Regents of the University of California.  All rights reserved.
      5  *
      6  * Redistribution and use in source and binary forms, with or without
      7  * modification, are permitted provided that the following conditions
      8  * are met:
      9  * 1. Redistributions of source code must retain the above copyright
     10  *    notice, this list of conditions and the following disclaimer.
     11  * 2. Redistributions in binary form must reproduce the above copyright
     12  *    notice, this list of conditions and the following disclaimer in the
     13  *    documentation and/or other materials provided with the distribution.
     14  * 3. Neither the name of the University nor the names of its contributors
     15  *    may be used to endorse or promote products derived from this software
     16  *    without specific prior written permission.
     17  *
     18  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     28  * SUCH DAMAGE.
     29  *
     30  *	@(#)sqrt.s	8.1 (Berkeley) 6/4/93
     31  */
     32 
     33 #include <machine/asm.h>
     34 
     35 #ifdef WEAK_ALIAS
     36 WEAK_ALIAS(sqrtl, sqrt)
     37 #endif
     38 
     39 /*
     40  * double sqrt(arg)   revised August 15,1982
     41  * double arg;
     42  * if(arg<0.0) { _errno = EDOM; return(<a reserved operand>); }
     43  * if arg is a reserved operand it is returned as it is
     44  * W. Kahan's magic square root
     45  * coded by Heidi Stettner and revised by Emile LeBlanc 8/18/82
     46  *
     47  * entry points:_d_sqrt		address of double arg is on the stack
     48  *		_sqrt		double arg is on the stack
     49  */
     50 	.set	EDOM,33
     51 
     52 ENTRY(d_sqrt, 0x003c)		# save %r5,%r4,%r3,%r2
     53 	movq	*4(%ap),%r0
     54 	jbr  	dsqrt2
     55 
     56 ENTRY(sqrt, 0x003c)		# save %r5,%r4,%r3,%r2
     57 	movq    4(%ap),%r0
     58 
     59 dsqrt2:	bicw3	$0x807f,%r0,%r2	# check exponent of input
     60 	jeql	noexp		# biased exponent is zero -> 0.0 or reserved
     61 	bsbb	__libm_dsqrt_r5_lcl
     62 noexp:	ret
     63 
     64 /* **************************** internal procedure */
     65 
     66 	.hidden __libm_dsqrt_r5
     67 ALTENTRY(__libm_dsqrt_r5)
     68 	halt
     69 	halt
     70 __libm_dsqrt_r5_lcl:
     71 				/* ENTRY POINT FOR cdabs and cdsqrt	*/
     72 				/* returns double square root scaled by	*/
     73 				/* 2^%r6	*/
     74 
     75 	movd	%r0,%r4
     76 	jleq	nonpos		# argument is not positive
     77 	movzwl	%r4,%r2
     78 	ashl	$-1,%r2,%r0
     79 	addw2	$0x203c,%r0	# %r0 has magic initial approximation
     80 /*
     81  * Do two steps of Heron's rule
     82  * ((arg/guess) + guess) / 2 = better guess
     83  */
     84 	divf3	%r0,%r4,%r2
     85 	addf2	%r2,%r0
     86 	subw2	$0x80,%r0	# divide by two
     87 
     88 	divf3	%r0,%r4,%r2
     89 	addf2	%r2,%r0
     90 	subw2	$0x80,%r0	# divide by two
     91 
     92 /* Scale argument and approximation to prevent over/underflow */
     93 
     94 	bicw3	$0x807f,%r4,%r1
     95 	subw2	$0x4080,%r1		# %r1 contains scaling factor
     96 	subw2	%r1,%r4
     97 	movl	%r0,%r2
     98 	subw2	%r1,%r2
     99 
    100 /* Cubic step
    101  *
    102  * b = a + 2*a*(n-a*a)/(n+3*a*a) where b is better approximation,
    103  * a is approximation, and n is the original argument.
    104  * (let s be scale factor in the following comments)
    105  */
    106 	clrl	%r1
    107 	clrl	%r3
    108 	muld2	%r0,%r2			# %r2:%r3 = a*a/s
    109 	subd2	%r2,%r4			# %r4:%r5 = n/s - a*a/s
    110 	addw2	$0x100,%r2		# %r2:%r3 = 4*a*a/s
    111 	addd2	%r4,%r2			# %r2:%r3 = n/s + 3*a*a/s
    112 	muld2	%r0,%r4			# %r4:%r5 = a*n/s - a*a*a/s
    113 	divd2	%r2,%r4			# %r4:%r5 = a*(n-a*a)/(n+3*a*a)
    114 	addw2	$0x80,%r4		# %r4:%r5 = 2*a*(n-a*a)/(n+3*a*a)
    115 	addd2	%r4,%r0			# %r0:%r1 = a + 2*a*(n-a*a)/(n+3*a*a)
    116 	rsb				# DONE!
    117 nonpos:
    118 	jneq	negarg
    119 	ret				# argument and root are zero
    120 negarg:
    121 	pushl	$EDOM
    122 	calls	$1,_C_LABEL(infnan)	# generate the reserved op fault
    123 	ret
    124 
    125 ENTRY(sqrtf, 0)
    126 	cvtfd	4(%ap),-(%sp)
    127 	calls	$2,_C_LABEL(sqrt)
    128 	cvtdf	%r0,%r0
    129 	ret
    130