kern.ldscript revision 1.4 
1/* $FreeBSD$ */
2OUTPUT_FORMAT("elf64-ia64-little", "elf64-ia64-little", "elf64-ia64-little")
3OUTPUT_ARCH(ia64)
4ENTRY(start)
5kernel_text = 0xe000000004000000;
6SECTIONS
7{
8  /* Read-only sections, merged into text segment: */
9  . = kernel_text + SIZEOF_HEADERS;
10  .interp         : { *(.interp) }
11  .hash           : { *(.hash) }
12  .dynsym         : { *(.dynsym) }
13  .dynstr         : { *(.dynstr) }
14  .gnu.version    : { *(.gnu.version) }
15  .gnu.version_d  : { *(.gnu.version_d) }
16  .gnu.version_r  : { *(.gnu.version_r) }
17  .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
18  .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
19  .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
20  .rela.got       : { *(.rela.got) }
21  .rela.sdata     : { *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*) }
22  .rela.sbss      : { *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*) }
23  .rela.sdata2    : { *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*) }
24  .rela.sbss2     : { *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*) }
25  .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
26  .rela.plt       : { *(.rela.plt) }
27  .rela.IA_64.pltoff   : { *(.rela.IA_64.pltoff) }
28  PROVIDE (btext = .);
29  .plt            : { *(.plt) }
30  .text           :
31  {
32    *(.text .stub .text.* .gnu.linkonce.t.*)
33    /* .gnu.warning sections are handled specially by elf32.em.  */
34    *(.gnu.warning)
35  } =0x00300000010070000002000001000400
36  _etext = .;
37  PROVIDE (etext = .);
38  .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
39  .rodata1        : { *(.rodata1) }
40  .sdata2         : { *(.sdata2 .sdata2.* .gnu.linkonce.s2.*) }
41  .sbss2          : { *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*) }
42  .opd            : { *(.opd) }
43  .IA_64.unwind_info   : { *(.IA_64.unwind_info* .gnu.linkonce.ia64unwi.*) }
44  .IA_64.unwind   : { *(.IA_64.unwind* .gnu.linkonce.ia64unw.*) }
45  /* Adjust the address for the data segment.  We want to adjust up to
46     the same address within the page on the next page up.  */
47  . = . + 8192;
48  .data           :
49  {
50    *(.data.proc0 .data .data.* .gnu.linkonce.d.*)
51    SORT(CONSTRUCTORS)
52  }
53  .data1          : { *(.data1) }
54  .dynamic        : { *(.dynamic) }
55  . = ALIGN(16);
56  __gp = . + 0x200000;
57  .got            : { *(.got.plt) *(.got) }
58  .IA_64.pltoff   : { *(.IA_64.pltoff) }
59  /* We want the small data sections together, so single-instruction offsets
60     can access them all, and initialized data all before uninitialized, so
61     we can shorten the on-disk segment size.  */
62  .sdata          :
63  {
64    *(.sdata .sdata.* .gnu.linkonce.s.*)
65  }
66  _edata = .;
67  PROVIDE (edata = .);
68  __bss_start = .;
69  .sbss           :
70  {
71    PROVIDE (__sbss_start = .);
72    PROVIDE (___sbss_start = .);
73    *(.dynsbss)
74    *(.sbss .sbss.* .gnu.linkonce.sb.*)
75    *(.scommon)
76    PROVIDE (__sbss_end = .);
77    PROVIDE (___sbss_end = .);
78  }
79  .bss            :
80  {
81    *(.dynbss)
82    *(.bss .bss.* .gnu.linkonce.b.*)
83    *(COMMON)
84    /* Align here to ensure that the .bss section occupies space up to
85       _end.  Align after .bss to ensure correct alignment even if the
86       .bss section disappears because there are no input sections.  */
87    . = ALIGN(64 / 8);
88  }
89  . = ALIGN(64 / 8);
90  _end = .;
91  PROVIDE (end = .);
92  /* Stabs debugging sections.  */
93  .stab          0 : { *(.stab) }
94  .stabstr       0 : { *(.stabstr) }
95  .stab.excl     0 : { *(.stab.excl) }
96  .stab.exclstr  0 : { *(.stab.exclstr) }
97  .stab.index    0 : { *(.stab.index) }
98  .stab.indexstr 0 : { *(.stab.indexstr) }
99  .comment       0 : { *(.comment) }
100  /* DWARF debug sections.
101     Symbols in the DWARF debugging sections are relative to the beginning
102     of the section so we begin them at 0.  */
103  /* DWARF 1 */
104  .debug          0 : { *(.debug) }
105  .line           0 : { *(.line) }
106  /* GNU DWARF 1 extensions */
107  .debug_srcinfo  0 : { *(.debug_srcinfo) }
108  .debug_sfnames  0 : { *(.debug_sfnames) }
109  /* DWARF 1.1 and DWARF 2 */
110  .debug_aranges  0 : { *(.debug_aranges) }
111  .debug_pubnames 0 : { *(.debug_pubnames) }
112  /* DWARF 2 */
113  .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
114  .debug_abbrev   0 : { *(.debug_abbrev) }
115  .debug_line     0 : { *(.debug_line) }
116  .debug_frame    0 : { *(.debug_frame) }
117  .debug_str      0 : { *(.debug_str) }
118  .debug_loc      0 : { *(.debug_loc) }
119  .debug_macinfo  0 : { *(.debug_macinfo) }
120  /* SGI/MIPS DWARF 2 extensions */
121  .debug_weaknames 0 : { *(.debug_weaknames) }
122  .debug_funcnames 0 : { *(.debug_funcnames) }
123  .debug_typenames 0 : { *(.debug_typenames) }
124  .debug_varnames  0 : { *(.debug_varnames) }
125}
126