Home | History | Annotate | Line # | Download | only in bootia32
ldscript revision 1.1 
      1 /*	$NetBSD: ldscript,v 1.1 2017/01/24 11:09:14 nonaka Exp $	*/
      2 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
      3 OUTPUT_ARCH(i386)
      4 ENTRY(_start)
      5 SECTIONS
      6 {
      7   . = 0;
      8   ImageBase = .;
      9   .hash : { *(.hash) }	/* this MUST come first! */
     10   . = ALIGN(4096);
     11   .text :
     12   {
     13    *(.text)
     14    *(.text.*)
     15    *(.gnu.linkonce.t.*)
     16   }
     17   . = ALIGN(4096);
     18   .sdata :
     19   {
     20    *(.got.plt)
     21    *(.got)
     22    *(.srodata)
     23    *(.sdata)
     24    *(.sbss)
     25    *(.scommon)
     26   }
     27   . = ALIGN(4096);
     28   .data :
     29   {
     30    *(.rodata*)
     31    *(.data)
     32    *(.data1)
     33    *(.data.*)
     34    *(.sdata)
     35    *(.got.plt)
     36    *(.got)
     37    /* the EFI loader doesn't seem to like a .bss section, so we stick
     38       it all into .data: */
     39    *(.sbss)
     40    *(.scommon)
     41    *(.dynbss)
     42    *(.bss)
     43    *(COMMON)
     44   }
     45   . = ALIGN(4096);
     46   .dynamic  : { *(.dynamic) }
     47   . = ALIGN(4096);
     48   .rel :
     49   {
     50     *(.rel.data)
     51     *(.rel.data.*)
     52     *(.rel.got)
     53     *(.rel.stab)
     54     *(.data.rel.ro.local)
     55     *(.data.rel.local)
     56     *(.data.rel.ro)
     57     *(.data.rel*)
     58   }
     59   . = ALIGN(4096);
     60   .reloc :		/* This is the PECOFF .reloc section! */
     61   {
     62     *(.reloc)
     63   }
     64   . = ALIGN(4096);
     65   .dynsym   : { *(.dynsym) }
     66   . = ALIGN(4096);
     67   .dynstr   : { *(.dynstr) }
     68   . = ALIGN(4096);
     69   /DISCARD/ :
     70   {
     71     *(.rel.reloc)
     72     *(.eh_frame)
     73     *(.note.GNU-stack)
     74   }
     75   .comment 0 : { *(.comment) }
     76 }
     77