rtld_start.S revision 1.10 
1/*	$NetBSD: rtld_start.S,v 1.10 2008/04/28 20:23:03 martin Exp $	*/
2
3/*-
4 * Copyright (c) 1998, 2002 The NetBSD Foundation, Inc.
5 * All rights reserved.
6 *
7 * This code is derived from software contributed to The NetBSD Foundation
8 * by Christos Zoulas and by Charles M. Hannum.
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 *    notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 *    notice, this list of conditions and the following disclaimer in the
17 *    documentation and/or other materials provided with the distribution.
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
20 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
21 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
22 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
23 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29 * POSSIBILITY OF SUCH DAMAGE.
30 */
31
32#include <machine/asm.h>
33
34	.text
35	.align	4
36	.globl	.rtld_start
37	.type	.rtld_start,@function
38.rtld_start:
39	subl	$8,%esp			# make room of obj_main and exit proc
40	pushl	%ebx			# save ps_strings
41
42	call	1f
431:
44	popl	%edx
45	leal	_DYNAMIC-1b(%edx),%ecx	# &_DYNAMIC
46	movl	%ecx,%ebx
47	subl	_GLOBAL_OFFSET_TABLE_-1b(%edx),%ebx
48
49	pushl	%ebx			# relocbase
50	pushl	%ecx			# &_DYNAMIC
51	call	_rtld_relocate_nonplt_self@PLT
52
53	leal	12(%esp),%eax		# &cleanup
54	pushl	%ebx			# relocbase
55	pushl	%eax			# sp
56	call	_rtld@PLT		# _rtld(sp, relocbase)
57
58	addl	$16,%esp		# pop args
59
60	popl	%ebx			# %ebx = ps_strings
61	popl	%edx			# %edx = cleanup
62	popl	%ecx			# %ecx = obj_main
63	jmp	*%eax
64
65	.align	4
66	.globl	_rtld_bind_start
67	.type	_rtld_bind_start,@function
68_rtld_bind_start:	# (obj, reloff)
69	pushf				# save registers
70	pushl	%eax
71	pushl	%ecx
72	pushl	%edx
73
74	pushl	20(%esp)		# Copy of reloff
75	pushl	20(%esp)		# Copy of obj
76	call	_rtld_bind@PLT		# Call the binder
77	addl	$8,%esp			# pop binder args
78	movl	%eax,20(%esp)		# Store function to be called in obj
79
80	popl	%edx
81	popl	%ecx
82	popl	%eax
83	popf
84
85	leal	4(%esp),%esp		# Discard reloff, do not change eflags
86	ret
87