Home | History | Annotate | Line # | Download | only in conf
kern.ldscript.Xen revision 1.5 
      1 /*	$NetBSD: kern.ldscript.Xen,v 1.5 2014/11/01 11:58:55 uebayasi Exp $	*/
      2 
      3 OUTPUT_FORMAT("elf32-i386", "elf32-i386",
      4 	      "elf32-i386")
      5 OUTPUT_ARCH(i386)
      6 SECTIONS
      7 {
      8    /* Read-only sections, merged into text segment: */
      9    .text :
     10    {
     11      *(.text)
     12      *(.text.*)
     13      *(.stub)
     14    } =0
     15    _etext = . ;
     16    PROVIDE (etext = .) ;
     17 
     18    .rodata :
     19    {
     20      *(.rodata)
     21      *(.rodata.*)
     22    }
     23 
     24    /* Adjust the address for the data segment.  We want to adjust up to
     25       the same address within the page on the next page up.  */
     26    . = ALIGN(0x1000) + (. & (0x1000 - 1));
     27    __data_start = . ;
     28    .data :
     29    {
     30      *(.data)
     31      . = ALIGN(64);	/* COHERENCY_UNIT */
     32      *(.data.cacheline_aligned)
     33      . = ALIGN(64);	/* COHERENCY_UNIT */
     34      *(.data.read_mostly)
     35      . = ALIGN(64);	/* COHERENCY_UNIT */
     36    }
     37    . = ALIGN(64);	/* COHERENCY_UNIT */
     38    _edata = . ;
     39    PROVIDE (edata = .) ;
     40    __bss_start = . ;
     41    .bss :
     42    {
     43      *(.bss)
     44      *(.bss.*)
     45      *(COMMON)
     46      . = ALIGN(32 / 8);
     47    }
     48    . = ALIGN(32 / 8);
     49   _end = . ;
     50   PROVIDE (end = .) ;
     51   .note.netbsd.ident :
     52   {
     53     KEEP(*(.note.netbsd.ident));
     54   }
     55 }
     56