asm2gas revision 1.8 
1#!/bin/sh
2#	$NetBSD: asm2gas,v 1.8 2006/06/24 03:28:42 tsutsui Exp $
3
4#
5# Copyright (c) 1998 The NetBSD Foundation, Inc.
6# All rights reserved.
7#
8# This code is derived from software contributed to The NetBSD Foundation
9# by Charles M. Hannum.
10#
11# Redistribution and use in source and binary forms, with or without
12# modification, are permitted provided that the following conditions
13# are met:
14# 1. Redistributions of source code must retain the above copyright
15#    notice, this list of conditions and the following disclaimer.
16# 2. Redistributions in binary form must reproduce the above copyright
17#    notice, this list of conditions and the following disclaimer in the
18#    documentation and/or other materials provided with the distribution.
19# 3. All advertising materials mentioning features or use of this software
20#    must display the following acknowledgement:
21#        This product includes software developed by the NetBSD
22#        Foundation, Inc. and its contributors.
23# 4. Neither the name of The NetBSD Foundation nor the names of its
24#    contributors may be used to endorse or promote products derived
25#    from this software without specific prior written permission.
26#
27# THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
28# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
29# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
30# PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
31# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
32# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
33# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
34# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
35# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
36# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
37# POSSIBILITY OF SUCH DAMAGE.
38#
39
40# This ugly script converts assembler code from Motorola's format to a
41# form that gas (MIT syntax) can digest.
42
43: ${SED:=sed}
44cat $1 | ${SED} -e '
45  # format canonicalization
46
47  /[ 	]IDNT[ 	]/{s/^/|/;p;d;}
48  /^\*/{s//|/;p;d;}
49  s/;/|/
50  /[ 	]equ[ 	]/{
51    s/\([A-Za-z_][A-Za-z0-9_]*\)[ 	]*equ[ 	]*/\1,/
52    s/[ 	][ 	]*\(.*\)$/		|\1/
53    s/		||/		|/
54    s/^/	.set	/
55    p;d
56  }
57  s/^\([A-Za-z_][A-Za-z0-9_]*\)[ 	][ 	]*/\1:	/
58  s/^\([A-Za-z_][A-Za-z0-9_]*\)$/\1:/
59  /^[A-Za-z_][A-Za-z0-9_]*:/{
60    h
61    s/:.*$/:/
62    p
63    g
64    s/^.*:[ 	]*/	/
65    /^	$/d
66  }
67  /^[ 	][ 	]*\([.a-zA-Z][.a-zA-Z0-9]*\)/{
68    h
69    s///
70    s/^[ 	][ 	]*//
71    s/[ 	][ 	]*\(.*\)$/		|\1/
72    s/		||/		|/
73    x
74    s/^[ 	][ 	]*//
75    s/[ 	][ 	]*.*$/	/
76    y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/
77    s/^/	/
78    G
79    s/\n//
80  }
81' | ${SED} -e '
82  # operator conversion
83
84  s/^	section	7/	.text/
85  s/^	section	8/	.text/
86  s/^	section	15/	.data/
87  /^	include/{s/include[ 	]/.include "/;s/\.h[ 	]*$/.defs"/;p;d;}
88  s/^	xref/|	xref/
89  s/^	end/|	end/
90  s/^	xdef/	.global/
91
92  s/^	dc\.l/	.long/
93  s/^	dc\.w/	.short/
94  s/^	dc\.b/	.byte/
95
96  /^	[aceg-z]/{
97    /^	add[aiqx]*\.[bwl]	/{s/\.//;p;d;}
98    /^	andi*\.[bwl]	/{s/\.//;p;d;}
99    /^	as[lr]\.[bwl]	/{s/\.//;p;d;}
100    /^	clr\.[bwl]	/{s/\.//;p;d;}
101    /^	cmp[i2]*\.[bwl]	/{s/\.//;p;d;}
102    /^	eori*\.[bwl]	/{s/\.//;p;d;}
103    /^	lea\.l	/{s/\..//;p;d;}
104    /^	ls[lr]\.[bwl]	/{s/\.//;p;d;}
105    /^	move[acmqs]*\.[bwl]	/{s/\.//;p;d;}
106    /^	mul[su]\.[wl]	/{s/\.//;p;d;}
107    /^	neg\.[bwl]	/{s/\.//;p;d;}
108    /^	ori*\.[bwl]	/{s/\.//;p;d;}
109    /^	ro[lrx]*\.[bwl]	/{s/\.//;p;d;}
110    /^	sub[aiqx]*\.[bwl]	/{s/\.//;p;d;}
111    /^	swap\.w	/{s/\..//;p;d;}
112    /^	s\([a-tv-z][a-z]*\)\.b	/{s/\..//;p;d;}
113    /^	tst\.[bwl]	/{s/\.//;p;d;}
114    p;d
115  }
116
117  /^	bchg\.[bl]	/{s/\..//;p;d;}
118  /^	bclr\.[bl]	/{s/\..//;p;d;}
119  /^	bset\.[bl]	/{s/\..//;p;d;}
120  /^	btst\.[bl]	/{s/\..//;p;d;}
121  /^	div[sul]*\.[wl]	/{s/\.//;p;d;}
122  /^	fabs\.[sdx]	/{s/\.//;p;d;}
123  /^	fadd\.[sdxbwl]	/{s/\.//;p;d;}
124  /^	fcmp\.[sdxbwl]	/{s/\.//;p;d;}
125  /^	fdiv\.[sdx]	/{s/\.//;p;d;}
126  /^	fmove[mx]*\.[sdxbwl]	/{s/\.//;p;d;}
127  /^	fmul\.[sdx]	/{s/\.//;p;d;}
128  /^	fneg\.[sdx]	/{s/\.//;p;d;}
129  /^	fsqrt\.[sdx]	/{s/\.//;p;d;}
130  /^	fsub\.[sdxbwl]	/{s/\.//;p;d;}
131  /^	ftst\.[sdx]	/{s/\.//;p;d;}
132
133  /^	b[a-eg-z][a-z]*\.b	/{s/\.b/s/;p;d;}
134  /^	b[a-eg-z][a-z]*\.w	/{s/\.w//;p;d;}
135  /^	b[a-eg-z][a-z]*\.l	/{s/\.l/l/;p;d;}
136  /^	db[a-z][a-z]*\.w	/{s/\.w//;p;d;}
137  /^	fb[a-eg-z][a-z]*\.w	/{s/\.w//;p;d;}
138  /^	fb[a-eg-z][a-z]*\.l	/{s/\.l/l/;p;d;}
139' | ${SED} -e '
140  # operand conversion
141
142  s/\([^_a-zA-Z0-9]\)FPIAR\([^_a-zA-Z0-9]\)/\1%FPI\2/g
143  s/\([^_a-zA-Z0-9]\)FPIAR$/\1%FPI/g
144  s/\([^_a-zA-Z0-9]\)fpiar\([^_a-zA-Z0-9]\)/\1%fpi\2/g
145  s/\([^_a-zA-Z0-9]\)fpiar$/\1%fpi/g
146  s/\([^_a-zA-Z0-9]\)FPCR\([^_a-zA-Z0-9]\)/\1%FPCR\2/g
147  s/\([^_a-zA-Z0-9]\)FPCR$/\1%FPCR/g
148  s/\([^_a-zA-Z0-9]\)fpcr\([^_a-zA-Z0-9]\)/\1%fpcr\2/g
149  s/\([^_a-zA-Z0-9]\)fpcr$/\1%fpcr/g
150  s/\([^_a-zA-Z0-9]\)FPSR\([^_a-zA-Z0-9]\)/\1%FPSR\2/g
151  s/\([^_a-zA-Z0-9]\)FPSR$/\1%FPSR/g
152  s/\([^_a-zA-Z0-9]\)fpsr\([^_a-zA-Z0-9]\)/\1%fpsr\2/g
153  s/\([^_a-zA-Z0-9]\)fpsr$/\1%fpsr/g
154
155  s/\$/0x/g
156  s/#:/#:0x/g
157
158  s/\([^[:alnum:]_]\)\([dDaA][0-7]\)\([^[:alnum:]_]\)/\1%\2\3/g
159  s/\([^[:alnum:]_]\)\([fF][pP][0-7]\)\([^[:alnum:]_]\)/\1%\2\3/g
160  s/\([^[:alnum:]_]\)\(sp\)\([^[:alnum:]_]\)/\1%\2\3/g
161  s/\([^[:alnum:]_]\)\(pc\)\([^[:alnum:]_]\)/\1%\2\3/g
162
163  s/\([^[:alnum:]_]\)\([dDaA][0-7]\)$/\1%\2/g
164  s/\([^[:alnum:]_]\)\([fF][pP][0-7]\)$/\1%\2/g
165  s/\([^[:alnum:]_]\)\(sp\)$/\1%\2/g
166
167  s/\(,\)\([dDaA][0-7]\)/\1%\2/g
168  s/\(,\)\([fF][pP][0-7]\)/\1%\2/g
169
170  s/-(\(%[sSpPaA][pPcC0-7]\))/\1@-/g
171  s/(\(%[sSpPaA][pPcC0-7]\))+/\1@+/g
172  s/\([-+A-Za-z0-9_]*\)(\(%[sSpPaA][pPcC0-7]\)\([),]\)/\2@(\1\3/g
173
174  s/\.\([bBwWlL])\)/:\1/g
175  s/\.\([bBwWlL]\)\*\([0-9][0-9]*)\)/:\1:\2/g
176  s/\*\([0-9][0-9]*\))/:l:\1)/g
177  s/{\([0-9][0-9]*\):\([0-9][0-9]*\)}/{#\1:#\2}/g
178  s/{\(%[dD][0-7]\):\([0-9][0-9]*\)}/{\1:#\2}/g
179  s/{\([dD][0-7]\):\([0-9][0-9]*\)}/{%\1:#\2}/g
180  s/{\([dD][0-7]\):\(%[dD][0-9]*\)}/{%\1:\2}/g
181
182  s/\(-\)\([dDaA][0-7]\)\([^_a-zA-Z0-9]\)/\1%\2\3/g
183  s/\(-\)\([fF][pP][0-7]\)\([^_a-zA-Z0-9]\)/\1%\2\3/g
184
185  s/\(\/\)\([dDaA][0-7]\)\([^_a-zA-Z0-9]\)/\1%\2\3/g
186  s/\(\/\)\([fF][pP][0-7]\)\([^_a-zA-Z0-9]\)/\1%\2\3/g
187
188  s/@(0*)/@/g
189  s/(,/(/g;s/:)/)/g
190
191  # make up for a gas bug
192  /^	fmovemx	/{
193	s/	\(%[fF][pP][0-7]\),/	\1-\1,/
194	s/,\(%[fF][pP][0-7]\)	/,\1-\1	/
195	s/,\(%[fF][pP][0-7]\)$/,\1-\1/
196  }
197' | ${SED} -e '
198  # Floating point literal conversion
199
200  s/:0x41dfffffffc00000/0r2147483647.0/g
201  s/:0xc1e0000000000000/0r-2147483648.0/g
202  s/:0x41dfffffffe00000/0r2147483647.5/g
203  s/:0xc1e0000000100000/0r-2147483648.5/g
204  s/:0x46fffe00/0r32767.0/g
205  s/:0xc7000000/0r-32768.0/g
206  s/:0x46ffff00/0r32767.5/g
207  s/:0xc7000080/0r-32768.5/g
208  s/:0x42fe0000/0r127.0/g
209  s/:0xc3000000/0r-128.0/g
210  s/:0x42ff0000/0r127.5/g
211  s/:0xc3008000/0r-128.5/g
212  s/:0x3F800000/0r1.0/g
213  s/:0x00000000/0r0.0/g
214  s/:0xBF800000/0r-1.0/g
215  s/:0x3F000000/0r0.5/g
216  s/:0x3E800000/0r0.25/g
217  s/:0x42B8AA3B/0r92.332481384277343750/g
218  s/:0xBC317218/0r-0.0108304247260093688964843750/g
219  s/:0x3AB60B70/0r0.001388890668749809265136718750/g
220  s/:0x3C088895/0r0.0083333449438214302062988281250/g
221  s/:0x42B8AA3B/0r92.332481384277343750/g
222  s/:0x3950097B/0r0.0001983995753107592463493347167968750/g
223  s/:0x3AB60B6A/0r0.001388889970257878303527832031250/g
224  s/:0x2F30CAA8/0r1.60791047143504783889511600136756896972656250e-10/g
225  s/:0x310F8290/0r2.0883454965314740547910332679748535156250e-09/g
226  s/:0x32D73220/0r2.5052088403754169121384620666503906250e-08/g
227  s/:0x3493F281/0r2.755732850800995947793126106262207031250e-07/g
228  s/:0x40000000/0r2.0/g
229  s/:0x42800000/0r6.40e+01/g
230  s/:0x3C800000/0r1.56250e-02/g
231  s/fadds	#:0x00800000,%[fF][pP]0/	.long	0xf23c4422,0x00800000/
232  s/fsubs	#:0x00800000,%[fF][pP]0/	.long	0xf23c4428,0x00800000/
233  s/fsubs	#:0x00800000,%[fF][pP]1/	.long	0xf23c44a8,0x00800000/
234  s/fmoves	#:0x80000000,%[fF][pP]0/	.long	0xf23c4400,0x80000000/
235  s/fmoves		#:0x00000000,%[fF][pP]0/	.long	0xf23c4400,0x00000000/
236
237'
238