Home | History | Annotate | Line # | Download | only in arm
cpu_in_cksum_v4hdr.S revision 1.2 
      1 /*-
      2  * Copyright (c) 2012 The NetBSD Foundation, Inc.
      3  * All rights reserved.
      4  *
      5  * This code is derived from software contributed to The NetBSD Foundation
      6  * by Matt Thomas of 3am Software Foundry.
      7  *
      8  * Redistribution and use in source and binary forms, with or without
      9  * modification, are permitted provided that the following conditions
     10  * are met:
     11  * 1. Redistributions of source code must retain the above copyright
     12  *    notice, this list of conditions and the following disclaimer.
     13  * 2. Redistributions in binary form must reproduce the above copyright
     14  *    notice, this list of conditions and the following disclaimer in the
     15  *    documentation and/or other materials provided with the distribution.
     16  *
     17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     27  * POSSIBILITY OF SUCH DAMAGE.
     28  */
     29 
     30 #include <machine/asm.h>
     31 
     32 RCSID("$NetBSD: cpu_in_cksum_v4hdr.S,v 1.2 2012/12/18 14:08:25 matt Exp $")
     33 
     34 ENTRY(cpu_in_cksum_v4hdr)
     35 #ifdef _ARM_ARCH_DWORD_OK
     36 	tst	r0, #4			/* 64-bit aligned? */
     37 	ldreqd	r2, [r0], #8		/* load 1st/2nd words */
     38 	ldrne	ip, [r0], #4		/* load 1st word */
     39 	ldreq	ip, [r0, #8]		/* load 5th word */
     40 	ldrned	r2, [r0, #8]		/* load 4th/5th words */
     41 #else
     42 	ldr	ip, [r0]		/* load 1st word */
     43 	ldr	r3, [r0, #4]		/* load 2nd word */
     44 	ldr	r2, [r0, #8]		/* load 3rd word */
     45 #endif
     46 	adds	r3, r3, ip		/* accumulate */
     47 	adcs	r2, r2, r3		/* accumulate */
     48 #ifdef _ARM_ARCH_DWORD_OK
     49 	ldrd	r0, [r0]		/* load remaining words */
     50 #else
     51 	ldr	r1, [r0, #12]		/* load 4th word */
     52 	ldr	r0, [r0, #16]		/* load 5th word */
     53 #endif
     54 	adcs	r1, r1, r2		/* accumulate */
     55 	adcs	r0, r0, r1		/* accumulate */
     56 	/*
     57 	 * We now have a 33-bit (r0 + carry) sum which needs to resolved to a
     58 	 * 16-bit sum.
     59 	 */
     60 	mov	r1, r0, lsr #16		/* get upper halfword */
     61 #ifdef _ARM_ARCH_6
     62 	uxth	r0, r0			/* clear upper halfword (16bit carry) */
     63 #else
     64 	bic	r0, r0, #0x00ff0000	/* clear upper halfword (16bit carry) */
     65 	bic	r0, r0, #0xff000000	/* clear upper halfword */
     66 #endif
     67 	adc	r0, r0, r1		/* add halfwords with leftover carry */
     68 	/*
     69 	 * At this point, we have a sum with a max of 0x1fffe.
     70 	 * If we have a 17-bit value (>= 0x10000) then subtract 0xffff.
     71 	 */
     72 	cmp	r0, #0x10000		/* test 16-bit carry */
     73 #ifdef _ARM_ARCH_7
     74 	movw	r1, #0xffff		/* load 0xffff */
     75 #else
     76 	mov	r1, #0x10000		/* load 0x10000 */
     77 	sub	r1, r1, #1		/* subtract by 1 to get 0xffff */
     78 #endif
     79 	subge	r0, r0, r1		/* subtract 0xffff */
     80 	eor	r0, r0, r1		/* complement lower halfword */
     81 	RET
     82 END(cpu_in_cksum_v4hdr)
     83