Home | History | Annotate | Line # | Download | only in arm
cpu_in_cksum_v4hdr.S revision 1.1 
      1 /*-
      2  * Copyright (c) 2012 The NetBSD Foundation, Inc.
      3  * All rights reserved.
      4  *
      5  * This code is derived from software contributed to The NetBSD Foundation
      6  * by Matt Thomas of 3am Software Foundry.
      7  *
      8  * Redistribution and use in source and binary forms, with or without
      9  * modification, are permitted provided that the following conditions
     10  * are met:
     11  * 1. Redistributions of source code must retain the above copyright
     12  *    notice, this list of conditions and the following disclaimer.
     13  * 2. Redistributions in binary form must reproduce the above copyright
     14  *    notice, this list of conditions and the following disclaimer in the
     15  *    documentation and/or other materials provided with the distribution.
     16  *
     17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     27  * POSSIBILITY OF SUCH DAMAGE.
     28  */
     29 
     30 #include <machine/asm.h>
     31 
     32 RCSID("$NetBSD: cpu_in_cksum_v4hdr.S,v 1.1 2012/12/18 13:41:42 matt Exp $")
     33 
     34 ENTRY(cpu_in_cksum_v4hdr)
     35 	ldr	ip, [r0]		/* load 1st word */
     36 	ldr	r3, [r0, #4]		/* load 2nd word */
     37 	adds	r3, r3, ip		/* add 1st to 2nd */
     38 	ldr	r2, [r0, #8]		/* load 3rd word */
     39 	adcs	r2, r2, r3		/* add sum to 3rd */
     40 	ldr	r1, [r0, #12]		/* load 4th word */
     41 	adcs	r1, r1, r2		/* add sum to 4th */
     42 	ldr	r0, [r0, #16]		/* load 5th word */
     43 	adcs	r0, r0, r1		/* add sum to 5th */
     44 	/*
     45 	 * We now have a 33-bit (r0 + carry) sum which needs to resolved to a
     46 	 * 16-bit sum.
     47 	 */
     48 	mov	r1, r0, lsr #16		/* get upper halfword */
     49 #ifdef _ARM_ARCH_6
     50 	uxth	r0, r0			/* clear upper halfword (16bit carry) */
     51 #else
     52 	bic	r0, r0, #0x00ff0000	/* clear upper halfword (16bit carry) */
     53 	bic	r0, r0, #0xff000000	/* clear upper halfword */
     54 #endif
     55 	adc	r0, r0, r1		/* add halfwords with leftover carry */
     56 	/*
     57 	 * At this point, we have a sum with a max of 0x1fffe.
     58 	 * If we have a 17-bit value (>= 0x10000) then subtract 0xffff.
     59 	 */
     60 	cmp	r0, #0x10000		/* test 16-bit carry */
     61 #ifdef _ARM_ARCH_7
     62 	movw	r1, #0xffff		/* load 0xffff */
     63 #else
     64 	mov	r1, #0x10000		/* load 0x10000 */
     65 	sub	r1, r1, #1		/* subtract 1 to get 0xffff */
     66 #endif
     67 	subge	r0, r0, r1		/* subtract 0xffff */
     68 	eor	r0, r0, r1		/* complement lower halfword */
     69 	RET
     70 END(cpu_in_cksum_v4hdr)
     71