rtld_start.S revision 1.4 
1/*	$NetBSD: rtld_start.S,v 1.4 2002/09/09 14:08:08 mycroft Exp $	*/
2
3/*-
4 * Copyright (c) 1998 The NetBSD Foundation, Inc.
5 * All rights reserved.
6 *
7 * This code is derived from software contributed to The NetBSD Foundation
8 * by Christos Zoulas.
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 *    notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 *    notice, this list of conditions and the following disclaimer in the
17 *    documentation and/or other materials provided with the distribution.
18 * 3. All advertising materials mentioning features or use of this software
19 *    must display the following acknowledgement:
20 *        This product includes software developed by the NetBSD
21 *        Foundation, Inc. and its contributors.
22 * 4. Neither the name of The NetBSD Foundation nor the names of its
23 *    contributors may be used to endorse or promote products derived
24 *    from this software without specific prior written permission.
25 *
26 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
27 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
28 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
29 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
30 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
31 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
32 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
33 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
34 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
35 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
36 * POSSIBILITY OF SUCH DAMAGE.
37 */
38
39#include <machine/asm.h>
40
41	.text
42	.align	4
43	.globl	.rtld_start
44	.type	.rtld_start,@function
45.rtld_start:
46	subl	$8,%esp			# make room of obj_main and exit proc
47	movl	%esp,%eax		# save stack pointer for _rtld
48	pushl	%ebx			# save ps_strings
49
50	call	1f
511:
52	popl	%ebx
53	addl	$_GLOBAL_OFFSET_TABLE_+[.-1b],%ebx
54
55	movl	_GLOBAL_OFFSET_TABLE_@GOT(%ebx),%edx
56	movl	_GOT_END_@GOT(%ebx),%ecx
57	subl	%edx,%ecx
58	shrl	$2,%ecx
59	subl	%ebx,%edx
601:
61	subl	%edx,(%ebx)
62	leal	4(%ebx),%ebx
63	decl	%ecx
64	jg	1b
65
66	pushl	%eax
67	call	_rtld@PLT		# _rtld(sp)
68	addl	$4,%esp			# pop args
69
70	popl	%ebx			# %ebx = ps_strings
71	popl	%edx			# %edx = cleanup
72	popl	%ecx			# %ecx = obj_main
73	jmp	*%eax
74
75	.align	4
76	.globl	_rtld_bind_start
77	.type	_rtld_bind_start,@function
78_rtld_bind_start:	# (obj, reloff)
79	pushf				# save registers
80	pushl	%eax
81	pushl	%ecx
82	pushl	%edx
83	pushl	%ebx
84	pushl	%ebp
85	pushl	%esi
86	pushl	%edi
87	pushl	%ds
88	pushl	%es
89
90	pushl	44(%esp)		# Copy of reloff
91	pushl	44(%esp)		# Copy of obj
92	call	_rtld_bind@PLT		# Call the binder
93	addl	$8,%esp			# pop binder args
94	movl	%eax,44(%esp)		# Store function to be called in obj
95
96	popl	%es			# restore registers
97	popl	%ds
98	popl	%edi
99	popl	%esi
100	popl	%ebp
101	popl	%ebx
102	popl	%edx
103	popl	%ecx
104	popl	%eax
105	popf
106
107	leal	4(%esp),%esp		# Discard reloff, do not change eflags
108	ret
109