Home | History | Annotate | Line # | Download | only in vax
rtld_start.S revision 1.16 
      1 /*	$NetBSD: rtld_start.S,v 1.16 2003/03/02 22:03:40 mycroft Exp $	*/
      2 
      3 /*
      4  * Copyright 1996 Matt Thomas <matt (at) 3am-software.com>
      5  * Portions copyright 2002, 2003 Charles M. Hannum <root (at) ihack.net>
      6  * All rights reserved.
      7  *
      8  * Redistribution and use in source and binary forms, with or without
      9  * modification, are permitted provided that the following conditions
     10  * are met:
     11  * 1. Redistributions of source code must retain the above copyright
     12  *    notice, this list of conditions and the following disclaimer.
     13  * 2. Redistributions in binary form must reproduce the above copyright
     14  *    notice, this list of conditions and the following disclaimer in the
     15  *    documentation and/or other materials provided with the distribution.
     16  * 3. The name of the author may not be used to endorse or promote products
     17  *    derived from this software without specific prior written permission.
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
     20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
     21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
     22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
     23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
     24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
     28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
     29  */
     30 
     31 #include <machine/asm.h>
     32 
     33 /* R9 contains the address of PS_STRINGS and since its caller saved,
     34  * we can just use it.  R6 has a backup copy of the stack pointer which
     35  * we can use as well.
     36  */
     37 ENTRY(_rtld_start, 0)
     38 	/* Allocate space on the stack for the cleanup and obj_main
     39 	 * entries that _rtld() will provide for us.
     40 	 */
     41 	clrl	%fp
     42 	subl2	$8,%sp
     43 
     44 	movab	_DYNAMIC,%r0
     45 	subl3	_GLOBAL_OFFSET_TABLE_,%r0,%r10
     46 	pushl	%r10		/* relocbase */
     47 	pushl	%r0		/* &_DYNAMIC */
     48 	calls	$2,_rtld_relocate_nonplt_self
     49 
     50 	pushl	%r10		/* relocbase */
     51 	pushal	4(%sp)		/* sp */
     52 	calls	$2,_rtld	/* entry = _rtld(sp, relocbase) */
     53 
     54 	movq	(%sp)+,%r7	/* grab cleanup and obj_main into %r7/%r8 */
     55 	jmp	2(%r0)		/* jump to entry point + 2 */
     56 
     57 /*
     58  * Lazy binding entry point, called via PLT.
     59  *
     60  * Note: Some functions rely on there not being an additional call frame;
     61  * hence the `optimization' to avoid the callg opportunistically.
     62  */
     63 ALTENTRY(_rtld_bind_start)
     64 	pushr	$0x3f		/* save R0-R5 */
     65 	movq	24(%sp),%r0	/* get addresses of plt.got & reloc index */
     66 	pushl	(%r1)		/* push relocation index */
     67 	pushl	%r0		/* push address of obj entry */
     68 	calls	$2,_rtld_bind
     69 	movl	%r0,28(%sp)	/* save return address onto stack */
     70 	bicw3	6(%fp),(%r0),%r0/* does the entry mask save any additional regs */
     71 	popr	$0x3f		/* restore R0-R5 (cond flags not modified) */
     72 	bneq	4f		/* yes? do it the hard way */
     73 	addl2	$4,%sp		/* no? skip past plt.got on stack */
     74 	addl2	$2,(%sp)		/*    skip past the mask */
     75 	rsb			/*    and jump to it */
     76 4:	addl2	$4,%sp
     77 	callg	(%ap),*(%sp)+	/* return value from _rtld_bind() == actual */
     78 	ret
     79