rtld_start.S revision 1.6 
1/*	$NetBSD: rtld_start.S,v 1.6 2002/09/12 17:07:26 mycroft Exp $	*/
2
3/*-
4 * Copyright (c) 1998 The NetBSD Foundation, Inc.
5 * All rights reserved.
6 *
7 * This code is derived from software contributed to The NetBSD Foundation
8 * by Christos Zoulas and by Charles M. Hannum.
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 *    notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 *    notice, this list of conditions and the following disclaimer in the
17 *    documentation and/or other materials provided with the distribution.
18 * 3. All advertising materials mentioning features or use of this software
19 *    must display the following acknowledgement:
20 *        This product includes software developed by the NetBSD
21 *        Foundation, Inc. and its contributors.
22 * 4. Neither the name of The NetBSD Foundation nor the names of its
23 *    contributors may be used to endorse or promote products derived
24 *    from this software without specific prior written permission.
25 *
26 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
27 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
28 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
29 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
30 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
31 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
32 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
33 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
34 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
35 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
36 * POSSIBILITY OF SUCH DAMAGE.
37 */
38
39#include <machine/asm.h>
40
41	.text
42	.align	4
43	.globl	.rtld_start
44	.type	.rtld_start,@function
45.rtld_start:
46	subl	$8,%esp			# make room of obj_main and exit proc
47	pushl	%ebx			# save ps_strings
48
49	call	1f
501:
51	popl	%ebx
52	addl	$_GLOBAL_OFFSET_TABLE_+[.-1b],%ebx
53
54	movl	_GLOBAL_OFFSET_TABLE_@GOT(%ebx),%edx
55	movl	_DYNAMIC@GOT(%ebx),%ecx
56	subl	%edx,%ebx
57	pushl	%ebx			# relocbase
58	addl	%ebx,%ecx
59	pushl	%ecx			# &_DYNAMIC
60	call	_rtld_relocate_nonplt_self@PLT
61
62	leal	12(%esp),%eax		# &cleanup
63	pushl	%ebx			# relocbase
64	pushl	%eax			# sp
65	call	_rtld@PLT		# _rtld(sp, relocbase)
66
67	addl	$16,%esp		# pop args
68
69	popl	%ebx			# %ebx = ps_strings
70	popl	%edx			# %edx = cleanup
71	popl	%ecx			# %ecx = obj_main
72	jmp	*%eax
73
74	.align	4
75	.globl	_rtld_bind_start
76	.type	_rtld_bind_start,@function
77_rtld_bind_start:	# (obj, reloff)
78	pushf				# save registers
79	pushl	%eax
80	pushl	%ecx
81	pushl	%edx
82	pushl	%ebx
83	pushl	%ebp
84	pushl	%esi
85	pushl	%edi
86	pushl	%ds
87	pushl	%es
88
89	pushl	44(%esp)		# Copy of reloff
90	pushl	44(%esp)		# Copy of obj
91	call	_rtld_bind@PLT		# Call the binder
92	addl	$8,%esp			# pop binder args
93	movl	%eax,44(%esp)		# Store function to be called in obj
94
95	popl	%es			# restore registers
96	popl	%ds
97	popl	%edi
98	popl	%esi
99	popl	%ebp
100	popl	%ebx
101	popl	%edx
102	popl	%ecx
103	popl	%eax
104	popf
105
106	leal	4(%esp),%esp		# Discard reloff, do not change eflags
107	ret
108