kern.ldscript revision 1.10 
1/*	$NetBSD: kern.ldscript,v 1.10 2014/11/01 11:58:55 uebayasi Exp $	*/
2
3OUTPUT_FORMAT("elf32-i386", "elf32-i386",
4	      "elf32-i386")
5OUTPUT_ARCH(i386)
6ENTRY(_start)
7SECTIONS
8{
9   /* Read-only sections, merged into text segment: */
10   .text :
11   AT (ADDR(.text) & 0x0fffffff)
12   {
13     *(.text)
14     *(.text.*)
15     *(.stub)
16   } =0
17   _etext = . ;
18   PROVIDE (etext = .) ;
19
20   .rodata :
21   AT (LOADADDR(.text) + (ADDR(.rodata) - ADDR(.text)))
22   {
23     *(.rodata)
24     *(.rodata.*)
25   }
26
27   /* Adjust the address for the data segment.  We want to adjust up to
28      the same address within the page on the next page up.  */
29   . = ALIGN(0x1000) + (. & (0x1000 - 1));
30   __data_start = . ;
31   .data :
32   AT (LOADADDR(.text) + (ADDR(.data) - ADDR(.text)))
33   {
34     *(.data)
35     . = ALIGN(64);	/* COHERENCY_UNIT */
36     *(.data.cacheline_aligned)
37     . = ALIGN(64);	/* COHERENCY_UNIT */
38     *(.data.read_mostly)
39     . = ALIGN(64);	/* COHERENCY_UNIT */
40   }
41   . = ALIGN(64);	/* COHERENCY_UNIT */
42   _edata = . ;
43   PROVIDE (edata = .) ;
44   __bss_start = . ;
45   .bss :
46   AT (LOADADDR(.text) + (ADDR(.bss) - ADDR(.text)))
47   {
48     *(.bss)
49     *(.bss.*)
50     *(COMMON)
51     . = ALIGN(32 / 8);
52   }
53   . = ALIGN(32 / 8);
54  _end = . ;
55  PROVIDE (end = .) ;
56  .note.netbsd.ident :
57  {
58    KEEP(*(.note.netbsd.ident));
59  }
60}
61