Home | History | Annotate | Line # | Download | only in vax
rtld_start.S revision 1.4 
      1 /*	$NetBSD: rtld_start.S,v 1.4 2000/07/14 22:03:03 matt Exp $	*/
      2 
      3 /*
      4  * Copyright 1996 Matt Thomas <matt (at) 3am-software.com>
      5  * All rights reserved.
      6  *
      7  * Redistribution and use in source and binary forms, with or without
      8  * modification, are permitted provided that the following conditions
      9  * are met:
     10  * 1. Redistributions of source code must retain the above copyright
     11  *    notice, this list of conditions and the following disclaimer.
     12  * 2. Redistributions in binary form must reproduce the above copyright
     13  *    notice, this list of conditions and the following disclaimer in the
     14  *    documentation and/or other materials provided with the distribution.
     15  * 3. The name of the author may not be used to endorse or promote products
     16  *    derived from this software without specific prior written permission.
     17  *
     18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
     19  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
     20  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
     21  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
     22  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
     23  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
     24  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
     25  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
     26  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
     27  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
     28  */
     29 
     30 #include <machine/asm.h>
     31 
     32 /* R9 contains the address of PS_STRINGS and since its caller saved,
     33  * we can just use it.  R6 has a backup copy of the stack pointer which
     34  * we can use as well.  Since the VAX has perfectly PIC code, we don't
     35  * need to relocate anything upon startup.
     36  */
     37 ENTRY(_rtld_start, 0)
     38 
     39 	/* Allocate space on the stack for the cleanup and obj_main
     40 	 * entries that _rtld() will provide for us.
     41 	 */
     42 	clrl	fp
     43 	subl2	$8,sp
     44 	pushl	sp
     45 
     46 	calls	$1,_rtld
     47 
     48 	movq	(sp)+,r7	/* grab cleanup and obj_main into r7/r8 */
     49 	jmp	2(r0)		/* jump to entry point + 2 */
     50 
     51 /*
     52  * Lazy binding entry point, called via PLT.
     53  */
     54 ALTENTRY(_rtld_bind_start)
     55 	pushr	$0xff		/* save R0-R7 */
     56 	movq	32(sp),r0	/* get addresses of plt.got & reloc index */
     57 	divl3	$12,(r1),r2	/* get reloc index */
     58 	moval	16(r0)[r2],r6	/* get location in .plt.got */
     59 	bicl3	$0xfffffffc,(r6),r7	/* get low 2 bits (addend) */
     60 	pushl	(r1)		/* push relocation index */
     61 	pushl	12(r0)		/* push address of obj entry */
     62 	calls	$2,_rtld_bind
     63 	movpsl	-(sp)		/* flush the instruction cache */
     64 	pushab	1f		/*   by issuing an */
     65 	rei			/*   rei. */
     66 1:	movl	r0,36(sp)	/* save return address onto stack */
     67 	tstl	r7		/* was this a call (0) or jmp (!0)? */
     68 	beql	2f		/*   branch if call */
     69 	addl2	r7,(r6)		/* preserve addend */
     70 	popr	$0xff		/* restore R0-R7 */
     71 	jbr	3f		/* jmp directly since this was a jsb/jmp */
     72 2:	bicw3	6(fp),(r0),r0	/* does the entry mask save any additional regs */
     73 	popr	$0xff		/* restore R0-R7 (cond flags not modified) */
     74 	bneq	4f		/* yes? do it the hard way */
     75 3:	addl2	$4,sp		/* no? skip past plt.got on stack */
     76 	addl2	$2,(sp)		/*    skip past the mask */
     77 	rsb			/*    and jump to it */
     78 4:	addl2	$4,sp
     79 	callg	(ap),*(sp)+	/* return value from _rtld_bind() == actual */
     80 	ret
     81