Home | History | Annotate | Line # | Download | only in iq80310
iq80310_start.S revision 1.5 
      1 /*	$NetBSD: iq80310_start.S,v 1.5 2011/01/31 06:28:03 matt Exp $	*/
      2 
      3 /*
      4  * Copyright (c) 2002 Wasabi Systems, Inc.
      5  * All rights reserved.
      6  *
      7  * Written by Jason R. Thorpe for Wasabi Systems, Inc.
      8  *
      9  * Redistribution and use in source and binary forms, with or without
     10  * modification, are permitted provided that the following conditions
     11  * are met:
     12  * 1. Redistributions of source code must retain the above copyright
     13  *    notice, this list of conditions and the following disclaimer.
     14  * 2. Redistributions in binary form must reproduce the above copyright
     15  *    notice, this list of conditions and the following disclaimer in the
     16  *    documentation and/or other materials provided with the distribution.
     17  * 3. All advertising materials mentioning features or use of this software
     18  *    must display the following acknowledgement:
     19  *	This product includes software developed for the NetBSD Project by
     20  *	Wasabi Systems, Inc.
     21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
     22  *    or promote products derived from this software without specific prior
     23  *    written permission.
     24  *
     25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
     26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
     29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     35  * POSSIBILITY OF SUCH DAMAGE.
     36  */
     37 
     38 #include <machine/asm.h>
     39 #include <arm/armreg.h>
     40 #include "assym.h"
     41 
     42 RCSID("$NetBSD: iq80310_start.S,v 1.5 2011/01/31 06:28:03 matt Exp $")
     43 
     44 	.section .start,"ax",%progbits
     45 
     46 	.global	_C_LABEL(iq80310_start)
     47 _C_LABEL(iq80310_start):
     48 	/*
     49 	 * We assume we've been loaded VA==PA, or that the MMU is
     50 	 * disabled.  We will go ahead and disable the MMU here
     51 	 * so that we don't have to worry about flushing caches, etc.
     52 	 */
     53 	mrc	p15, 0, r2, c1, c0, 0
     54 	bic	r2, r2, #CPU_CONTROL_MMU_ENABLE
     55 	mcr	p15, 0, r2, c1, c0, 0
     56 
     57 	nop
     58 	nop
     59 	nop
     60 
     61 	/*
     62 	 * We want to construct a memory map that maps us
     63 	 * VA==PA (SDRAM at 0xa0000000) and also double-maps
     64 	 * that space at 0xc0000000 (where the kernel address
     65 	 * space starts).  We create these mappings uncached
     66 	 * and unbuffered to be safe.
     67 	 *
     68 	 * We also want to map the various devices we want to
     69 	 * talk to VA==PA during bootstrap.
     70 	 *
     71 	 * We just use section mappings for all of this to make it easy.
     72 	 *
     73 	 * We will put the L1 table to do all this at 0xa0004000, which
     74 	 * is also where RedBoot puts it.
     75 	 */
     76 
     77 	/*
     78 	 * Step 1: Map the entire address space VA==PA.
     79 	 */
     80 	adr	r0, Ltable
     81 	ldr	r0, [r0]			/* r0 = &l1table */
     82 
     83 	mov	r3, #(L1_S_AP_KRW)
     84 	orr	r3, r3, #(L1_TYPE_S)
     85 	mov	r2, #0x100000			/* advance by 1MB */
     86 	mov	r1, #0x1000			/* 4096MB */
     87 1:
     88 	str	r3, [r0], #0x04
     89 	add	r3, r3, r2
     90 	subs	r1, r1, #1
     91 	bgt	1b
     92 
     93 	/*
     94 	 * Step 2: Map VA 0xc0000000->0xc3ffffff to PA 0xa0000000->0xa3ffffff.
     95 	 */
     96 	adr	r0, Ltable			/* r0 = &l1table */
     97 	ldr	r0, [r0]
     98 
     99 	mov	r3, #(L1_S_AP_KRW)
    100 	orr	r3, r3, #(L1_TYPE_S)
    101 	orr	r3, r3, #0xa0000000
    102 	add	r0, r0, #(0xc00 * 4)		/* offset to 0xc00xxxxx */
    103 	mov	r1, #0x40			/* 64MB */
    104 1:
    105 	str	r3, [r0], #0x04
    106 	add	r3, r3, r2
    107 	subs	r1, r1, #1
    108 	bgt	1b
    109 
    110 	/* OK!  Page table is set up.  Give it to the CPU. */
    111 	adr	r0, Ltable
    112 	ldr	r0, [r0]
    113 	mcr	p15, 0, r0, c2, c0, 0
    114 
    115 	/* Flush the old TLBs, just in case. */
    116 	mcr	p15, 0, r0, c8, c7, 0
    117 
    118 	/* Set the Domain Access register.  Very important! */
    119 	mov	r0, #1
    120 	mcr	p15, 0, r0, c3, c0, 0
    121 
    122 	/* Get ready to jump to the "real" kernel entry point... */
    123 	ldr	r0, Lstart
    124 
    125 	/* OK, let's enable the MMU. */
    126 	mrc	p15, 0, r2, c1, c0, 0
    127 	orr	r2, r2, #CPU_CONTROL_MMU_ENABLE
    128 	mcr	p15, 0, r2, c1, c0, 0
    129 
    130 	nop
    131 	nop
    132 	nop
    133 
    134 	/* CPWAIT sequence to make sure the MMU is on... */
    135 	mrc	p15, 0, r2, c2, c0, 0	/* arbitrary read of CP15 */
    136 	mov	r2, r2			/* force it to complete */
    137 	mov	pc, r0			/* leap to kernel entry point! */
    138 
    139 Ltable:
    140 	.word	0xa0004000
    141 
    142 Lstart:
    143 	.word	start
    144