xref: /src/sys/arch/i386/conf/kern.ldscript.Xen

/*	$NetBSD: kern.ldscript.Xen,v 1.5 2014/11/01 11:58:55 uebayasi Exp $	*/

OUTPUT_FORMAT("elf32-i386", "elf32-i386",
	      "elf32-i386")
OUTPUT_ARCH(i386)
SECTIONS
{
   /* Read-only sections, merged into text segment: */
   .text :
   {
     *(.text)
     *(.text.*)
     *(.stub)
   } =0
   _etext = . ;
   PROVIDE (etext = .) ;

   .rodata :
   {
     *(.rodata)
     *(.rodata.*)
   }

   /* Adjust the address for the data segment.  We want to adjust up to
      the same address within the page on the next page up.  */
   . = ALIGN(0x1000) + (. & (0x1000 - 1));
   __data_start = . ;
   .data :
   {
     *(.data)
     . = ALIGN(64);	/* COHERENCY_UNIT */
     *(.data.cacheline_aligned)
     . = ALIGN(64);	/* COHERENCY_UNIT */
     *(.data.read_mostly)
     . = ALIGN(64);	/* COHERENCY_UNIT */
   }
   . = ALIGN(64);	/* COHERENCY_UNIT */
   _edata = . ;
   PROVIDE (edata = .) ;
   __bss_start = . ;
   .bss :
   {
     *(.bss)
     *(.bss.*)
     *(COMMON)
     . = ALIGN(32 / 8);
   }
   . = ALIGN(32 / 8);
  _end = . ;
  PROVIDE (end = .) ;
  .note.netbsd.ident :
  {
    KEEP(*(.note.netbsd.ident));
  }
}