xref: /src/sys/arch/m68k/fpsp/sasin.sa

*	$NetBSD: sasin.sa,v 1.2 1994/10/26 07:49:29 cgd Exp $

*	MOTOROLA MICROPROCESSOR & MEMORY TECHNOLOGY GROUP
*	M68000 Hi-Performance Microprocessor Division
*	M68040 Software Package 
*
*	M68040 Software Package Copyright (c) 1993, 1994 Motorola Inc.
*	All rights reserved.
*
*	THE SOFTWARE is provided on an "AS IS" basis and without warranty.
*	To the maximum extent permitted by applicable law,
*	MOTOROLA DISCLAIMS ALL WARRANTIES WHETHER EXPRESS OR IMPLIED,
*	INCLUDING IMPLIED WARRANTIES OF MERCHANTABILITY OR FITNESS FOR A
*	PARTICULAR PURPOSE and any warranty against infringement with
*	regard to the SOFTWARE (INCLUDING ANY MODIFIED VERSIONS THEREOF)
*	and any accompanying written materials. 
*
*	To the maximum extent permitted by applicable law,
*	IN NO EVENT SHALL MOTOROLA BE LIABLE FOR ANY DAMAGES WHATSOEVER
*	(INCLUDING WITHOUT LIMITATION, DAMAGES FOR LOSS OF BUSINESS
*	PROFITS, BUSINESS INTERRUPTION, LOSS OF BUSINESS INFORMATION, OR
*	OTHER PECUNIARY LOSS) ARISING OF THE USE OR INABILITY TO USE THE
*	SOFTWARE.  Motorola assumes no responsibility for the maintenance
*	and support of the SOFTWARE.  
*
*	You are hereby granted a copyright license to use, modify, and
*	distribute the SOFTWARE so long as this entire notice is retained
*	without alteration in any modified and/or redistributed versions,
*	and that such modified versions are clearly identified as such.
*	No licenses are granted by implication, estoppel or otherwise
*	under any patents or trademarks of Motorola, Inc.

*
*	sasin.sa 3.3 12/19/90
*
*	Description: The entry point sAsin computes the inverse sine of
*		an input argument; sAsind does the same except for denormalized
*		input.
*
*	Input: Double-extended number X in location pointed to
*		by address register a0.
*
*	Output: The value arcsin(X) returned in floating-point register Fp0.
*
*	Accuracy and Monotonicity: The returned result is within 3 ulps in
*		64 significant bit, i.e. within 0.5001 ulp to 53 bits if the
*		result is subsequently rounded to double precision. The 
*		result is provably monotonic in double precision.
*
*	Speed: The program sASIN takes approximately 310 cycles.
*
*	Algorithm:
*
*	ASIN
*	1. If |X| >= 1, go to 3.
*
*	2. (|X| < 1) Calculate asin(X) by
*		z := sqrt( [1-X][1+X] )
*		asin(X) = atan( x / z ).
*		Exit.
*
*	3. If |X| > 1, go to 5.
*
*	4. (|X| = 1) sgn := sign(X), return asin(X) := sgn * Pi/2. Exit.
*
*	5. (|X| > 1) Generate an invalid operation by 0 * infinity.
*		Exit.
*

SASIN	IDNT	2,1 Motorola 040 Floating Point Software Package

	section	8

PIBY2	DC.L $3FFF0000,$C90FDAA2,$2168C235,$00000000

	xref	t_operr
	xref	t_frcinx
	xref	t_extdnrm
	xref	satan

	xdef	sasind
sasind:
*--ASIN(X) = X FOR DENORMALIZED X

	bra		t_extdnrm

	xdef	sasin
sasin:
	FMOVE.X		(a0),FP0	...LOAD INPUT

	move.l		(a0),d0
	move.w		4(a0),d0
	ANDI.L		#$7FFFFFFF,D0
	CMPI.L		#$3FFF8000,D0
	BGE.B		asinbig

*--THIS IS THE USUAL CASE, |X| < 1
*--ASIN(X) = ATAN( X / SQRT( (1-X)(1+X) ) )

	FMOVE.S		#:3F800000,FP1
	FSUB.X		FP0,FP1		...1-X
	fmovem.x	fp2,-(a7)
	FMOVE.S		#:3F800000,FP2
	FADD.X		FP0,FP2		...1+X
	FMUL.X		FP2,FP1		...(1+X)(1-X)
	fmovem.x	(a7)+,fp2
	FSQRT.X		FP1		...SQRT([1-X][1+X])
	FDIV.X		FP1,FP0	 	...X/SQRT([1-X][1+X])
	fmovem.x	fp0,(a0)
	bsr		satan
	bra		t_frcinx

asinbig:
	FABS.X		FP0	 ...|X|
	FCMP.S		#:3F800000,FP0
	fbgt		t_operr		;cause an operr exception

*--|X| = 1, ASIN(X) = +- PI/2.

	FMOVE.X		PIBY2,FP0
	move.l		(a0),d0
	ANDI.L		#$80000000,D0	...SIGN BIT OF X
	ORI.L		#$3F800000,D0	...+-1 IN SGL FORMAT
	MOVE.L		D0,-(sp)	...push SIGN(X) IN SGL-FMT
	FMOVE.L		d1,FPCR		
	FMUL.S		(sp)+,FP0
	bra		t_frcinx

	end