kern.ldscript revision 1.10 
1/* $NetBSD: kern.ldscript,v 1.10 2015/08/24 08:13:07 uebayasi Exp $ */
2
3/*  ldscript for NetBSD/mips kernels and LKMs */
4OUTPUT_ARCH(mips)
5ENTRY(_start)
6/* Do we need any of these?
7   __DYNAMIC = 0;    */
8_DYNAMIC_LINK = 0;
9SECTIONS
10{
11  /*  Read-only sections, merged into text segment.  Assumes the
12      kernel Makefile sets the start address via -Ttext.  */
13  .text      :
14  {
15    _ftext = . ;
16    *(.text)
17    __stub_start = . ;
18    *(.stub*)
19    __stub_end = . ;
20    *(.gnu.warning)
21  } =0
22  _etext = .;
23  PROVIDE (etext = .);
24  .rodata    : { *(.rodata) *(.rodata.*) }
25  .reginfo : { *(.reginfo) }
26/*  . = . + 0x1000; */
27  .data    :
28  {
29    _fdata = . ;
30    *(.data)
31    CONSTRUCTORS
32    . = ALIGN(32);       /* COHERENCY_UNIT */
33    *(.data.cacheline_aligned)
34    . = ALIGN(32);       /* COHERENCY_UNIT */
35    *(.data.read_mostly)
36    . = ALIGN(32);       /* COHERENCY_UNIT */
37  }
38  _gp = ALIGN(16) + 0x7ff0;
39  .lit8 : { *(.lit8) }
40  .lit4 : { *(.lit4) }
41  .sdata     : { *(.sdata) }
42  _edata  =  .;
43  PROVIDE (edata = .);
44  __bss_start = .;
45  _fbss = .;
46  .sbss      : { *(.sbss) *(.scommon) }
47  .bss       :
48  {
49    *(.bss)
50    *(COMMON)
51  }
52  _end = . ;
53  PROVIDE (end = .);
54}
55