Home | History | Annotate | Line # | Download | only in conf
kern.ldscript.Xen revision 1.9 
      1 /*	$NetBSD: kern.ldscript.Xen,v 1.9 2015/08/25 08:04:31 uebayasi Exp $	*/
      2 
      3 ENTRY(_start)
      4 SECTIONS
      5 {
      6   /* Read-only sections, merged into text segment: */
      7   .text :
      8   {
      9     *(.text)
     10     *(.text.*)
     11     *(.stub)
     12     *(.rodata)
     13   }
     14   _etext = . ;
     15   PROVIDE (etext = .) ;
     16 
     17   /* Adjust the address for the data segment.  We want to adjust up to
     18      the same address within the page on the next page up.  */
     19   . = ALIGN(0x100000) + (. & (0x100000 - 1));
     20   __data_start = . ;
     21   .data :
     22   {
     23     *(.data)
     24   }
     25   . = ALIGN(COHERENCY_UNIT);
     26   .data.cacheline_aligned :
     27   {
     28     *(.data.cacheline_aligned)
     29   }
     30   . = ALIGN(COHERENCY_UNIT);
     31   .data.read_mostly :
     32   {
     33     *(.data.read_mostly)
     34   }
     35   . = ALIGN(COHERENCY_UNIT);
     36   _edata = . ;
     37   PROVIDE (edata = .) ;
     38   __bss_start = . ;
     39   .bss :
     40   {
     41     *(.bss)
     42     *(.bss.*)
     43     *(COMMON)
     44     . = ALIGN(64 / 8);
     45   }
     46   . = ALIGN(64 / 8);
     47   _end = . ;
     48   PROVIDE (end = .) ;
     49   .note.netbsd.ident :
     50   {
     51     KEEP(*(.note.netbsd.ident));
     52   }
     53 }
     54 SECTIONS
     55 {
     56   .text :
     57   AT (ADDR(.text))
     58   {
     59     *(.text)
     60   } =0
     61 }
     62