Home | History | Annotate | Line # | Download | only in conf
kern.ldscript.Xen revision 1.14 
      1 /*	$NetBSD: kern.ldscript.Xen,v 1.14 2017/06/25 20:22:32 bouyer Exp $	*/
      2 
      3 #include "assym.h"
      4 
      5 __PAGE_SIZE = 0x1000 ;
      6 
      7 SECTIONS
      8 {
      9 	.text :
     10 	{
     11 		*(.text)
     12 		*(.text.*)
     13 		*(.stub)
     14 	}
     15 	_etext = . ;
     16 	PROVIDE (etext = .) ;
     17 
     18 	. = ALIGN(__PAGE_SIZE);
     19 
     20 	__rodata_start = . ;
     21 	.rodata :
     22 	{
     23 		*(.rodata)
     24 		*(.rodata.*)
     25 	}
     26 
     27 	. = ALIGN(__PAGE_SIZE);
     28 
     29 	__data_start = . ;
     30 	.data :
     31 	{
     32 		*(.data)
     33 	}
     34 
     35 	. = ALIGN(COHERENCY_UNIT);
     36 	.data.cacheline_aligned :
     37 	{
     38 		*(.data.cacheline_aligned)
     39 	}
     40 	. = ALIGN(COHERENCY_UNIT);
     41 	.data.read_mostly :
     42 	{
     43 		*(.data.read_mostly)
     44 	}
     45 	. = ALIGN(COHERENCY_UNIT);
     46 
     47 	_edata = . ;
     48 	PROVIDE (edata = .) ;
     49 	__bss_start = . ;
     50 	.bss :
     51 	{
     52 		*(.bss)
     53 		*(.bss.*)
     54 		*(COMMON)
     55 		. = ALIGN(32 / 8);
     56 	}
     57 	. = ALIGN(32 / 8);
     58 	_end = . ;
     59 	PROVIDE (end = .) ;
     60 
     61 	. = ALIGN(__PAGE_SIZE);
     62 
     63 	/* End of the kernel image */
     64 	__kernel_end = . ;
     65 
     66 	.note.netbsd.ident :
     67 	{
     68 		KEEP(*(.note.netbsd.ident));
     69 	}
     70 }
     71 
     72 SECTIONS
     73 {
     74 	.text :
     75 	AT (ADDR(.text))
     76 	{
     77 		*(.text)
     78 	} = 0
     79 }
     80